PROC m_fl_tap
;Version 4


IF (P@NRT_STATE#TELECOMMAND = "ENABLED") THEN
/NRT TPUT PAUS
ELSE
ENDIF


GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: m_fl_tap    
;#		   	MMS-F Name:  	 
;#		   	SUM Issue:   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  21 DEC 94   TL
;#			    Revision:   1. 2-21-95
;#					2. 07-APR-95  CG
;#					3. 5-26-95 RR
;#					4. 12-02-95 GJ
;#
;#		1.3	Change Description:	
;#
;#			1.  Change question in prompt and move prompt out of loop
;#			2.  Corrected IF statement that was missing THEN in value
;#				check of P1.  Deleted an extra ASK, P1 conversion statement
;#				& WAIT UNTIL.
;#			3.  removed wait 16.
;#			4.  Changed name convention from m_ts* to m_fl*.
;#
;#		1.4	Point of Contact:	
;#			FOT Author:  T. LA FAVE	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure takes 4 pictures.
;#
;#		2.2	Intended Use:
;#
;#			Take 4 images and downlink in 4x4 packed arrays of
;#             256x256 pixels each.
;#
;#		2.3	Duration:	
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			1) P1 - Exposure time in ticks for image.  Range in 
;#                     decimal is from 1 to 65535.  Nominal value = 4000.
;#
;#		3.2	Critical Activities
;#
;#			NONE
;#
;#		3.3	Special Constraints or Activities
;#
;#			MDI in SAFE, STANDBY, or READY mode.  High rate telemetry
;#             support required for downlink of images.  MDI Operator on
;#             station to support verification of procedure.
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL P1

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

IF ((P@KKTMMODE<3) and (P@KKTMFID<1)) THEN	;Check TM is not in HR
WRITE "TM IS NOT IN HIGH RATE."
GOTO END
ENDIF


WAIT;	MDI Operator must open the Decom File

WAIT;	SET IP TO 4X4 PACK MODE

s m_fl_iplbic(5)

question:

ASK "ENTER A VALUE FOR P1 (exposure, decimal)==>" P1 
P1=%HEX(P1,4)
If((h'$P1'>1) AND (h'$P1'<65535)) then ;	VERIFY RANGE OF P1
else
	write "This is not a valid value"
	wait 10
	goto question
endif



FOR XNUM = 1 TO 4 DO 

   WAIT;	TAKE A 1X IMAGE WITH P1 EXPOSURE
  
   /MBCMTP1R,C01A,$P1,$P1
   WAIT;	VERIFY CONTENTS OF THE COMMAND BUFFER
   /SEND
   WAIT; 30	30 SECOND DELAY or until MDI gives OK to continue

ENDDO
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		NONE
;#
;#**************************************************************************


IF (P@NRT_STATE#TELECOMMAND = "PAUSE-ENAB") THEN
/NRT TPUT RSUM
/CMSMSG,MDI,'Procedure M_FL_TAP has completed'
ELSE
ENDIF

end:
ENDPROC