PROC C_FL_PWRON_N
;# VERSION 7
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:   C_FL_PWRON_N
;#		   	CDS Name:   CDS_ON 
;#		   	CDS Issue:  v3.4  	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  6-FEB-95
;#			    Revision:  1. 21-FEB-95	MH
;#						2. 28-MAR-95	MH
;#						3.  1-MAY-95	MH
;#						4. 19-MAY-95	MH
;#						5. 03-JUN-95   BS
;#						6. 01-Sept-95  TFM
;#                            7. 27-OCT-95   TFM
;#		1.3	Change Description:	
;#
;#			1. Replaced /CBCSLOBT with K_OBT_DIST to set OBT
;#			2. Added section delimiters.  Edited command comments and WAIT 
;#			   from Experimenters. Added page references.
;#			3. Changed OBT distribution in section 3 from K_OBT_DIST to
;#			   /KNK12000.
;#			4. Deleted LCL Power Off command for CDS A.  Added call to 
;#			   S K_EXP_MON_ENA to Enable experiment monitoring and
;#			   corrective action at end of procedure.
;#			5. Add lower bound to check for CIEU+27V.
;#			6. Changed header info. and C-ECN12V  & C+EG12V from .GT. to .GE..
;#             7. Changed ts in name to fl.
;#		1.4	Point of Contact:	CCazeau
;#			FOT Author:  MHill	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			Power On of CDS (Nominal)
;#
;#		2.2	Intended Use:
;#
;#			Normal Power On sequence of CDS (Nominal Case)
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References: pages I_EXP_STAT, C_CDS_STATUS_HK, C_CDHS_HARDWARE,
;#		   		C_EPS_HK
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			NONE
;#
;#		3.3	Special Constraints or Activities
;#
;#			If procedure fails during check of Isolation Relay Status, then
;#			run procedure C_FL_SAFE before C_FL_PWRON_N
;#
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (p@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF


;******SECTION 1******

IF (p@CSPWB = "ON") THEN
	/KNCPWBFN		;CDS B LCL Power Off (Nominal)
	WAIT		;Verify command buffer contents
	/SEND
	WAIT UNTIL (p@CSPWB = "OFF")
ENDIF


;******SECTION 2.1******

WAIT		;GO TO BEGIN POWER ON SEQUENCE

/CCPWRAN		;CDS Changeover Relay To A Power (Nomianl)
/KNCPWANN		;CDS A LCL Power On (Nominal)
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (p@CSPWA = "ON")	;Verify CDS A Powered ON
WAIT UNTIL (p@CIPWA > 0.3) AND (p@CIPWA < 0.6)	;Check between .3 and .6 A

WAIT 5

/CCCRSETN		;CDHS Processor Reset (Nominal)
/CZCPRPU1		;Select Primary Interface Processor 1
WAIT		;Verify command buffer contents
/SEND

WAIT 15

/CB0CLER		;Clear and Boot from EPROM (blk,11,12,50,h0040,h1222,h0001)
WAIT		;Verify command buffer contents
/SEND

WAIT 30		;For Boot to complete

WAIT UNTIL (p@CIPWA > 0.25) AND (p@CIPWA < 0.3)	;Check between .25 and .3 A


;******SECTION 3******

WAIT		;GO To Set LOBT for CDS
/KNK12000,0800	;distribute OBT to CDS
WAIT		;Verify command buffer contents
/SEND

WAIT 15
WAIT UNTIL (p@CSCLOBT = "RECEIVED")	;Verify CDS LOBT received

/CB5ZZZ		;CDS Snooze Mode
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (CKCMODE = H'10')	;Check CDS Mode


;******SECTION 4.1******

;CHECK NOMINAL ISOLATION RELAY STATUS (IF ANY FAIL RUN C_FL_SAFE):
WAIT UNTIL (p@CSSGHVN = "ENABLE")	
WAIT UNTIL (p@CSSVDSN = "ENABLE")
WAIT UNTIL (p@CSSFILN = "ENABLE")
WAIT UNTIL (p@CSSMECN = "ENABLE")
WAIT UNTIL (p@CSSDORN = "OFF")


;******SECTION 5******

;CHECK EPS RELAY INITIAL STATUS:
WAIT UNTIL (p@CSEVHV = "OFF") 	;Verify VDS HV OFF
WAIT UNTIL (p@CSEVHTR = "OFF")	;Verify VDS Heater OFF
WAIT UNTIL (p@CSEGHV1 = "OFF")	;Verify GIS HV 1 +27V Relay OFF
WAIT UNTIL (p@CSEGHV2 = "OFF")	;Verify GIS HV 2 +27V Relay OFF
WAIT UNTIL (p@CSEGHV3 = "OFF")	;Verify GIS HV 3 +27V Relay OFF
WAIT UNTIL (p@CSEGHV4 = "OFF")	;Verify GIS HV 4 +27V Relay OFF
WAIT UNTIL (p@CSEVDS = "OFF") 	;Verify VDS Elec +27V Relay OFF
WAIT UNTIL (p@CSEVSBY = "OFF")	;Verify VDS Standby +27V Relay OFF
WAIT UNTIL (p@CSECOMP = "OFF")	;Verify Compens. Heat (VDS Ballast) Relay OFF
WAIT UNTIL (p@CSEM5V = "OFF") 	;Verify MCU +5V Relay OFF
WAIT UNTIL (p@CSEG5V = "OFF") 	;Verify GIS +5V Relay OFF
WAIT UNTIL (p@CSEHTRS = "OFF")	;Verify Oper. Heater Power +27V Relay OFF
WAIT UNTIL (p@CSEFIL = "OFF") 	;Verify Filament Relay OFF
WAIT UNTIL (p@CSEIRXE = "_")  	;Verify Logic Receive Error Status (No error)
WAIT UNTIL (p@'C+EG12V' >= 0.0) AND (p@'C+EG12V' < 0.1) ;Verify GIS +12V between 
			;0.0 and 0.1 V
WAIT UNTIL (p@'C+EM12V' > 0.0) AND (p@'C+EM12V' < 0.3) ;Verify MCU +12V between 
			;0.0 and 0.3 V


;******SECTION 6******

;CHECK POWER CONVERTERS AND SUPPLY VOLTAGE:
WAIT UNTIL (p@'C+ESC27V' > 26.5) AND (p@'C+ESC27V' < 29.0)	;Verify +27V Voltage 
			;between 26.5 and 29.0 volts
WAIT UNTIL (p@'C+ECN5V' > 5.08) AND (p@'C+ECN5V' < 5.28)	;Verify +5V Conv.
			;Voltage between 5.08 and 5.28 volts
WAIT UNTIL (p@'C+ECN12V' > 12.08) AND (p@'C+ECN12V' < 12.28) ;Verify +12V Conv.
			;Voltage between 12.08 and 12.28 volts
WAIT UNTIL (p@'C-ECN12V' >= -12.28) AND (p@'C-ECN12V' < -12.08) ;Verify -12V Conv.
			;Voltage between -12.28 and -12.08 volts
WAIT UNTIL ((p@'CIEU+27V' < 10) AND (p@'CIEU+27V' > -10)) 	;Verify +27V current 
			;between 10 and -10 milliamps.

;******SECTION 7******

;CHECK EPS MONITORED TEMPS:
WAIT UNTIL (p@CTEE1 > 0.0) AND (p@CTEE1 < 25.0)	;Verify EPS Temp 1
WAIT UNTIL (p@CTEE2 > 0.0) AND (p@CTEE2 < 25.0)	;Verify EPS Temp 2
WAIT UNTIL (p@CTEE3 > 0.0) AND (p@CTEE3 < 25.0)	;Verify EPS Temp 3
WAIT UNTIL (p@CTEE4 > 0.0) AND (p@CTEE4 < 25.0)	;Verify EPS Temp 4
WAIT UNTIL (p@CTEC1 > 0.0) AND (p@CTEC1 < 25.0)	;Verify CDHS Temp 1
WAIT UNTIL (p@CTEC2 > 0.0) AND (p@CTEC2 < 25.0)	;Verify CDHS Temp 2
WAIT UNTIL (p@CTEC3 > 0.0) AND (p@CTEC3 < 25.0)	;Verify CDHS Temp 3
WAIT UNTIL (p@CTEC4 > 0.0) AND (p@CTEC4 < 25.0)	;Verify CDHS Temp 4


;******SECTION 8******

;CHECK CDHS I:
WAIT UNTIL (p@'CIEC+5V' > 800) AND (p@'CIEC+5V' < 950)	;CDHS +5V Current


START K_EXP_MON_ENA	;Enable experiment monitoring and corrective action 

OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		NONE
;#
;#**************************************************************************
RETURN
ENDPROC