PROC C_FL_EPS_N
; VERSION 6
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: 	C_FL_EPS_N
;#		   	CDS Name: 	CDS_EPS
;#		   	CDS Issue:	V3.4
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  14-FEB-95
;#			    Revision:  1. 30-MAR-95	MH
;#						2.  1-MAY-95	MH
;#						3. 17-MAY-95	MH
;#						4. 03-JUN-95   BS
;#						5, 01-Sept-95  TFM
;#                            6. 27-OCT-95   TFM
;#
;#		1.3	Change Description:	
;#
;#			1. Added section delimiters.  Deleted Filament 2 test from
;#			   section 8.  Made minor comment changes from experimenters.
;#			   Added SNAP directive to section 6.  Added page references.
;#			2. Changed OBT distribution from K_OBT_DIST to /KNK12000 in
;#			   section 3.  Added /CMSMSG, NRT TPUT RSUM, NRT TPUT PAUS 
;#			   directives to section 6.
;#			3. Deleted sections 1, 2, 3, 4 and 11 for GSCT2 after direction 
;#			   from CDS team.
;#			4. Correct TM checks for:CIEFIL,CIEU+27V,CTEE1-4, CTEC1-4
;#			   CIED+5V,C-ECN12V.
;#			5. Updated header info. And changed the CMSMG CDS 'VERIFY AUEVREF =
;#			   1.25' to 1.25. Changed C+EG12V < 0.1 to 0.00 and CIEC+5V > 850 to
;#			   853.15.
;#             6. Changed ts in name to fl.
;#		1.4	Point of Contact:	CCazeau
;#			FOT Author:  MHill	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure is a modified version of the EPS SFT.  Redundant
;#			power and commands have been deleted.  Power-on checks (performed
;#			in CDS_ON) also deleted.
;#
;#		2.2	Intended Use:
;#
;#			To perform the EPS module of the SFT. (Nominal)
;#
;#		2.3	Duration:	?
;#
;#		2.4	References: pages I_EXP_STAT, C_EPS_HK, C_CDS_STATUS_HK,
;#		   			C_CDHS_HARDWARE
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			/CBEGHVE to Enable GIS HV is a critical command.
;#			/CBEFILE to Enable Filaments is a critical command.
;#			/CBEFILN to Power Filament Supply On is a critical command.
;#
;#		3.3	Special Constraints or Activities
;#
;#			THIS PROCEDURE SHOULD BE RUN WHEN CDS IS OFF.  THIS PROCEDURE
;#			WILL POWER OFF CDS IF NOT ALREADY OFF.
;#			THIS PROCEDURE WILL NORMALLY BE RUN AS THE FIRST MODULE IN THE 
;#			CDS SFT.
;#
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF


;******SECTION 5******

WAIT		;GO TO TEST ISOLATION RELAYS
/CCEGHVDN	;GIS HV Disable (Nom)
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSSGHVN = "DISABLE")	

/CBEGHVE	;GIS HV Enable (Nom)
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSSGHVN = "ENABLE")	

WAIT 5

/CCEVDSDN	;VDS Disable
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSSVDSN = "DISABLE")

WAIT 5

/CBEVDSE	;VDS Enable
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSSVDSN = "ENABLE")

WAIT 5

/CCEFILDN	;Filaments Disable
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSSFILN = "DISABLE")

WAIT 5

/CBEFILE	;Filaments Enable
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSSFILN = "ENABLE")

WAIT 5

/CCEMECDN	;MCU Mechanisms disable
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSSMECN = "DISABLE")

WAIT 5

/CBEMECE	;MCU Mechanisms Enable
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSSMECN = "ENABLE")

WAIT UNTIL (P@CSSDORN = "OFF")	;Verify Door Relay OFF


;******SECTION 6******

/NRT TPUT RSUM
/CMSMSG CDS 'VERIFY AUEVREF = 1.25V'
WAIT	;VERIFY WITH CDS IWS (AUEVREF = 1.23V): IF NOT EPS MONITORS INACCURATE
/NRT TPUT PAUS

WAIT UNTIL (P@'C+ESC27V' >= 26.5) AND (P@'C+ESC27V' <= 29.0)	;S/C +27V
WAIT UNTIL (P@'C+ECN5V' >= 5.08) AND (P@'C+ECN5V' <= 5.28)	;Converter +5V
WAIT UNTIL (P@'C+ECN12V' >= 12.14) AND (P@'C+ECN12V' <= 12.34)	;Converter +12V
WAIT UNTIL (P@'C-ECN12V' >= -12.34) AND (P@'C-ECN12V' <= -12.18)	;Converter -12V

