--+------------------------------------------------------------------------------+
--+                        SOHO Project -- Control File
--+                        ----------------------------
--+
--+ Name        : MDI_EMC_ON , MDI_Config , !Print
--+ Purpose     : TURN ON THE MDI EXPERIMENT FOR EMC TESTS.
--+                    
--+ Sub_system  : PLM
--+ Drawing No  : 3137-ZA042-SCB  Issue : A/00
--+ Project No  : SH-MAR-SW-70224
--+ Origin      : Fr
--+ Author      : Ph. IATRINO 
--+------------------------------------------------------------------------------+
--+ Principle   :
--+ ---------
--+   To turn ON the MDI experiment in the required configuration (Redundant Bus).
--+
--+ Passed parameters :
--+ -----------------
--+   !MDI_Config : MDI Configuration ( 2 (Redundant Bus ONLY))
--+   !Print      : CF Log print indicator ( "yes" (default) | "no" ).
--+
--+ Prerequisites :
--+ -------------
--+  (a)  PLM is powered ON in a ready mode.
--+  
--+  (b)  Ensure the Purge Equipment is mated to the MDI Sensor and is 
--+       switched ON and Purging.
--+
--+ History :
--+ -------
--+   Issue SIC Note Time   Date      Name / Updates
--+   +---+ +------+ +---+  +------++--------------------------------------------+ 
--+   1/00    597    11:06  25/04/95  Ph. IATRINO     -- Creation.
--+   1/01    597    17:26  18/05/95  J.B.B           -- Updates.
--+   1/02    609    06:30  19/05/95  Ph. IATRINO     -- Updates.
--+
--+------------------------------------------------------------------------------+
Common
Var
    Bool        !GZ_Window        -- Open window flag (on CF start)
    Bool        !GZ_Spool         -- Automatic Spool (at End of CF exec)
    Bool        !GZ_Halt          -- Check Error flag (to halt if error)
    Bool        !GZ_Test          -- Execution test flag (to not send TC)
    Int         !GZ_Trace         -- Level of Trace (TBD)

    Int         !GM_Conf          -- MDI Configuration
    Int         !GM_NbErr         -- MDI Global Error Count

End Common
---------------------------------------------------------------------------------+
Extern
    Cfile   MDI_LRCONEMC, MDI_LIP, MDI_LCM, MDI_LMCH
    Group   MWTM

    Procedure   DispMess    , OpenWindow , Message    , ExitCF
    Procedure   CheckArgReal, CheckArgStr, CheckArgInt

End Extern
---------------------------------------------------------------------------------+
Program MDI_EMC_ON , Unique

Defarg
    Int         !MDI_Config = 1
    Str(3)      !Print      = "yes"
End Defarg

Var
    Str( 3)     !ExpName    = "MDI"               -- Experiment name
    Str(80)     !S          = &80s(" ")           -- To save the display messages
    Str(10)     !Phase      = " "                 -- Phase label (e.g. 3.3.1.2)
    Str(49)     !Title      = "" 
    Int         !NbErr      = 0                   

Main 

    @OpenWindow()

    @CheckArgInt (!MDI_Config, "Arg 1 as Config No.", "= 1", *!NbErr)

    If( !NbErr <> 0 ) Then
        !Title   = "*ERROR: INVALID Input Argument (see above)"
        @Message( "DC", "date", !ExpName, !Phase, !Title, *!S)
        !Rstat = "ARG_NOK"
        If !GZ_Test = FALSE Then
           Halt
        End If
        Return !Rstat        
    End If

    !Title  = "-START OF MDI SWITCH-ON"
    @Message ("DCL", "date", !ExpName, !Phase, !Title, *!S)

    !GM_NbErr = 0

    PERFORM/NO MDI_LRCONEMC, "lrconemc", "no"
    PERFORM/NO MDI_LIP   , "lipona"  , "no"
    PERFORM/NO MDI_LCM   , "lcmon"   , "no"
    PERFORM/NO MDI_LMCH  , "lmchson" , "no"

    !GM_Conf = !MDI_Config

    Cflog
    !Title  = "*MDI IS NOW IN SAFE/STANDBY MODE"
    @Message ("DC", "date", !ExpName, !Phase, !Title, *!S)

    !Title  = "-END OF MDI SWITCH-ON"
    @Message ("DCL", "date", !ExpName, !Phase, !Title, *!S)

    @ExitCF  ( !GM_NbErr )
    @PrintCF ( !ExpName , !Print )
    Return !Rstat
End Program
---------------------------------------------------------------------------------+
Procedure PrintCF(str(3) !ExpName, Str(3) !Print)
--. Print the control file log file if required by !Print ;
--.  - using the 'Spool' statement if the variable !GZ_Spool is TRUE,
--.  - using the dialog box window if the variable !GZ_Spool is FALSE.
--. 
  Var
     str(80)  !S = &80s("")

  Main
     If !Print = "yes" Then
       If !GZ_Spool = TRUE  Then
          Spool CF
       Else   
          Cflog
          @Message ("DC", "date", !ExpName, " ", \
                    "++++Print the CFLog, then type CONT+++", *!S)
          Halt
          @Message ("DC", "date", !ExpName, " ", \
                    "+Operator continue.", *!S)
       End If
     End If
  Return
End Procedure
---------------------------------------------------------------------------------+