PROC C_FL_EMEROF
;VERSION 3
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: 	C_FL_EMEROF
;#		   	CDS Name: 	CDS_EMRGNCY
;#		   	CDS Issue:	v3.4
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  10-FEB-95
;#			    Revision:  1. 20-MAY-95	MH
;#                            2. 27-OCT-95   TFM
;#                            3. 10-DEC-95   TFM
;#
;#		1.3	Change Description:	
;#
;#			1. Added page reference. No TSTOL change.
;#             2. Changed ts in name to fl.
;#			3. Added call to start procedure k_exp_mon_dis.prc
;#			   Added more comments.
;#
;#		1.4	Point of Contact:	MHill
;#			FOT Author:  MHill	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			To turn off the power of CDS in an emergency.
;#
;#		2.2	Intended Use:
;#
;#			Quick procedure to turn CDS Off.  This procedure will allow
;#			CDS to power up in a normal mode when power is re-applied.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4	References: page I_EXP_STAT
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			NONE
;#
;#		3.3	Special Constraints or Activities
;#
;#			NONE
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

; If CDS is already off exit procedure.
IF ((p@CSPWA = "OFF") AND (p@CSPWB = "OFF")) GOTO OUT 

;--------------------------------------------
; CB5ESB ==> Emergency CDS Standby mode.
;--------------------------------------------
/CMD CB5ESB
WAIT ;Verify command buffer contents
/SEND
; Verify CDS Mode
WAIT UNTIL (CKCMODE = H'E0')

IF (p@CSPWA = "ON") THEN
     ;---------------------------------------
     ; The NOMinal LCL A is currently on.
     ; Disable the NOMinal CDS line
     ; experiment monitoring parameter.
     ;---------------------------------------
ELSEIF (p@CSPWB = "ON") THEN
     ;---------------------------------------
     ; The REDundant LCL B is currently on.
     ; Disable the REDundant CDS line
     ; experiment monitoring parameter.
     ;---------------------------------------
ELSE
ENDIF
;--------------------------------------------
; Type 'GO' to call the procedure to disable
; experiment monitoring for CDS.
;--------------------------------------------
WAIT ; Read message.

START K_EXP_MON_DIS

WAIT	;Go to power OFF LCLs.

IF (p@CSPWA = "ON") THEN
     ;---------------------------------------
     ; KNCPWAFN ==> Power OFF CDS A LCL
     ;              (Nominal side).
     ;---------------------------------------
     /CMD KNCPWAFN
     WAIT	;Verify command buffer contents 
     /SEND
     WAIT UNTIL (p@CSPWA = "OFF") TIMEOUT 60

     ; If still on try redundant command.
     IF (p@CSPWA = "ON") THEN
          ;----------------------------------
          ; KNCPWAFR ==> Power OFF CDS A LCL 
          ;              (Redundant side). 
          ;----------------------------------
          /CMD KNCPWAFR
          WAIT	;Verify command buffer contents 
          /SEND
          WAIT UNTIL (p@CSPWA = "OFF")
     ENDIF
ENDIF

IF (p@CSPWB = "ON") THEN
     ;---------------------------------------
     ; KNCPWBFN ==> Power OFF CDS B LCL
     ;              (Nominal side).
     ;---------------------------------------
     /CMD KNCPWBFN
     WAIT	;Verify command buffer contents 
     /SEND
     WAIT UNTIL (p@CSPWB = "OFF") TIMEOUT 60

     ; If still on try redundant command.
     IF (p@CSPWB = "ON") THEN
          ;----------------------------------
          ; KNCPWBFR ==> Power OFF CDS A LCL 
          ;              (Redundant side). 
          ;----------------------------------
          /CMD KNCPWBFR
          WAIT ;Verify command buffer contents 
          /SEND
          WAIT UNTIL (p@CSPWB = "OFF")
     ENDIF
ENDIF

OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		NONE
;#
;#**************************************************************************
RETURN
ENDPROC