--+----------------------------------------------------------------------------+
--+
--+                        SOHO Project -- Control File
--+                        ----------------------------
--+
--+ Name        : MDI_TEST , !MDI_Config , !Test , !Print
--+ Purpose     : AFT or SFT TEST OF THE MDI EXPERIMENT. 
--+                  
--+ Sub_system  : PLM
--+ Drawing No  : 3137-ZA042-SCB  Issue : A/00
--+ Project No  : SH-MAR-SW-70224
--+ Origin      : UK 
--+ Author      : Jon B. CARTER 
--+----------------------------------------------------------------------------+
--+ Principle   :
--+ ---------
--+    This test sequence performs the individual MDI Experiment Sub-System
--+    AFT or SFT activities in either of the redundancy configurations known as
--+    1 (all NOMINAL) or 2 (all REDUNDANT).
--+
--+ Passed parameters :
--+ -----------------
--+   !MDI_Config : Configuration 1 | 2
--+   !Test_s     : Required test type "AFT" | "SFT"
--+   !Print      : CF Log print indicator ( "yes" (default) | "no" ).
--+
--+ Prerequisites :
--+ -------------
--+  (a)  Ensure Ground Equipment SVM Simulator is configured to the correct
--+       Redundancy under test.
--+      
--+  (b)  PLM is powered ON and is in the ready mode.
--+      
--+  (c)  Non-Operational Heaters are powered OFF.
--+      
--+  (d)  Experiment Sub-System is powered OFF.
--+      
--+  (e)  Ensure the Purge Equipment is mated to the MDI Sensor and is
--+       switched ON and Purging.
--+
--+ History :
--+ -------
--+   Issue SIC Note Time   Date      Name/Updates
--+   +---+ +------+ +---+  +------+ +-------------------------------------+
--+   1/00   211     16:36  20/01/94  A.J. TURK    -- Conversion from MDI language.
--+   1/01   289     08:22  07/02/94  A.J. TURK    -- During debug phase.
--+   1/02   360     10:01  18/04/94  Ed COBB      -- Rationalization.
--+   1/03   393     17:45  16/05/94  Ph. IATRINO  -- MDI Updates.
--+
--+----------------------------------------------------------------------------<
Common
Var
    Bool        !GZ_Window        -- Open window flag (on CF start)
    Bool        !GZ_Spool         -- Automatic Spool (at End of CF exec)
    Bool        !GZ_Halt          -- Check Error flag (to halt if error)
    Bool        !GZ_Test          -- Execution test flag (to not send TC)
    Int         !GZ_Trace         -- Level of Trace (TBD)

    Int         !GM_Conf          -- MDI Configuration
    Int         !GM_NbErr         -- MDI Global Error Count

End Common
-------------------------------------------------------------------------------<
Extern                                                                          
    Cfile    MDI_ON , MDI_OFF , MDI_COM , MDI_OBS , MDI_CHK , MDI_RCS
    Cfile    MDI_DSOS , MDI_LFD
    Group    MWTM , MWTC , PWP12TM 

    Procedure   CheckArgReal , CheckArgStr , CheckArgInt
    Procedure   DispMess
    Procedure   ExConnect , ExDisconnect
    Procedure   ExitCF
    Procedure   Message
    Procedure   OpenWindow
    Procedure   Lower , Upper , AskStr

End Extern
-------------------------------------------------------------------------------<
Program MDI_TEST , Unique

Defarg
    Int         !MDI_Config    = 0
    Str(3)      !Test_s        = "???"
    Str(3)      !Print         = "yes"
End Defarg

Var
    Str( 3)     !ExpName   = "MDI"           -- Experiment name
    Str(80)     !S         = &80s("")        -- To save the display messages
    Str(10)     !Phase     = " "             -- Phase label (e.g. 3.3.1.2)
    Str(49)     !Title     = "" 
    Str(80)     !Question  = ""
    Str(80)     !Check     = ""
    Str(80)     !Resp_s    = ""
    Int         !NbErr     = 0                   
    Int         !Test_Err  = 0               -- No. of Errors in 'TEST' CF                   

Main
    @OpenWindow()

    @CheckArgInt (!MDI_Config, "Arg 1 as Config No.", ">= 1 and <= 2", *!NbErr )
    @CheckArgStr (!Test_s, "Arg 2 as Test Phase","in AFT, SFT", *!NbErr )

    If( !NbErr <> 0 ) Then
        !Title   = "*ERROR: INVALID Input Argument (see above)"
        @Message( "DC", "date", !ExpName, !Phase, !Title, *!S)
        !Rstat = "ARG_NOK"
        If !GZ_Test = FALSE Then
           Halt
        End If
        Return !Rstat        
    End If

    !Title   = "-START OF MDI TEST CF : 'MDI_TEST'"
    @Message( "DCL", "date", !ExpName, !Phase, !Title, *!S)

    PERFORM/NO MDI_ON , !MDI_Config , "yes"
    !Test_Err = !Test_Err + !GM_NbErr 

    If !Test_s = "SFT" Then
        PERFORM/NO MDI_COM , "yes"
    Else
        PERFORM/NO MDI_CHK , "yes"
    End If
    !Test_Err = !Test_Err + !GM_NbErr 

    !Question  = "Want to Open FRONT DOOR ? (y/n)"
    !Check     = "in Y, N, y, n"
    @AskStr (!Question, !Check, *!Resp_s, *!S, *!NbErr)
    @Upper (!Resp_s, *!Resp_s)

    If !Resp_s = "Y" Then
       PERFORM/NO MDI_LFD , "lfdopen"  , "yes"
    End If

    PERFORM/NO MDI_OBS , "yes"
    !Test_Err = !Test_Err + !GM_NbErr 
    PERFORM/NO MDI_OFF , "yes"
    !Test_Err = !Test_Err + !GM_NbErr 

    If !MDI_Config = 1 Then
       PERFORM/NO MDI_RCS , "yes"
    Else
       PERFORM/NO MDI_DSOS , "yes"
    End If
    !Test_Err = !Test_Err + !GM_NbErr 

    !Title   = "-END OF MDI TEST CF : 'MDI_TEST'"
    @Message( "DCL", "date", !ExpName, !Phase, !Title, *!S)

    @ExitCF (!Test_Err )
    @PrintCF (!ExpName , !Print )
    Return !Rstat

End Program
-------------------------------------------------------------------------------<
Procedure PrintCF(str(3) !ExpName, Str(3) !Print)
--. Print the control file log file if required by !Print ;
--.  - using the 'Spool' statement if the variable !GZ_Spool is TRUE,
--.  - using the dialog box window if the variable !GZ_Spool is FALSE.
--. 
  Var
     str(80) !S  =  &80s("")

  Main
     If !Print = "yes" Then
       If !GZ_Spool = TRUE  Then
          Spool CF
       Else   
          Cflog
          @Message ("DC", "date", !ExpName, " ", \
                    "++++Print the CFLog, then type CONT+++", *!S)
          Halt
          @Message ("DC", "date", !ExpName, " ", \
                    "+Operator continue.", *!S)
       End If
     End If
  Return
End Procedure
-------------------------------------------------------------------------------<