PROC C_FL_SHUTDOORS
;VERSION 0
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: 	C_FL_SHUTDOORS	
;#		   	CDS Name:      C_TS_SHUTDOORS	
;#		   	CDS Issue:	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  30-NOV-95
;#			    Revision:  
;#
;#		1.3	Change Description:	
;#
;#			None.
;#
;#		1.4	Point of Contact:	Jeff Pain
;#			FOT Author:  Tom Moore ATSC/SOHO 286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#            
;#             This procedure will shut the VDS and GIS doors on the 
;#			CDS instrument in preparation for a S/C manoeuver.           
;#
;#		2.2	Intended Use:
;#             
;#			Called from the c_fl_manprep procedure.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4	References: Memo to Rich Kavanagh from Eric Sawyer dated
;#                         24/AUG/95.
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			C_TS_SHUTDOORS
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			TBD
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

LOCAL standby,
LET standby = 32

IF (CKCMODE .NE. $standby) THEN
     ;---------------------------------------
     ; This procedure assumes that CDS in
     ; standby mode. CDS is NOT currently in
     ; standby mode. 
     ;---------------------------------------
     WAIT 15
     GOTO OUT
ELSE
     ;---------------------------------------          
     ; Start of CDS shut doors procedure.
     ;---------------------------------------
     ;---------------------------------------
     ; CBMDRINI ==> Door register init.
     ;---------------------------------------
     /CMD CBMDRINI
     WAIT ; verfiy command buffer contents.
     /SEND
     WAIT 10

     ;---------------------------------------
     ; CBMPMDN ==> Power Door on.
     ;---------------------------------------
     /CMD CBMPMDN
     WAIT ; verfiy command buffer contents.
     /SEND
     WAIT 5
     ; Checks door is powered on.
     WAIT UNTIL (p@CSMPDOR .EQ. "ON")

     ;---------------------------------------
     ; CBMDVCT ==> Shut VDS door.
     ;---------------------------------------
     /CMD CBMDVCT
     WAIT ; verfiy command buffer contents.
     /SEND
     ; Checks that VDS door is shut.
     WAIT UNTIL (p@CSMDORVS .EQ. "SHUT")

     ;---------------------------------------
     ; CBMDGCT ==> Shut GIS door.
     ;---------------------------------------
     /CMD CBMDGCT        
     WAIT ; verfiy command buffer contents.
     /SEND
     WAIT UNTIL (p@CSMDORGS .EQ. "SHUT")
     
     ;---------------------------------------
     ; CBMPMDF ==> Power door off.
     ;---------------------------------------
     /CMD CBMPMDF
     WAIT ; verfiy command buffer contents.
     /SEND
     ; Checks door is powered off.
     WAIT UNTIL (p@CSMPDOR .EQ. "OFF")
ENDIF
    
OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;# Procedure C_FL_SHUTDOORS is finished.
;#
;#**************************************************************************
RETURN
ENDPROC