--+----------------------------------------------------------------------------+
--+
--+                        SOHO Project -- Control File
--+                        ----------------------------
--+
--+ Name        : MDI_TM_SEL , !Print
--+ Purpose     : Exorcise MDI TLM selection Anomaly 
--+                  
--+ Sub_system  : PLM
--+ Drawing No  : 3137-ZA042-SCB  Issue : A/00
--+ Project No  : SH-MAR-SW-70224
--+ Origin      : UK 
--+ Author      : Ed COBB 
--+----------------------------------------------------------------------------+
--+ Principle   :
--+ ---------
--+  This CF is to be run when a Telemetry selection anomaly occurs.  
--+
--+ Passed parameters :
--+ -----------------
--+   !Print      : CF Log print indicator ( "yes" (default) | "no" ).
--+
--+ Prerequisites :
--+ -------------
--+    MDI Experiment Sub_System Powered ON 
--+
--+ History :
--+ -------
--+   Issue SIC Note Time   Date      Name/Updates
--+   +---+ +------+ +---+  +------+ +-----------------------------------------+
--+   2/00   477     18:47  19/09/94  Ed COBB / Ph. IATRINO      -- Creation.
--+   2/01   479     19:52  20/09/94  Ed COBB / Ph. IATRINO      -- CF Errors.
--+   2/02   480     17:43  23/09/94  Ed COBB / Ph. IATRINO      -- CF Errors.
--+
--+----------------------------------------------------------------------------<
Common
Var
    Bool        !GZ_Window        -- Open window flag (on CF start)
    Bool        !GZ_Spool         -- Automatic Spool (at End of CF exec)
    Bool        !GZ_Halt          -- Check Error flag (to halt if error)
    Bool        !GZ_Test          -- Execution test flag (to not send TC)
    Int         !GZ_Trace         -- Level of Trace (TBD)

    Int         !GM_Conf          -- MDI Configuration
    Int         !GM_NbErr         -- MDI Global Error Count

End Common
-------------------------------------------------------------------------------<
Extern                                                                          
    Group       MWTM , MWTC , PWP12TM 

    Procedure   CheckArgReal , CheckArgStr , CheckArgInt
    Procedure   DispMess 
    Procedure   ExConnect , ExDisconnect
    Procedure   ExitCF
    Procedure   Message, SendCommand
    Procedure   OpenWindow , WaitTime , WaitDig
    Procedure   Lower , Upper , AskStr

End Extern
-------------------------------------------------------------------------------<
Program MDI_TM_SEL , Unique

Defarg
    Str(3)      !Print     = "yes"
End Defarg

Var
    Str( 3)     !ExpName   = "MDI"           -- Experiment name
    Str(80)     !S         = &80s("")        -- To save the display messages
    Str(10)     !Phase     = " "             -- Phase label (e.g. 3.3.1.2)
    Str(49)     !Title     = "" 
    Str(80)     !Question  = ""
    Str(80)     !Check     = ""
    Str(80)     !Response  = ""
    Int         !NbErr     = 0                   
    Int         !Test_Err  = 0               -- No. of Errors in 'TEST' CF                   

Main
    @OpenWindow()

    !Title  = "-START OF MDI TLM SELECTION EXORCISM"
    @Message ("DCL", "date", !ExpName, !Phase, !Title, *!S)

    DO

      !Question = "MDI READY ? (Y/N)" 
      !Check    = "in Y, y"
      @AskStr (!Question, !Check, *!Response, *!S, *!NbErr)
      @Upper  (!Response, *!Response )

      If (!GM_Conf = 1) Then

         Cflog
         @SendCommand ("MBPWTM2O", "")
         @WaitDig     ("MKTMSEL", "= 2", "00h00m45s", *!S)
         @SendCommand ("MBPWTM1O", "")
         @WaitDig     ("MKTMSEL", "= 1", "00h00m45s", *!S)
         @SendCommand ("MBCMTP1", "0, 0, 4000")   
   
      Else

         Cflog
         @SendCommand ("MBPWTM1O", "")
         @WaitDig     ("MKTMSEL", "= 1", "00h00m45s", *!S)
         @SendCommand ("MBPWTM2O", "")
         @WaitDig     ("MKTMSEL", "= 2", "00h00m45s", *!S)
         @SendCommand ("MBCMTP1", "0, 0, 4000")      
 
      End If

      !Question = "MDI High Rate Data OK ? (Y/N)" 
      !Check    = "in Y, y, N, n"
      @AskStr (!Question, !Check, *!Response, *!S , *!NbErr)
      @Upper  (!Response, *!Response)

      EXIT IF (!Response = "Y")

    END DO
  
    !GM_NbErr = !GM_NbErr + !NbErr 

    !Title  = "-END OF MDI TLM SELECTION EXORCISM"
    @Message ("DCL", "date", !ExpName, !Phase, !Title, *!S)

    @ExitCF  (!Test_Err)
    @PrintCF (!ExpName, !Print)
    Return !Rstat

End Program
-------------------------------------------------------------------------------<
Procedure PrintCF(str(3) !ExpName, Str(3) !Print)
--. Print the control file log file if required by !Print ;
--.  - using the 'Spool' statement if the variable !GZ_Spool is TRUE,
--.  - using the dialog box window if the variable !GZ_Spool is FALSE.
--. 
  Var
     str(80) !S  =  &80s("")

  Main
     If !Print = "yes" Then
       If !GZ_Spool = TRUE  Then
          Spool CF
       Else   
          Cflog
          @Message ("DC", "date", !ExpName, " ", \
                    "++++Print the CFLog, then type CONT+++", *!S)
          Halt
          @Message ("DC", "date", !ExpName, " ", \
                    "+Operator continue.", *!S)
       End If
     End If
  Return
End Procedure
-------------------------------------------------------------------------------<