PROC m_fl_ccdspt
;Version 8
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:   m_fl_ccdspt.prc
;#		   	MMS-F Name:  	 
;#		   	SUM Issue:   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  19-DEC-94   BS
;#			    Revision:  1.  2-21-95   RR
;#						2.  4/24/95 RR
;#						3.  05-03-95 RR
;#						4.  5-26-95 RR
;#						5. 06-JUN-95	HB
;#						6. 11/18/95	GJ
;#						7. 12-9-95
;#						8. 09-FEB-96	TB
;#
;#		1.3	Change Description:	
;#
;#			1.  Remove current check per PI request.
;#			2.  Added current check.
;#			3.  Reworded question for Set Point prompt
;#			4.  Reworked logic for commanding per PI inputs
;#			5. Deleted LOCAL variable S3.  Changed text in first WRITE
;#			   statement from 3 bits to 4 bits.  Changed value in first
;#			   ASK statement from 0-7 to 0-15.  Changed IF(SC<"ON") to
;#			   IF(SC<>"ON").  Changed statement S3=P@MKPWHCM to S1=
;#			   P@MKPWHCM.  Changed IF((PONT1>8) to IF((PONT1>=8).  Changed
;#			   expected value in the second S1="ON" from ON to OFF.  Added
;#			   two WAIT UNTIL statements. WAIT for MKPWHCM vice MKPWHKM.
;#			   Add quotes arooun $S1 in wait for MIKPWHCM.'
;#			6. Changed naming convention from m_ts_* to m_fl_*.
;#			7.  CHANGE LOGIC FOR RUNNING HCMON OR HCMOFF per OCD#43
;#			8. UPDATED VERSION NUMBER
;#
;#		1.4	Point of Contact:	
;#			FOT Author: BSAPPER 	ATSC/SOHO	805-3749
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure congigures the set point for the Operational
;#			CCD heater controller.
;#
;#		2.2	Intended Use:
;#
;#			Setting the MDI Operational CCD controller set point
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			MDI in SLEEP or higher mode. MR TLM required for duration of 
;#			power up sequence.  MDI operator on station to support 
;#			verification of proc. MDI operator verification required for
;#			each step before continuing.
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

IF (P@KKTMMODE = "HK") THEN	;Check TM is not in LR
WRITE "TM IS NOT IN MEDIUM/HIGH RATE."
GOTO END
ENDIF

LOCAL PONT1, PONT2, TEMP, S1,S2,WATTS

WRITE "THIS PROC REQUIRES THE SET POINT P1, WHICH IS 4 BITS (0-15), WHERE"
WRITE "0 IS NO POWER AND 15 IS MAX POWER"
WAIT 10

ASK "WHAT IS THE SET POINT VALUE (Decimal 0-15)"PONT1

PONT2=PONT1
IF(PONT2>=8)THEN
	PONT2=PONT1-8
ENDIF

;DETERMINE IF HOC IS NEEDED AND IS POWERED ON

IF(PONT2>0)THEN
  S2=P@MKPWHOP
  IF(S2<>"ON")THEN
    WRITE"SET POINT SELECTED REQUIRES OPTICS PACKAGE HEATER(HOP)"
    WRITE"BUT IT IS NOT ON."
    ASK"SHOULD HOP BE POWERED ON (Y/N)?"
    ANSWER=%UPPER(ANSWER)
    IF(ANSWER="Y")THEN
      S M_FL_HTRON
    ENDIF
  ENDIF
ENDIF

;SET HCM POWER AS REQUIRED

S1=P@MKPWHCM
IF(PONT1>=8) THEN
  IF(S1<>"ON")THEN
    S M_FL_HCMON
    S1="ON"
  ENDIF
ELSE
  IF(S1<>"OFF")THEN
    S M_FL_HCMOFF
    S1="OFF"
  ENDIF
ENDIF

WAIT UNTIL(P@MKPWHCM = "$S1")

IF(PONT2<>MKHCMSPT)THEN
  PONT2=%HEX(PONT2,4)
  /MBHCMSPT,$PONT2
  /SEND
ENDIF

WAIT UNTIL(MKHCMSPT = H'$PONT2')

;CALCULATE THE TOTAL CCD HEATER POWER

WATTS=2.25*PONT2+15*(PONT1/8)

SV WATTS
SV P@MIPWA
WAIT  ;RECORD MDI CURRENT (MIPWA,MIPWB) SHOULD BE < 1.5

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
end:
ENDPROC