WAIT		;GO TO SNAP PAGE C_EPS_HK FOR PREVIOUS TM TO FILE C_EPS_HK.rpt
SNAP C_EPS_HK,,C_EPS_HK.RPT APPEND

WAIT UNTIL ((P@'CIEU+27V' > -0.01) AND (P@'CIEU+27V' < 0.01))	;+27V current
WAIT UNTIL (P@CTEE1 > 15) AND (P@CTEE1 < 30)	;EPS 1 Temp
WAIT UNTIL (P@CTEE2 > 15) AND (P@CTEE2 < 30)	;EPS 2 Temp
WAIT UNTIL (P@CTEE3 > 15) AND (P@CTEE3 < 30)	;EPS 3 Temp
WAIT UNTIL (P@CTEE4 > 15) AND (P@CTEE4 < 30)	;EPS 4 Temp


;******SECTION 6.1******

WAIT	;GO TO CHECK INITIAL RELAY STATUS
WAIT UNTIL (P@'C+EG12V' < 0.00)	;GIS +12V implies OFF
WAIT UNTIL (P@'C+EM12V' < 0.3)	;MCU +12V implies OFF


;******SECTION 7******

WAIT	;GO TO CHECK CDHS MONITORING BY EPS
WAIT UNTIL ((P@'CIEC+5V' < 950) AND (P@'CIEC+5V' > 853.15))	;CDHS +5V Current

WAIT UNTIL (P@CTEC1 > 15) AND (P@CTEC1 < 30)	;CDHS 1 TEMP
WAIT UNTIL (P@CTEC2 > 15) AND (P@CTEC2 < 35)	;CDHS 2 TEMP
WAIT UNTIL (P@CTEC3 > 15) AND (P@CTEC3 < 30)	;CDHS 3 TEMP
WAIT UNTIL (P@CTEC4 > 15) AND (P@CTEC4 < 30)	;CDHS 4 TEMP


;******SECTION 8******

WAIT		;GO TO RUN PRIME IMIF TESTS (CBEFIL 1/2 USED AS NOP, FIL POWER NOT ON)
/CBCIMIP	;Prime IMIF used for CDHS communications with EPS
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCIMIP = "ON")
WAIT 15
WAIT UNTIL (P@CSEISEL = "PRIMARY")

/CBEFIL1	;Filament 1 select
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSEFILS = "FIL1")

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

/CBEFIL2	;Filament 2 select
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSEFILS = "FIL2")

WAIT		;GO TO RUN RED. IMIF TESTS (CBEFIL 1/2 USED AS NOP, FIL POWER NOT ON)
/CBCIMIR	;Redundant IMIF used for CDHS communications with EPS
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSCIMIR = "ON")
WAIT 15
WAIT UNTIL (P@CSEISEL = "REDUND")

/CBEFIL1	;Filament 1 select
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSEFILS = "FIL1")

/CBCIMIP	;Prime IMIF used for CDHS communications with EPS
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSEISEL = "PRIMARY")


;******SECTION 9******

WAIT		;GO TO RUN IMIF RX ERROR TEST
/CBEINVAL	;Invalid command for testing (pattern = EEDD)
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSEIRXE = "ERROR")

/CBEIRXER	;EPS IMIF RX Error Reset
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSEIRXE = "_")


;******SECTION 10******

WAIT		;GO TO RUN FILAMENT SUPPLY TEST
WAIT		;VERIFY FILAMENTS ARE DISCONNECTED (FILAMENTS WILL BURN OUT IF NOT)
/CBEFILN	;Filament Supply ON
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSEFIL = "ON")

/CBEFILF	;Filament Supply OFF
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CSEFIL = "OFF")

/CBEFILI,7700	;Filament Intensity set to 0
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CIEFIL < 10)	;Verify Filament current
WAIT  
/CBEFILI,77FF	;Filament Intensity set to 255
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CIEFIL > 130) AND (P@CIEFIL < 150)	;Verify Filament current 141 Nom

/CBEFILI,7700	;Filament Intensity set to 0
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@CIEFIL < 10)	;Verify Filament current

OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		NONE
;#
;#**************************************************************************
RETURN
ENDPROC