PROC C_FL_CDHS_N
: VERSION 6
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: 	C_FL_CDHS_N
;#		   	CDS Name: 	CDS_CDHS
;#		   	CDS Issue:	V3.4
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  15-FEB-95
;#			    Revision:  1.  6-APR-95	MH
;#						2.  1-MAY-95	MH
;#						3. 17-MAY-95	MH
;#						4. 03-JUN-95   BS
;#						5. 01-Sept-95  TFM
;#						6. 27-OCT-95   TFM
;#
;#		1.3	Change Description:	
;#
;#			1. Added section delimiters. Corrected typos from experimenters
;#			   comments.  Deleted copy of section 3.3.  Added WAIT to
;#			   section 1.4 for processing delay.
;#			2. Changed OBT distribution from K_OBT_DIST to /KNK12000 in
;#			   sections 1.1, 2.1, 3.1.
;#			3. Deleted sections 1 and 2 for GSCT2 after direction from CDS
;#			   team.
;#			4. Update TM checks for: CKCNOEVT,CIEC+5V- add lower bound of 
;#			   zero. for CIEC+5V for GIS data capture upper bound now 1150.
;#			5. Updated header information and changed WAIT 10 to WAIT UNTIL 
;# 			   TCBUF emepty. 
;#             6. Changed ts in name to fl.
;#
;#		1.4	Point of Contact:	CCazeau
;#			FOT Author:  MHill	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			To test the Command and Data Handling System (CDHS) for CDS 
;#			(Nominal Side).
;#
;#		2.2	Intended Use:
;#
;#			To perform the CDS Module of the SFT.
;#
;#		2.3	Duration:	?
;#
;#		2.4	References: pages I_EXP_STAT, C_CDHS_HARDWARE, C_CDHS_SWHK,
;#		     		  C_CDS_STATUS_HK
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			NONE
;#
;#		3.3	Special Constraints or Activities
;#
;#			NONE
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

WAIT UNTIL (CKCMODE = H'10')	;Verify CDS in SNOOZE mode.


;******SECTION 3******

WAIT	;GO TO REBOOT, CONFIGURE WITH PU1 PRIMARY
/CCCRSETN		;CDHS Reset (Nom)
/CZCPRPU1		;Select Primary Interface Processor 1
WAIT		;Verify command buffer contents
/SEND
WAIT 15

/CB0CLER		;Bootstrap clear EPROM Reload
WAIT		;Verify command buffer contents
/SEND

WAIT 30		;For Boot to Complete


;******SECTION 3.1******


/KNK12000,0800	;To set CDS LOBT (Replaces CBSLOBT)
WAIT		;Verify command buffer contents
/SEND

WAIT UNTIL (P@CSCLOBT = "RECEIVED")		;= 1 LOBT in lock


;******SECTION 3.2******

WAIT	;GO TO CHECK POWER CONFIGURATION REGISTER
WAIT UNTIL (P@CSCSCIF = "PRIMARY")	;SCIF Selection
WAIT UNTIL (P@CSCPU1 = "ON")		;Processor Unit 1 Power
WAIT UNTIL (P@CSCPU2 = "OFF")		;Processor Unit 2 Power
WAIT UNTIL (P@CSCPU3 = "OFF")		;Processor Unit 3 Power
WAIT UNTIL (P@CSCIMIP = "ON")		;Primary IMIF ON/OFF Status
WAIT UNTIL (P@CSCIMIR = "OFF")		;Redundant IMIF ON/OFF Status
WAIT UNTIL (P@CSCPROM = "OFF")		;EPROM Power
WAIT UNTIL (P@CSCPU1R = "DISABLED")		;Processor Unit 1 RAM
WAIT UNTIL (P@CSCPU2R = "DISABLED")		;Processor Unit 2 RAM
WAIT UNTIL (P@CSCPU3R = "DISABLED")		;Processor Unit 3 RAM
WAIT UNTIL (P@CSCGDC = "OFF")		;Grazing Data Capture Power
WAIT UNTIL (P@CSCVI = "OFF")		;Viewfinder I/F Power
WAIT UNTIL (P@CSCVM1 = "OFF")		;Viewfinder Memory 1 Power
WAIT UNTIL (P@CSCVM2 = "OFF")		;Viewfinder Memory 2 Power

