PROC C_FL_DOORS
;Version 3
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: 	C_FL_DOORS
;#		   	CDS Name: 	CDS_MCU2
;#		   	CDS Issue:	
;#			Simulator Validation Status: COBS level only.
;#
;#		1.2	Date Created:  17-MAY-95
;#			    Revision:  1. 03-JUN-95	BS
;#						2. 07-AUG-95	MH
;#                            3. 27-OCT-95   TFM
;#		1.3	Change Description:	
;#
;#			1. Reverse order of TM checks for CIEU+27V and CSMPDOR. Add 
;#			   new upper and lower bound for CIEU+27V
;#			2. Add intended use, duration, page reference, correct S/C +27V
;#			   current TM check, deleted WAIT 5 at end of proc.
;#             3. Changed ts in name to fl.
;#		1.4	Point of Contact:	CCazeau
;#			FOT Author:  MHill	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure is derived from C_TS_MCU2 sections 21-24 for
;#			GSCT2.
;#
;#		2.2	Intended Use:
;#
;#			Test of CDS Doors.
;#
;#		2.3	Duration:	10 min
;#
;#		2.4	References: page C_MCU_HK1
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			/CBMDGOS - GIS Door Open is a critical command.
;#			/CBMDVOS - VDS Door Open is a critical command.
;#
;#		3.3	Special Constraints or Activities
;#
;#			None
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

;******SECTION 21******

;DOOR CONTROL REGISTER
/CBMDRINI		;Door Initialization (turns motor off), no power on reset
WAIT			;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSMDORGS = "SHUT")	;GIS Door Shut
WAIT UNTIL (P@CSMDORGO = "_")		;GIS Door Open (microswitches)
WAIT UNTIL (P@CSMDORVS = "SHUT")	;VDS Door Shut
WAIT UNTIL (P@CSMDORVO = "_")		;VDS Door Open

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

;DOOR POWER ON
/CBMPMDN		;Power Door ON
WAIT			;Verify command buffer contents
/SEND

WAIT UNTIL (P@CSMPDOR = "ON")		;Door Power Status
WAIT UNTIL ((P@'CIEU+27V' > 55.0) AND (P@'CIEU+27V' < 75.0))
							;Check S/C +27V Current

WAIT UNTIL (P@CSMDORGS = "SHUT")	;GIS Door Shut
WAIT UNTIL (P@CSMDORGO = "_")		;GIS Door Open (microswitches)
WAIT UNTIL (P@CSMDORVS = "SHUT")	;VDS Door Shut
WAIT UNTIL (P@CSMDORVO = "_")		;VDS Door Open


;******SECTION 22******

;GIS DOOR
/CBMDGOS		;GIS Door Open with solenoid
WAIT			;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSMDORGS = "_")		;GIS Door Shut
WAIT UNTIL (P@CSMDORGO = "OPEN")	;GIS Door Open

/CBMDGCT		;GIS Door close on timer
WAIT			;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSMDORGS = "SHUT")	;GIS Door Shut
WAIT UNTIL (P@CSMDORGO = "_")		;GIS Door Open


;******SECTION 23******

;VDS DOOR
/CBMDVOS		;VDS Door Open with solenoid
WAIT			;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSMDORVS = "_")		;VDS Door Shut
WAIT UNTIL (P@CSMDORVO = "OPEN")	;VDS Door Open

/CBMDVCT		;VDS Door close on timer
WAIT			;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSMDORVS = "SHUT")	;VDS Door Shut
WAIT UNTIL (P@CSMDORVO = "_")		;VDS Door Open


;******SECTION 24******

;OPEN DOORS BY EMERGENCY BACKUP SYSTEM
/CCEDORNN		;Emergency Door Relay ON (Nom)
WAIT			;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSSDORN = "ON")
WAIT UNTIL (P@CSMDORVO = "OPEN")	;VDS Door Open
WAIT UNTIL (P@CSMDORGO = "OPEN")	;GIS Door Open

/CBEDORF		;Emergency Door Relay OFF
WAIT			;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSSDORN = "OFF")

/CBMDVCT		;VDS Door close on timer
WAIT			;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSMDORVS = "SHUT")	;VDS Door Shut

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

/CBMDGCT		;GIS Door close on timer
WAIT			;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSMDORGS = "SHUT")	;GIS Door Shut

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

/CBMPMDF		;Power Door OFF
WAIT			;Verify command buffer contents
/SEND

OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None
;#
;#**************************************************************************
RETURN
ENDPROC