--+----------------------------------------------------------------------------+
--+                        SOHO Project -- Control File
--+                        ----------------------------
--+
--+ Name        : MDI_OFF , !Print
--+ Purpose     : TURN OFF THE MDI EXPERIMENT 
--+                
--+ Sub_system  : PLM
--+ Drawing No  : 3137-ZA042-SCB  Issue : A/00
--+ Project No  : SH-MAR-SW-70224
--+ Origin      : UK 
--+ Author      : Jon B. CARTER
--+----------------------------------------------------------------------------+
--+ Principle   :
--+ ---------
--+   To Turn OFF the Power to the appropriate Redundancy of the MDI Experiment.
--+
--+ Passed parameters :
--+ -----------------
--+   !Print    : CF Log print indicator ( "yes" (default) | "no" ).
--+
--+ Prerequisites :
--+ -------------
--+    The MDI Experiment is in SAFE/STANDBY mode.
--+
--+ History :
--+ -------
--+   Issue SIC Note Time   Date      Name/Updates
--+   +---+ +------+ +---+  +-------+  +----------------------+
--+   1/00   211     16:57  20/01/94   A.J. TURK -- Conversion from MDI language.
--+   1/01   289     09:02  07/02/94   A.J. TURK -- During debug phase.
--+   1/02   360     09:42  18/04/94   Ed COBB   -- FM Rationalization. 
--+   1/03   393     11:08  17/05/94   Ed COBB   -- MDI Updates. 
--+
--+----------------------------------------------------------------------------+
Common
Var
    Bool        !GZ_Window              -- Open window flag (on CF start)
    Bool        !GZ_Spool               -- Automatic Spool (at End of CF exec)
    Bool        !GZ_Halt                -- Check Error flag (to halt if error)
    Bool        !GZ_Test                -- Execution test flag (to not send TC)
    Int         !GZ_Trace               -- Level of Trace (TBD)

    Int         !GM_Conf                -- MDI Configuration
    Int         !GM_NbErr               -- MDI Global Error Count

End Common
-------------------------------------------------------------------------------<
Extern
    Cfile    MDI_LOFF , MDI_IPKA , MDI_IP , MDI_LIP ,  MDI_LFD
    Group    MWTM , PWP12TM

    Procedure   AskReal, AskStr, AskInt
    Procedure   CheckAna, CheckDig, CheckReg
    Procedure   CheckArgReal, CheckArgStr, CheckArgInt
    Procedure   DispMess, OpenWindow, Message, ExitCF
    Procedure   ExConnect, ExDisconnect
    Procedure   PrintAna, PrintDig, PrintReg, PrintParam
    Procedure   SendCommand 
    Procedure   Lower, Upper
    Procedure   WaitAna, WaitDig, WaitReg, WaitTime

End Extern
-------------------------------------------------------------------------------<
Program MDI_OFF , Unique

Defarg
    Str(3)      !Print         = "yes"
End Defarg

Var
    Str( 3)     !ExpName    = "MDI"               -- Experiment name
    Str(80)     !S          = &80s("")            -- To save the display messages
    Str(10)     !Phase      = " "                 -- Phase label (e.g. 3.3.1.2)
    Str(49)     !Title      = "" 
    Str(80)     !Question   = ""
    Str(80)     !Check      = ""
    Str(80)     !LM_S0      = ""
    Int         !NbErr      = 0

Main 
    @OpenWindow()

    PERFORM/NO MDI_LFD , "lfdclose" ,"no"

    !Title   = "-START OF MDI SWITCH-OFF: 'MDI_OFF'"
    @Message( "DCL", "date", !ExpName, !Phase, !Title, *!S)

    !GM_NbErr = 0

    If !GM_Conf = 1 Then
       PERFORM/NO MDI_IP    , "ipwload"  , "no"
       PERFORM/NO MDI_IPKA  , "ipkaload" , "no"

       !Question =  "MDI to Open Decom File(Y)" 
       !Check = "in Y, y"
       @AskStr ( !Question , !Check , *!LM_S0 , *!S , *!NbErr )

       PERFORM/NO MDI_IPKA  , "ipkaltst" , "no"

       !Question =  "MDI to Close Decom File(Y)" 
       !Check = "in Y, y"
       @AskStr ( !Question , !Check , *!LM_S0 , *!S , *!NbErr )
  
       PERFORM/NO MDI_LOFF  , "loffsca"  , "no"
    Else
       PERFORM/NO MDI_LOFF  , "loffscb"  , "no"
    End If

    !GM_Conf = 0

    Cflog
    !Title   = "-END OF MDI SWITCH-OFF: 'MDI_OFF'"
    @Message( "DCL", "date", !ExpName, !Phase, !Title, *!S)

    @ExitCF ( !GM_NbErr )
    @PrintCF (!ExpName, !Print)
    Return !Rstat
End Program
-------------------------------------------------------------------------------<
Procedure PrintCF(str(3) !ExpName, Str(3) !Print)
--. Print the control file log file if required by !Print ;
--.  - using the 'Spool' statement if the variable !GZ_Spool is TRUE,
--.  - using the dialog box window if the variable !GZ_Spool is FALSE.
--. 
  Var
     str(80) !S = &80s("")

  Main
     If !Print = "yes" Then
       If !GZ_Spool = TRUE  Then
          Spool CF
       Else   
          Cflog
          @Message ("DC", "date", !ExpName, " ", \
                    "++++Print the CFLog, then type CONT+++", *!S)
          Halt
          @Message ("DC", "date", !ExpName, " ", \
                    "+Operator continue.", *!S)
       End If
     End If
  Return
End Procedure
-------------------------------------------------------------------------------<