PROC m_fl_pconpri
;Version 11
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:		M_FL_PCONPRI	
;#		    MMS-F Name:		
;#		    SUM Issue:	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:	9-SEP-94
;#				Revision: 1. 11-29-94	
;#					  2. 1/25/95 RR
;#                         	  	  3. 4/24/95 GLJ
;#					  4. 4/26/95 GLJ
;#					  5. 5-26-95 RR
;#					  6. 7-24-95 RR
;#					  7. 8-15-95 GJ
;#					  8. 9-7-95  RR
;#					  9. 11 NOV 95 RS
;#					 10. 11/18/95 GJ
;#					 11. 12/03/95 GJ
;#
;#		1.3	Change Description:	
;#
;#			1.  Changed TM check to end proc if in LR
;#			2.  added s k_exp_mon_ena
;#			3.  changed comments and removed waits
;#			4.  added GLOBAL mdi_hrtlm, mdi_cmd and deleted wait until off
;#			5.  changed redundant global variable definitions
;#			6.  added wait 10 between commands in AE sequence
;#			7.  Added wait 5 and 10 seconds and /mcdprstr
;#			8.  Removed references to global variables
;#			9.  Removed checks for low currents on MIPWA and MIPWB since
;#			    they are not valid when ASPWA and ASPWB are off.
;#		     10. Changed name convention from m_ts_* to m_fl_*.
;#			11. Deleted GOTO END and added WAIT; GO TO CONTINUE.
;#
;#
;#		1.4	Point of Contact:	
;#			FOT Author: RRowe	ATSC/SOHO	805-3642
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#			
;#			This procedure powers up the MDI instrument with the primary
;#			MDI power converters on the spacecraft primary power interface (A)
;#		        and primary telecommand and telemetry interfaces.  It powers on
;#			PC1, PC2, DEP and AE.  It is initiated with MDI in OFF mode and
;#			if successful, completes with MDI in SLEEP mode.
;#			
;#
;#		2.2	Intended Use:
;#
;#			Controlled initial power on of MDI from OFF to SLEEP.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References:
;#
;#			"stol_list.tst" provided from SOI-MDI and SOHO FOT meeting.
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			Medium rate telemetry support required for duration of power on
;#			sequence.  MDI Operator on station to support verification of 
;#			procedure.  MDI Operator verification required for each step
;#			before continuing.
;#**************************************************************************
;#	4.0	STEPS:
;#		
;
BEGIN:
;
;
IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF
;
IF (P@KKTMMODE = "HK") THEN	;Check TM is not in LR
WRITE "TM IS NOT IN MEDIUM/HIGH RATE."
WAIT;	 GO TO CONTINUE.
ENDIF
;

P M_PWR_1,1,,+325+450

WAIT UNTIL(P@MSPWA="OFF");	Wait until MSPWA indicates OFF
WAIT UNTIL(P@MSPWB="OFF");	Wait until MSPWB indicates OFF
;
WAIT	;Verify currents and 'GO' to command MDI all off.
;
/mcallofn	;Safety command to ensure MDI is OFF, before powering on
/SEND
;

WAIT;				'GO' to switch MDI power converters to B bus.
;
/mcpc1bn;		PRIMARY CONVERTER 1 TO B(N)
/mcpc2bn;		PRIMARY CONVERTER 2 TO B(N)
/mcrc1bn;		PRIMARY CONVERTER 1 TO B(N)
/mcrc2bn;		PRIMARY CONVERTER 2 TO B(N)
/SEND
;
WAIT UNTIL(P@MSPC1N="B");	Verify command execution.
WAIT UNTIL(P@MSPC2N="B");	Verify command execution.
WAIT UNTIL(P@MSRC1N="B");	Verify command execution.
WAIT UNTIL(P@MSRC2N="B");	Verify command execution.
;
WAIT;				'GO' for s/c bus A power on
;
/KNMPWANN;	S/C BUS A POWER ON
/SEND
;
WAIT UNTIL(P@MSPWA="ON");	Verify s/c bus A power on
WAIT UNTIL((P@MIPWA>=0)AND(P@MIPWA<0.05))	;Current should be approx zero

s k_exp_mon_ena

WAIT;				'GO' to send ALL OFF command.
;
/mcallofn;	SEND MDI ALL OFF CMD
/SEND
;
WAIT UNTIL(P@MSPWDPN="OFF");	Verify DEP is OFF.
WAIT UNTIL(P@MSPWAEN="OFF");	Verify App electronics are OFF.
;

WAIT;	'GO' TO SWITCH PC2 TO A BUS

/MCPC2AN;		PC2 TO A BUS
/SEND

WAIT UNTIL(P@MSPC2N="A");	VERIFY PC2 TO A BUS


SV P@MIPWA
WAIT;	RECORD MDI CURRENT, SHOULD BE ABOUT 0.3


WAIT;	'GO' TO SWITCH ON DEP

/MCDPONN;		SWITCH ON DEP
/SEND

WAIT UNTIL(P@MSPWDPN="ON")

SV P@MIPWA
WAIT;	RECORD MDI CURRENT, SHOULD BE ABOUT 0.4

WAIT;	'GO' TO SWITCH ON APPS ELECTRONICS

/MBPWAEON;	AE ON
/SEND

WAIT 5

WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE")
;
/MCDPRSTN;	RESET DEP
/SEND

WAIT 10

WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE")
;	
/MBPWAEON;	
/SEND

WAIT UNTIL(P@MSPWAEN="ON");	VERIFY AE ON

WAIT;	'GO' TO TELL DEP THE PRIME 160K TLM IF IS SELECTED

/MBPWTM1O;	TELL DEP IS PRIME 160K TLM IF
/SEND


WAIT;				'GO' to set DEP local on-board time.
;
/knk12000,0020;	DISTRIBUTE OBT TO MDI
/SEND
;
WAIT;				'GO' to reset all motor controllers.
;
/mbshrs;	SHUTTER RESET
/mbm1rs;	MTM1 RESET
/mbm2rs;	MTM2 RESET
/mbpars;	PA RESET
/mbc1rs;	C1 RESET
/mbc2rs;	C1 RESET
/mbfdrs;	FRONT DOOR RESET
/mbam1rs;	AM1 RESET
/mbam2rs;	AM2 RESET
/SEND
;
WAIT;				'GO' to switch pc1 to A bus.
WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
/mcpc1an;		PC1 TO A BUS
/SEND
;
WAIT UNTIL(P@MSPC1N="A");	Verify PC1 is connected to A bus.
;
SV P@MIPWA
;				Record the MDI current.  This should be 
WAIT;				approximately 0.7.
;
WAIT UNTIL(P@MKPWAE="ON")	;Verify application is on I/F power.
WAIT UNTIL(P@MKTMSEL="1")	;Verify TM selection enabled.
WAIT UNTIL(P@MSTMSELN="1")	;Verify TM selection enabled.
;
SNAP M_PWR_1,,PCSONSCA.RPT,OVERWRITE
;
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
END:
ENDPROC