PROC C_FL_OPENDOORS
;VERSION 0
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: 	C_FL_OPENDOORS	
;#		   	CDS Name:      C_TS_OPENDOORS	
;#		   	CDS Issue:	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  30-NOV-95
;#			    Revision:  
;#
;#		1.3	Change Description:	
;#
;#			None.
;#
;#		1.4	Point of Contact:	Jeff Pain
;#			FOT Author:  Tom Moore ATSC/SOHO 286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#            
;#             This procedure will open the VDS and GIS doors on the 
;#			CDS instrument, used after a S/C manoeuver.           
;#
;#		2.2	Intended Use:
;#             
;#			Called from the c_fl_man_rec procedure.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4	References: Memo to Rich Kavanagh from Eric Sawyer dated
;#                         24/AUG/95.
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			TBD
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

LOCAL standby,
LET standby = 32

IF (CKCMODE .NE. $standby) THEN
     ;---------------------------------------
     ; This procedure assumes that CDS in
     ; standby mode. CDS is NOT currently in
     ; standby mode. 
     ;---------------------------------------
     WAIT 15
     GOTO OUT
ELSE
     ;---------------------------------------          
     ; Start of CDS open doors procedure.
     ;---------------------------------------
     ;---------------------------------------
     ; CBMDRINI ==> Door register init.
     ;---------------------------------------
     /CMD CBMDRINI
     WAIT ; verfiy command buffer contents.
     /SEND
     WAIT 10

     ;---------------------------------------
     ; CBMPMDN ==> Power Door on.
     ;---------------------------------------
     /CMD CBMPMDN
     WAIT ; verfiy command buffer contents.
     /SEND
     WAIT 5
     ; Checks door is powered on.
     WAIT UNTIL (p@CSMPDOR .EQ. "ON")

     ;---------------------------------------
     ; CBMDVOS ==> Open VDS door.
     ;---------------------------------------
     /CMD CBMDVOS
     WAIT ; verfiy command buffer contents.
     /SEND
     ; Checks that VDS door is open.
     WAIT UNTIL (p@CSMDORVO .EQ. "OPEN")

     ;---------------------------------------
     ; CBMDGOS ==> Open GIS door.
     ;---------------------------------------
     /CMD CBMDGOS        
     WAIT ; verfiy command buffer contents.
     /SEND
     ; Checks that GIS door is open.
     WAIT UNTIL (p@CSMDORGO .EQ. "OPEN")
     
     ;---------------------------------------
     ; CBMPMDF ==> Power door off.
     ;---------------------------------------
     /CMD CBMPMDF
     WAIT ; verfiy command buffer contents.
     /SEND
     ; Checks door is powered off.
     WAIT UNTIL (p@CSMPDOR .EQ. "OFF")
ENDIF
    
OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;# Procedure C_FL_OPENDOORS is finished.
;#
;#**************************************************************************
RETURN
ENDPROC