WAIT UNTIL ((CKCNOEVT > 0) AND (CKCNOEVT < 9))  	;Check Number of Events
WAIT UNTIL (P@CSCPWR1 = "COLDSTART")	;Power ON 1 Status
WAIT UNTIL (P@CSCPWR2 = "COLDSTART")	;Power ON 2 Status

WAIT UNTIL (P@CSCPAR = "ENABLED")	;Processor Unit 1 Parity

WAIT UNTIL (CKCCMDBV = 1)    		;Number of Valid Block Commands
WAIT UNTIL (CKCCMDWV = 3)    		;Number of Valid Command words
WAIT UNTIL (CKCCMDBI = 0)    		;Number of Invalid Block Commands

WAIT UNTIL (CKCMODE = H'10')		;Snooze Mode
/CB5ZZZ		;Hold in Snooze Mode
WAIT		;Verify command buffer contents
/SEND

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

/CBENOOP	;NO OP Command
/CBENOOP	;NO OP Command
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (CKCCMDBV = 4)    		;Number of Valid Block Commands


;******SECTION 3.3******

WAIT UNTIL ((P@'CIEC+5V' < 950) AND (P@'CIEC+5V' > 0))  ;CDHS +5V Current


;******SECTION 3.5******

WAIT	;GO TO LINK TO PU2 AS SECONDARY PROCESSOR
/CBCPU2N	;Processor 2 ON
WAIT		;Verify command buffer contents
/SEND	
WAIT UNTIL (P@CIPWA > 0.33) AND (P@CIPWA < 0.37)	;Check LCL A current
WAIT UNTIL (P@'CIEC+5V' > 1100) AND (P@'CIEC+5V' < 1300)	;CDHS +5V Current

/CBCPU2RS	;Processor 2 Reset
/CB9SECLD,0003		;Load Secondary, Link 3
WAIT		;Verify command buffer contents
/SEND	
WAIT UNTIL (P@CS9LOAD = "OK")	;Transputer Load Status

/CBCPU2F	;Processor 2 Off
/CB9RST		;Reset 2T module err flags, = 0003
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CS9LOAD = "_")	;Transputer Load Status


;******SECTION 3.6******

WAIT	;GO TO LINK TO PU3 AS SECONDARY PROCESSOR
/CBCPU3N	;Processor 3 ON
WAIT		;Verify command buffer contents
/SEND	
WAIT UNTIL (P@CIPWA > 0.33) AND (P@CIPWA < 0.37)	;Check LCL A current
WAIT UNTIL (P@'CIEC+5V' > 1100) AND (P@'CIEC+5V' < 1300)	;CDHS +5V Current

/CBCPU3RS	;Processor 3 Reset
/CB9SECLD,0001		;Load Secondary, Link 1
WAIT		;Verify command buffer contents
/SEND	
WAIT UNTIL (P@CS9LOAD = "OK")	;Transputer Load Status

/CBCPU3F	;Processor 3 Off
/CB9RST		;Reset 2T module err flags, = 0003
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CS9LOAD = "_")	;Transputer Load Status


;******SECTION 4******

WAIT		;GO TO BEGIN CDHS MODULES POWER CHECK
;VDS INTERFACE
/CBCVIN	;VDS I/F Power ON
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCVI = "ON")    	;Verify Viewfinder I/F Power
WAIT UNTIL ((P@'CIEC+5V' < 1000) AND (P@'CIEC+5V' > 0))
							;CDHS +5V Current (Approx 961 mA)

/CBCVISP	;VDS I/F Select Primary
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCVIS = "PRIMARY")	;Verify Viewfinder I/F Primary/Red. select

/CBCVISR	;VDS I/F Select Redundant
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCVIS = "REDUND")	;Verify Viewfinder I/F Primary/Red. select

