PROC C_FL_VDS
; VERSION 8
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: 	C_FL_VDS
;#		   	CDS Name: 	CDS_VDS
;#		   	CDS Issue:	V3.4
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  1-MAR-95
;#			    Revision:  1.  8-MAR-95	MH
;#						2. 20-APR-95	MH	
;#						3.  9-MAY-95	MH
;#						4. 17-MAY-95	MH
;#						5. 03-JUN-95   BS
;# 						6. 01-Sept-95	TFM 
;#                            7. 16-Oct-95   TFM
;#                            8. 27-OCT-95   TFM
;#		1.3	Change Description:	
;#
;#			1.  Added reference pages
;#			2.  Added section delimiters.  In section 10, data words 8000
;#			    and 007C were reversed.  In section 11, deleted BS2VHK WAIT
;#			    and TC CB2DMPV and added comment to next WAIT.  Added CMSMSG
;#			    to sections 2.1, 3, 3.1, 4.1, 5, 10, 11.
;#			3.  Deleted TM checks for C+V5VSB and CIV+5VSB.  Made TM check
;#			    for CIV-12V a CDS IWS check.  Added /NRT TPUT RSUM and 
;#			    /NRT TPUT PAUS directives before and after /CMSMSG directives
;#			    in sections 2, 2.1, 3, 3.1, 4.1, 5, 10, and 11.  Added TM 
;#			    comments for CDS iWS checks in sections 2.1, 3, and 4.1
;#			4.  Deleted High Voltage On command which had been commented
;#			    out.
;#			5.  Change discrete states for CSVPIFE, CSVLPWRE to ENABLED.
;#			6.  Fixed some greater than symbol which should have been less than
;#			    symbols. 
;#             7. Add a wait 15 secconds between 
;#                WAIT UNTIL (p@CSEVDS = "ON")
;#                WAIT UNTIL (p@'CIEU+27V' > 390) AND (p@'CIEU+27V' < 430)	;420mA Nom
;#                As requested by PI. Changed / to /CMD for commands. Moved comments
;#                so they will fit in the event window.
;#             8. Changed ts in name to fl.
;#		1.4	Point of Contact:	CCazeau
;#			FOT Author:  MHill	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			Test of the VDS detector subsystem to be used when CDS is fully
;#			integrated.
;#
;#		2.2	Intended Use:
;#
;#			To test the VDS detector subsystem
;#
;#		2.3	Duration: ?
;#
;#		2.4	References:	pages C_VDSHK,  C_CDS_STATUS_HK
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			NONE
;#
;#		3.3	Special Constraints or Activities
;#
;#			VDS ARMING PLUG OUT - RED TAG ITEM
;#			VDS Enable Relay ON
;#			CDS in Snooze Mode
;#
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (p@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF
; CDS in Snooze Mode
WAIT UNTIL (CKCMODE = H'10')


;******SECTION 1******

;POWER ON
;Isolation relay
WAIT UNTIL (p@CSSVDSN = "ENABLE")

; IMIF primary
/CMD CBCIMIP
WAIT ;Verify command buffer contents
/SEND

WAIT 5

; VDS Standby Power ON
/CMD CBEVSBYN
WAIT ;Verify command buffer contents
/SEND

; Relay ON/OFF +27V VDS Elec
WAIT UNTIL (p@CSEVSBY = "ON")

WAIT 5
; VDS Main Supply On
/CMD CBEVDSN
WAIT ;Verify command buffer contents
/SEND
WAIT UNTIL (p@CSEVDS = "ON")
WAIT 15
;420mA Nom
WAIT UNTIL (p@'CIEU+27V' > 390) AND (p@'CIEU+27V' < 430)

WAIT 10
; CDS NOOP
/CMD CBVNOOP
WAIT ;Verify command buffer contents
/SEND
; 490mA Nom
WAIT UNTIL (p@'CIEU+27V' > 480) AND (p@'CIEU+27V' < 510)


;******SECTION 2******

;ANALOG MONITOR CHECKS
; 4.96V Nom
WAIT UNTIL (p@'C+V5V' > 4.9) AND (p@'C+V5V' < 5.1)
; 222mA Nom
WAIT UNTIL (p@'CIV+5V' > 190) AND (p@'CIV+5V' < 250)
;11.89V Nom
WAIT UNTIL (p@'C+V12V' > 11.8) AND (p@'C+V12V' < 11.89)
;207mA Nom
WAIT UNTIL (p@'CIV+12V' > 180) AND (p@'CIV+12V' < 240)
;-11.93V Nom
WAIT UNTIL (p@'C-V12V' > -12.2) AND (p@'C-V12V' < -11.92)
;-193mA Nom
;WAIT UNTIL (p@'CIV-12V' > -230) AND (p@'CIV-12V' < -170)
;13.43V Nom
WAIT UNTIL (p@'CUV+CLK' > 13.3) AND (p@'CUV+CLK' < 13.7)
;28mA Nom
WAIT UNTIL (p@'CIV+CLK' > 25) AND (p@'CIV+CLK' < 35)
;-13.52V Nom
WAIT UNTIL (p@'CUV-CLK' > -13.7) AND (p@'CUV-CLK' < -13.3)
;-37mA Nom
WAIT UNTIL (p@'CIV-CLK' > -40) AND (p@'CIV-CLK' < -30)

WAIT UNTIL (p@'C+V28V' > 26) AND (p@'C+V28V' < 29)
;8mA Nom
WAIT UNTIL (p@'CIV+28V' > 6) AND (p@'CIV+28V' < 10)

/NRT TPUT RSUM
/CMSMSG CDS 'VERIFY CIV-12V > -230) AND CIV-12V < -170'
WAIT ;for CDS IWS verification

;******SECTION 2.1******

/CMSMSG CDS 'Perform necessary analog monitor checks from section 2.1'
; -------------------------------------------
;AUV+SER = 8.0V +/- 0.1  ,7.91 MEASURED
;AUV-SER = -4.0V +/- 0.1  ,-4.04 MEASURED
;AUV+PTG = 7.0V +/- 0.1 ,6.93 MEASURED
;AUV-PTG = -5.0V +/- 0.1 ,-5.06 MEASURED
;AUV+PSPL = 3.5V +/- 0.1 , 3.45 MEASURED
;AUV-PSPL = -8.0V +/- 0.1 , -8.09 MEASURED
;AUV+PCOM = 5.5V +/- 0.1 , 5.42 MEASURED
;AUV-PCOM = -8.0V +/- 0.1 , -8.07 MEASURED
;AUVVDD = 24.0V +/- 0.2 , 23.99 MEASURED
;AUVVREF = 15.0V +/- 0.1 , 14.94 MEASURED
;AUV+RST = 12.0V +/- 0.2 , 11.90 MEASURED
;AUVBSLN = 1.65V +/- 0.05 , 1.64 MEASURED
;AUV+SWC = 8.0V +/- 0.1 , 7.95 MEASURED
;AUV-SWC = -3.0V +/- 0.1 , -3.02 MEASURED
;AUVLG = -2.0V +/- 0.1 , -2.06 MEASURED
;AUVMCPC = 0.0 +/- 0.1 , 0.04 MEASURED
;AIVMCP = 2uA +/- 2 , NB HV on or off
;ATVDIODE = -0.3V +/- 0.05
;AUVZREF = 7FFH +/- 1 , 7FF
; -------------------------------------------
;Check analog monitor check ok from CDS IWS
WAIT

;******SECTION 3******

/CMSMSG CDS 'Perform necessary status words checks from section 3'
; -------------------------------------------
;ASVCOMER = _
;ASVIVR = _
;ASVIEP = _
;ASVIWSQ = _
;ASVIWR = _
;ASVSERR = _
;ASVVIS = _
;ASVRGAF = _
;ASVRGBF = _
;ASVMALF = _
;ASVMODR = ERROR
;ASVRSTE = _
; -------------------------------------------
WAIT	;Status words checks - CDS IWS
/NRT TPUT PAUS

/CMD CBVRESET	
WAIT	;Verify command buffer contents
/SEND

WAIT UNTIL (p@CMD_STATE#TELECOMMAND = "AVAILABLE")

/NRT TPUT RSUM
/CMSMSG CDS ' CDS IWS check ASVMODR = _'
WAIT ;for CDS IWS TM check verification
/NRT TPUT PAUS


;******SECTION 3.1******

;STATUS WORDS 
;OP STATUS WORD = 1241h
;HK Lockout Enabled Status
WAIT UNTIL (p@CSVTLO = "DISABLED")
;Dark Exposure Mode Enabled Status
WAIT UNTIL (p@CSVDARK = "DISABLED")
;Secondary IMIF Chan Enabled Status
WAIT UNTIL (p@CSVSIFE = "DISABLED")
;Primary IMIF Chan Enabled Status
WAIT UNTIL (p@CSVPIFE = "ENABLED")
;Low Power Mode Enabled Status
WAIT UNTIL (p@CSVLPWRE = "DISABLED")
;Turbo Mode Enabled Status
WAIT UNTIL (p@CSVTRBE = "DISABLED")
;Heartbeat Enabled Status
WAIT UNTIL (p@CSVHBE = "ENABLED")
;Halt State
WAIT UNTIL (p@CSVHALT = "_")
;Integrate State
WAIT UNTIL (p@CSVINTG = "_")
;Flush State
WAIT UNTIL (p@CSVFLSH = "FLUSH")
;Windowing Enabled Status
WAIT UNTIL (p@CSVWINE = "DISABLED")
;Binning Enabled Status
WAIT UNTIL (p@CSVBINE = "DISABLED")
;High time Resolution Mode Enabled Status
WAIT UNTIL (p@CSVHTR = "DISABLED")
;3 LSBs
WAIT UNTIL (CSVRDM = 1)

/NRT TPUT RSUM
/CMSMSG CDS 'Perform necessary status words checks from section 3.1'
; -------------------------------------------
;AKVRECTM = 64H
;AKVBINXY = 0
;AKVNOWIN = 0
;AKVEXPTM = 0464H
; -------------------------------------------
WAIT ;for CDS IWS TM verification
/NRT TPUT PAUS

WAIT 5

;******SECTION 4******

;SET PROGRAMMABLE VOLTAGES
;Set Prog Voltage, Will be sent every 15 seconds
/CMD CBVVOLT,40A0
WAIT	;Verify command buffer contents
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,4182
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,42C8
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,435A
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,44B4
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,4546
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,46F0
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,4750
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,48A0
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,4982
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,4A64
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,4BF0
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,4CAA
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,4D55
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,4E82
/SEND

WAIT 15
;Set Prog Voltage
/CMD CBVVOLT,4F80
/SEND

WAIT 15


;******SECTION 4.1******

/NRT TPUT RSUM
/CMSMSG CDS 'Check programmed voltages from section 4.1'
; -------------------------------------------
;AUV+SER = 2.62V +/- 0.1  ,2.62 MEASURED
;AUV-SER = -0.03V +/- 0.1  ,0.03 MEASURED
;AUV+PTG = 5.63V +/- 0.1 ,5.63 MEASURED
;AUV-PTG = -2.85V +/- 0.1 ,-2.85 MEASURED
;AUV+PSPL = 4.1V +/- 0.1 , 4.09 MEASURED
;AUV-PSPL = -4.48V +/- 0.1 , -4.48 MEASURED
;AUV+PCOM = 8.8V +/- 0.1 , 8.79 MEASURED
;AUV-PCOM = -3.7V +/- 0.1 , -3.68 MEASURED
;AUVVDD = 15.8V +/- 0.1 , 15.77 MEASURED
;AUVVREF = 10.35V +/- 0.1 , 10.29 MEASURED
;AUV+RST = 10.0V +/- 0.2 , 9.98 MEASURED
;AUVBSLN = 4.4V +/- 0.05 , 4.40 MEASURED
;AUV+SWC = 3.3V +/- 0.1 , 3.29 MEASURED
;AUV-SWC = -3.2V +/- 0.1 , -3.23 MEASURED
;AUVLG = 0.4V +/- 0.1 , 0.37 MEASURED
;AUVMCPC = 4.5 +/- 0.1 , 4.49 MEASURED
; -------------------------------------------
WAIT	;check programmed voltages on CDS IWS
/NRT TPUT PAUS


;******SECTION 5******

;PROCESSOR RESET
/CMD CBVRESET
WAIT ;Verify command buffer contents
/SEND
WAIT 15

/NRT TPUT RSUM
/CMSMSG CDS 'CHECK AKVCAMTM < 40h FROM SECTION 5'
WAIT	;CDS check AKVCAMTM < 40h
/NRT TPUT PAUS

;******SECTION 6******

;IMIF CHANNEL SWITCHING
;VDS on Primary
WAIT UNTIL (p@CSVPIFE = "ENABLED")
;CDHS switch to redundant
/CMD CBCIMIR
WAIT	;Verify command buffer contents
/SEND
WAIT 15
;Indicates VDS has switched
WAIT UNTIL (p@CSVSIFE = "ENABLED")
;VDS on Primary
WAIT UNTIL (p@CSVPIFE = "DISABLED")
;Set operation mode
/CMD CBVOPERA,A000
WAIT	;Verify command buffer contents
/SEND
;Heartbeat Enabled Status
WAIT UNTIL (p@CSVHBE = "DISABLED")
;IMIF Prime
/CMD CBCIMIP
WAIT	;Verify command buffer contents
/SEND
WAIT 15
;Indicates VDS has not switched
WAIT UNTIL (p@CSVSIFE = "ENABLED")
;VDS on Primary
WAIT UNTIL (p@CSVPIFE = "DISABLED")
;CDHS switch back to redundant
/CMD CBCIMIR
WAIT	;Verify command buffer contents
/SEND

WAIT UNTIL (p@CMD_STATE#TELECOMMAND = "AVAILABLE")
;Set operation mode
/CMD CBVOPERA,A004
WAIT	;Verify command buffer contents
/SEND
;Heartbeat Enabled Status
WAIT UNTIL (p@CSVHBE = "ENABLED")
;Switch back to IMIF Prime
/CMD CBCIMIP
WAIT	;Verify command buffer contents
/SEND
WAIT 15
;Indicates VDS has not switched
WAIT UNTIL (p@CSVSIFE = "DISABLED")
;VDS on Primary
WAIT UNTIL (p@CSVPIFE = "ENABLED")


;******SECTION 7******

;SWITCH TO TURBO MODE
;Set operation mode to Turbo mode
/CMD CBVOPERA,A005
WAIT	;Verify command buffer contents
/SEND
WAIT UNTIL (p@'CIEU+27V' > 470) AND (p@'CIEU+27V' < 570)
;Turbo Mode Enabled Status	
WAIT UNTIL (p@CSVTRBE = "ENABLED")


;******SECTION 8******

;LOW POWER MODE
;Set operation mode to low power mode
/CMD CBVOPERA,A006
WAIT	;Verify command buffer contents
/SEND
WAIT UNTIL (p@'CIEU+27V' > 390) AND (p@'CIEU+27V' < 490)
;Low Power Mode Enabled Status
WAIT UNTIL (p@CSVLPWRE = "ENABLED")
;Set operation mode back to Turbo mode
/CMD CBVOPERA,A005
WAIT	;Verify command buffer contents
/SEND
WAIT UNTIL (p@'CIEU+27V' > 470) AND (p@'CIEU+27V' < 570)
;Turbo Mode Enabled Status	
WAIT UNTIL (p@CSVTRBE = "ENABLED")
;Low Power Mode Enabled Status
WAIT UNTIL (p@CSVLPWRE = "DISABLED")


;******SECTION 10******

;WATCHDOG RESET

/NRT TPUT RSUM
/CMSMSG CDS 'RECORD AKVCAMTM'
WAIT	;CDS RECORD AKVCAMTM
/NRT TPUT PAUS
;*F Poke
/CMD CBVMPOKE,007C,8000,0000,0000
WAIT	;Verify command buffer contents
/SEND
WAIT 5

/NRT TPUT RSUM
/CMSMSG CDS 'CHECK AKVCAMTM (< 40h  , POKE causes reset) FROM SECTION 10'
;CDS record AKVCAMTM 
WAIT	;(should be < 40H, POKE causes reset)
/NRT TPUT PAUS

;******SECTION 11******

;RAM CHECK
;Instruct VDS to dump all memory
/CMD CB2DMPV
WAIT	;Verify command buffer contents
/SEND
WAIT 5

/NRT TPUT RSUM
/CMSMSG CDS 'Check BS2VHK = MEMDUMP then NORMAL'
WAIT	;CDS Check BS2VHK = MEMDUMP then NORMAL
/NRT TPUT PAUS


;******SECTION 12******

;POWER OFF
;VDS HV Power supply OFF
/CMD CBEVHVF
WAIT	;Verify command buffer contents
/SEND
WAIT UNTIL (p@CSEVHV = "OFF")
;VDS Supply OFF
/CMD CBEVDSF
WAIT	;Verify command buffer contents
/SEND
WAIT UNTIL (p@CSEVDS = "OFF")
;VDS Standby OFF
/CMD CBEVSBYF
WAIT	;Verify command buffer contents
/SEND
WAIT UNTIL (p@CSEVSBY = "OFF")

OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		NONE
;#
;#**************************************************************************
RETURN
ENDPROC