PROC m_fl_lton
;Version 3
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:	M_LTON
;#		    MMS-F Name:	
;#		    SUM Issue:	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:	14-SEP-94
;#				Revision:	1. 24-APR-95 GJ
;#						2. 5-26-95 RR
;#						3. 11/18/95 GJ
;#
;#
;#		1.3	Change Description:	
;#
;#			1.  Changed comments and removed waits
;#			2.  Corrected syntax errors
;#			3.  Changed name convention from m_ts_* to m_fl_*.
;#
;#
;#		1.4	Point of Contact:	
;#			FOT Author: RROWE	ATSC/SOHO	805-3642
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure powers up and initializes the MDI limb
;#			tracker (or image stabilization system)  subsystem as
;#			part of MDI ON.
;#
;#		2.2	Intended Use:
;#
;#			Controlled initial power on of MDI LT subsystem.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			MDI in SLEEP mode.  Medium rate telemetry support
;#			required for duration of power on sequence.  MDI Operator
;#			on station to support verification of procedure.  MDI
;#			operator verification required for each step before
;#			continuing.
;#**************************************************************************
;#	4.0	STEPS:
;#		
;
BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

IF (P@KKTMMODE = "HK") THEN	;Check TM is not in LR
WRITE "TM IS NOT IN MEDIUM/HIGH RATE."
GOTO END
ELSE
ENDIF

;
WAIT;				'GO' to power on LT with open loop.
;
/mbpwlton;	power on LT
/mbltopnl;	LT to open loop
/SEND

;
WAIT UNTIL(P@MKPWLT="ON");
;
;
WAIT;	'GO' to select prime diodes, low gain (sun) and fine offsets
;
/mbltpdio;	select prime diodes
/mbltpout
/mbltlogn;	select low gain (sun)
/mbltfine;	select fine offsets
/SEND
;
WAIT;				'GO' to set X & Y gains to H'0040'
;
/mbltxgn,0040;		x gain
/mbltygn,0040;		y gain
/SEND
;
WAIT UNTIL(MKLTXGN=H'0040')
WAIT UNTIL(MKLTYGN=H'0040')
;
WAIT;				'GO' to set X & Y offsets to 0
;
/mbltxofs,0000;			Set the X offset to 0
/mbltyofs,0000;			Set the Y offset to 0
/SEND
;
WAIT UNTIL(MKLTXOFS=H'0000');		Telemetry verification of X offset
WAIT UNTIL(MKLTYOFS=H'0000');		Telemetry verificaiton of Y offset
;
WAIT;				'GO' to set all PZT offsets to H'0040'
;
/mbltaofs,0040;			set a offset to H'0040'
/mbltbofs,0040;			set b offset to H'0040'
/mbltcofs,0040;			set c offset to H'0040'
/SEND
;
WAIT UNTIL(MKLTAOS=H'0040');	Telemetry verification of a offset
WAIT UNTIL(MKLTBOS=H'0040');	Telemetry verification of b offset
WAIT UNTIL(MKLTCOS=H'0040');	Telemetry verification of c offset
;
SV P@MIPWA
SV P@MIPWB
WAIT;				Record the MDI current.  Should be about 1.1.
;
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
end:
ENDPROC