/CBCVIF	;VDS I/F Power OFF
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCVI = "OFF") 


;VDS BUS
/CBCVBUSN	;VDS Bus ON
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCVBUS = "ON")		;Verify Viewfinder Bus Status
WAIT UNTIL ((P@'CIEC+5V' < 900) AND (P@'CIEC+5V' > 0))	
							;CDHS +5V Current (Approx 872 mA)

/CBCVBUSF	;VDS Bus OFF
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCVBUS = "OFF")	;Verify Viewfinder Bus Status


;VDS MEMORY CARD 1
/CBCVM1N	;VDS Memory 1 ON
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCVM1 = "ON")	;Viewfinder Memory 1 Power
WAIT UNTIL ((P@'CIEC+5V' < 1200) AND (P@'CIEC+5V' > 0))
							;CDHS +5V Current

/CBCVM1F	;VDS Memory 1 OFF
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCVM1 = "OFF")	;Viewfinder Memory 1 Power


;VDS MEMORY CARD 2
/CBCVM2N	;VDS Memory 2 ON
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCVM2 = "ON")	;Viewfinder Memory 2 Power
WAIT UNTIL (P@'CIEC+5V' < 1200)	;CDHS +5V Current

/CBCVM2F	;VDS Memory 2 OFF
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCVM2 = "OFF")	;Viewfinder Memory 2 Power


;GIS DATA CAPTURE
/CBCGDCN	;GIS Data Capture ON
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCGDC = "ON")	;Grazing Data Capture Power
WAIT UNTIL ((P@'CIEC+5V' < 1150) AND (P@'CIEC+5V' > 0))	;CDHS +5V Current

/CBCGDCSP	;GIS DC Select Primary
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCGDCS = "PRIMARY")	;Primary/Red GIDC Select

/CBCGDCSR	;GIS DC Select Redundant
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCGDCS = "REDUND")	;Primary/Red GIDC Select

/CBCGDCF	;GIS Data Capture OFF
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCGDC = "OFF")	;Grazing Data Capture Power


;GIS BUS
/CBCGBUSN	;GIS DC BUS ON
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCGBUS = "ON")	;GIS Bus
WAIT UNTIL ((P@'CIEC+5V' < 900) AND (P@'CIEC+5V' > 0))		;CDHS +5V Current

/CBCGBUSF	;GIS DC BUS OFF
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCGBUS = "OFF")	;GIS Bus


;PROM
/CBCPROMN	;EPROM ON
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCPROM = "ON")	;Verify EPROM Power
WAIT UNTIL ((P@'CIEC+5V' < 900) AND (P@'CIEC+5V' > 0))		;CDHS +5V Current

/CBCPROMF	;EPROM OFF
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCPROM = "OFF")	;Verify EPROM Power


;******SECTION 5******

WAIT		;GO TO CHECK COMMAND COUNTERS
WAIT UNTIL (CKCCMDBV = 32)    	;Number of Valid Block Commands
WAIT UNTIL (CKCCMDBI = 0)    		;Number of Invalid Block Commands
WAIT UNTIL (CKCLCMD1 = H'1081')	;Check last command received
WAIT UNTIL (CKCLCMD2 = H'11E2')	;Check last command received -1

/CBENOOP	;NO OP Command	
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (CKCLCMD1 = H'2401')	;Check last command received
WAIT UNTIL (CKCLCMD2 = H'EEEE')	;Check last command received -1


;******SECTION 6******

WAIT		;GO TO RUN ESR Check
WAIT UNTIL (CSCESR = 0)	;ESR Acknowledge
/CBSESR	;Emergency S/C Request (blk,11,12,50,h0040,h10A2,hCCCC
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (CSCESR = H'CC')	;ESR Acknowledge = 204 Dec
WAIT UNTIL (CKCMODE = H'E0')	;Check CDS mode

/CB5ZZZ	;SNOOZE MODE
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (CKCMODE = H'10')	;Check CDS mode

OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		NONE
;#
;#**************************************************************************
RETURN
ENDPROC