PROC M_TS_FDOPEN1
;Version 3
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:	M_FDOPEN1	
;#		    MMS-F Name:	
;#		    SUM Issue:	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:	9-23-94
;#				Revision:	1. 4-24-95  GJ
;#						2. 05-04-95 RR
;#						3. 11/18/95 GJ
;#
;#		1.3	Change Description:	
;#
;#			1.  Changed comments and removed hard waits
;#			2.  Corrected door open logic
;#			3.  Changed naming convention from m_ts_* to m_fl_*.
;#
;#		1.4	Point of Contact:	
;#			FOT Author: RRowe	ATSC/SOHO	805-3642
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure powers up the MDI front door, opens the
;#			door on motor 1, verified the open status for the door
;#			and then powers the door back down.  Opening the door
;#			transitions MDI fron SAFE to STANDBY mode.
;#
;#		2.2	Intended Use:
;#
;#			To open the MDI front door and transition from SAFE to
;#			STANDBY mode.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			MDI in SAFE mode.  Medium rate telemetry support required for
;#			duration of power on sequence.  MDI Operator on station to support
;#			verification of procedure.  MDI operator verification required for
;#			each step before continuing.
;#**************************************************************************
;#	4.0	STEPS:
;#		
;
BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

IF (P@KKTMMODE = "HK") THEN	;Check TM is not in LR
WRITE "TM IS NOT IN MEDIUM/HIGH RATE."
GOTO END
ELSE
ENDIF

;Check if the front door is closed.  If so, skip procedure.
;
IF((P@MSFDCLN != "CLOSED") or (P@MSFDCLR != "CLOSED") or      ;;
   (P@MSFDOPN != "NOT OPEN") or (P@MSFDOPR != "NOT OPEN") or  ;;
   (P@MKFDMTR1 != "CLOSED") or (P@MKFDMTR2 != "CLOSED") or    ;;
   (P@MKFDOPN1 != "NOT OPEN") or (P@MKFDOPN2 != "NOT OPEN")) then
        write "MDI Front door may already be open"
	wait 10
	goto end
endif
;
;
WAIT;					'GO' to turn on the front door controller
;
/mbfdrs;				reset the front door controller
/SEND
;
wait 5
;
/mbpwfdon;				turn on the 15V power to the front door
/SEND
;
WAIT UNTIL(P@MKPWFD="ON");		Telemetry verification of front door power
;
WAIT;					'GO' to open front door on motor 1
;
/mbfd1o;				open front dor on motor 1
/SEND
;
WAIT UNTIL(P@MKFDMOVE="MOVING");	Telemetry verification of moving door.
;
;
;		The following will verify the open door
;
WAIT UNTIL(P@MSFDCLN="NOT CLOSED");		Verify the door is not closed
WAIT UNTIL(P@MSFDCLR="NOT CLOSED");		Verify the door is not closed (redundant)	
;
WAIT UNTIL(P@MSFDOPN="OPEN");			Verify the door is open
WAIT UNTIL(P@MSFDOPR="OPEN");			Verify the door is open (redundant)
;
WAIT UNTIL(P@MKFDMTR1="NOT CLOSED");	Verify front door motor indicates not closed
;
WAIT UNTIL(P@MKFDOPN1="OPEN");			Verify the front door is open
;
WAIT UNTIL(P@MKFDMOVE="NOT MOVING");	Verify the door is not open
;
WAIT UNTIL(P@MKFDSTAT="COMPLETED");		Verify the action is complete
;
WAIT UNTIL(P@MKFDFUNC="OPEN 1");
;
SV P@MKFDTIME
WAIT;				Record the close time.  Should be about 400.
;
;
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
end:
ENDPROC