PROC m_fl_ovenspt
;Version 7
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  M_TS_OVENSPT  
;#		   	MMS-F Name:  	 
;#		   	SUM Issue:   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  21-DEC-94   BS
;#			    Revision:  1. 2-21-95
;#					2. 4-24-95
;#					3. 5-26-95 RR
;#						4. 06-JUN-95	HB
;#					5. 11/18/95 GJ
;#					6. 12/03/95 GJ
;#					7. 07/16/96 CG
;#
;#		1.3	Change Description:	
;#
;#			1.  Change questions and comments to clarify procedure
;#			2.  Changed comments
;#			3.  added new logic for disabling oven monitoring
;#			4. Added an additional WRITE statement, /MKHPONON, /SEND,
;#			   and a WAIT UNTIL statement in the IF(P@MKHPOMON="ON") loop.
;#			5. Changed name convention from m_ts_* to m_fl_*.
;#			6. Deleted GOTO END and added WAIT; GO TO CONTINUE.
;#			7. Added P@ to SV MIPWA & MIPWB.  Also added IFs so they will
;#			   not be displayed if OFF.
;#
;#		1.4	Point of Contact:	
;#			FOT Author:  BSAPPER	ATSC/SOHO	805-3749
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure sets the prime oven set point.
;#
;#		2.2	Intended Use:
;#
;#			Establish prime oven set point for thermal control.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			P1-prime oven set point. 3 bits (value 0-7) where 0 corresponds
;#			to approx. 33 degC, and 7 41degC.
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			MDI in SLEEP mode. MR TLM required. MDI operator support verif.
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

IF (P@KKTMMODE = "HK") THEN	;Check TM is not in LR
 WRITE "TM IS NOT IN MEDIUM/HIGH RATE."
 WAIT		; GO TO CONTINUE.
ENDIF

LOCAL P1

IF (P@MSPWA = "ON") THEN
	SV P@MIPWA
 ELSEIF (P@MSPWB = "ON") THEN
	SV P@MIPWB
 ELSE
	WRITE"MSPWA & MSPWB ARE NOT ON."
ENDIF
WAIT		;RECORD MDI CURRENT

ASK "WHAT IS THE DESIRED PRIME OVEN SET POINT (0 TO 7)?"P1
P1 = %HEX(P1,4)
if(h'$p1'=mkhpospt)then
  goto end
endif

/MBHPOSPT,$P1			;HPO SET POINT TO P1
WAIT 		;VERIFY BUFFER CONTENTS
/SEND

WAIT UNTIL (MKHPOSPT = h'$P1')

if(p@mkhpomon="ON")then
  write"Oven Monitoring will be disabled.  It should be re-enabled"
  WRITE"when oven temperatures stabilized."

  /MBHPOMOF
  /SEND
  WAIT UNTIL(P@MKHPOMON = "OFF")
endif


IF (P@MSPWA = "ON") THEN
	SV P@MIPWA
 ELSEIF (P@MSPWB = "ON") THEN
	SV P@MIPWB
 ELSE
	WRITE"MSPWA & MSPWB ARE NOT ON."
ENDIF
WAIT		;RECORD MDI CURRENT, SHOULD INCREASE BY 0.4 

SV P@MTOPTS4
SV P@MTOPTS5
WAIT		;RECORD OVEN TEMP (MKOPTS4,MKOPTS5)

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
end:
ENDPROC