PROC F_FL_CLS_ON_P
  ;VERSION 1
  GOTO BEGIN
  ;
  ;#***********************************************************************
  ;#      ****PROCEDURE HEADER****
  ;#
  ;#  1.0     Introduction
  ;#
  ;#          1.1     FOT Name:   F_FL_CLS_ON_P
  ;#                  MMS-F Name: -/-
  ;#                  SUM Issue:  -/-
  ;#
  ;#          1.2     Date Created: 16-OCT-95 (ABG)
  ;#                  Revision:     
  ;#
  ;#          1.3     Change Description:
  ;#
  ;#          1.4     Point of Contact:
  ;#                  FOT Author: BSAPPER ATSC/SOHO 286-4799
  ;#                  CELIAS Author:  AGALVIN UMD 301-405-6208
  ;#
  ;#***********************************************************************
  ;#  2.0     Description
  ;#
  ;#          2.1     Narrative Description: 
  ;#
  ;#		      Power on CELIAS into SAFE mode using DPU MAIN Bus and
  ;#                  nominal side current.
  ;#
  ;#          2.2     Intended Use:  
  ;#
  ;#		      TURN ON CELIAS EXPERIMENT SIDE A (PRIME)
  ;#
  ;#          2.3     Duration: 15 min.
  ;#
  ;#          2.4     References:
  ;#		
  ;#                  f_ts_pwron_pr.prc  (ground test version)
  ;#
  ;#***********************************************************************
  ;#  3.0     Instructions for Use:
  ;#
  ;#          3.1     Parameters Required: None
  ;#
  ;#          3.2     Critical Activities: 
  ;#
  ;#		      Verify that CELIAS is OFF before proceeding.
  ;#
  ;#		      Power line selection for the DPU must only take
  ;#		      place when CELIAS is off.  The cmds to select DPU
  ;#		      power are CRITICAL.
  ;#
  ;#          3.3     Special Constraints or Activities:
  ;#		      
  ;#		      The command for the DPU non-ops (substitution) heater
  ;#		      also affects the STOF-Electronics box non-ops heater.
  ;#		      If STOF is not to be turned on at the time of DPU
  ;#		      turn on, then the heater status should be discussed
  ;#		      with the experiment representative.
  ;#
  ;# *************************************************************************
  ;#  4.0     STEPS:

  BEGIN:

  IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
  ELSE
      /CLEAR  ;Clearing the Command Buffer.
  ENDIF

  ;#  4.1   Verify CELIAS is OFF

  WAIT UNTIL(P@FSPWA = "OFF")      ; CELIAS A STATUS
  WAIT UNTIL(P@FSPWB = "OFF")      ; CELIAS B STATUS		
  WAIT UNTIL(P@PS1PE = "ON")       ; PLM1 Experiment Bus 2
  WAIT       ;VERIFY CELIAS IS WITHIN OPERATIONAL TEMPERATURES
  WAIT UNTIL(P@QSFA = "OFF")	   ; CELIAS Substitution Heater A
  WAIT UNTIL(P@QSFB = "OFF")	   ; CELIAS Substitution Heater B

  ;#  4.2    Turn on CELIAS DPU

  /FCPWRAN			;Select DPU main power, nominal side
  WAIT	     ;VERIFY BUFFER CONTENTS
  /SEND

  WAIT 5

  /KNFPWANN			;Power on CELIAS LCL Nominal
  WAIT	     ;VERIFY BUFFER CONTENTS
  /SEND

  WAIT UNTIL(P@FSPWA = "ON")    ; CELIAS A Status
  WAIT UNTIL((P@FIPWA < 0.12) AND (P@FIPWA > 0.06))   ;current nominal side

  WAIT 60

  IF(FSDSWV < H'56')THEN
      /KNFPWAFN        ;LCL CELIAS A PWR OFF(N)
      WAIT             ;VERIFY BUFFER CONTENTS
      /SEND

      WAIT 30

      /KNFPWANN        ;LCL CELIAS A PWR ON(N)
      WAIT             ;VERIFY BUFFER CONTENTS
      /SEND

      WAIT UNTIL(P@FSPWA = "ON")
      WAIT UNTIL((P@FIPWA < 0.12) AND (P@FIPWA > 0.06))
      WAIT UNTIL(FSDSWV >=H'56')
  ENDIF  

  START K_EXP_MON_ENA		;Start proc to enable exp. monitoring

  ;#  4.3  Verify DPU turn on status is nominal for nominal side

  WAIT UNTIL(P@FSDESRD = "STANDBY")		;ESR response
  WAIT UNTIL(FSDPOC >= 1)			;DPU power on counter

  ; DPU classification calculations - requires about 10 minutes
  WAIT   ;VERIFY FSDIDLE starts at zero and ends at about 175-187 (69-73%)
  WAIT UNTIL(P@FSDJOB = "Idle")
 
  WAIT   ;VERIFY FSDEDBC (EDB) increments by 1 every 15 sec
  WAIT   ;VERIFY FSDHDBC increments by 1 every 15 sec,should be close to EDB

  WAIT UNTIL(FSDPEC = 0)			;Parity error count
  WAIT UNTIL(FSDCLMU1 = 1)			;Classification Mux
  WAIT UNTIL(FSDCLMU2 = 2)
  WAIT UNTIL(FSDCLMU3 = 3)

  WAIT UNTIL(FSDTTMUX = H'2000')

  WAIT UNTIL(P@FSDSPS1 = "Off")			;STOF power lines
  WAIT UNTIL(P@FSDSPS2 = "Off")
  WAIT UNTIL(P@FSDSPS3 = "Off")
  WAIT UNTIL(P@FSDSPM1 = "Off")			;MTOF power lines
  WAIT UNTIL(P@FSDSPM2 = "Off")
  WAIT UNTIL(P@FSDSPM3 = "Off")
  WAIT UNTIL(P@FSDSPC1 = "Off")			;CTOF power lines
  WAIT UNTIL(P@FSDSPC2 = "Off")

  WAIT UNTIL(P@FSDMODS = "Power Off")		;STOF mode Power Off
  WAIT UNTIL(P@FSDMODM = "Power Off")		;MTOF mode
  WAIT UNTIL(P@FSDMODC = "Power Off")		;CTOF mode

  WAIT UNTIL(FSDTCOK = 0)		;Command OK counter starts at 0
  WAIT UNTIL(FSDTCERR = 0)		;Command Error is zero
  WAIT UNTIL(FSDEXAD = 5)		;Experiment address is 5
  WAIT UNTIL(P@FSDTCHS1 = "<empty>")    ;Command Error History 1,2,3
  WAIT UNTIL(P@FSDTCHS2 = "<empty>")
  WAIT UNTIL(P@FSDTCHS3 = "<empty>")
  WAIT UNTIL(P@FSDSCECS = 0)		;STOF cmd errors
  WAIT UNTIL(P@FSDSCECM = 0)		;MTOF
  WAIT UNTIL(P@FSDSCECC = 0)		;CTOF

  WAIT UNTIL(P@FSDMEMS1 = "Not Tested")		;STOF memory state 
  WAIT UNTIL(P@FSDMEMS2 = "Not Tested")
  WAIT UNTIL(P@FSDMEMM1 = "Not Tested")		;MTOF memory state
  WAIT UNTIL(P@FSDMEMM2 = "Not Tested")
  WAIT UNTIL(P@FSDMEMC1 = "Not Tested")		;CTOF memory state
  WAIT UNTIL(P@FSDMEMC2 = "Not Tested")

  ;#   4.4   Send LOBT command

  /KNK12000,0400
  WAIT        ;VERIFY BUFFER CONTENTS
  /SEND

  WAIT        ;VERIFY FSDTCOK 0 -> 1 AFTER CMD RECEIVE
  WAIT	      ;VERIFY FKTMOBTS IS SYNCED WITH OBT

  ;#***********************************************************************
  ;#   5.0   Final Constraints
  ;#
  ;#         Verify non-ops heater status.
  ;#
  ;#	     Procedure f_fl_d_lud_on must be performed next.
  ;#
  ;#***********************************************************************
  ENDPROC