PROC F_FL_D_PATCH3
  ;Version 1
  GOTO BEGIN
  ;
  ;#***********************************************************************
  ;#      ****PROCEDURE HEADER****
  ;#
  ;#  1.0     Introduction
  ;#
  ;#          1.1     FOT Name:   F_FL_D_PATCH3
  ;#                  MMS-F Name: -/-
  ;#                  SUM Issue:  -/-
  ;#
  ;#          1.2     Date Created: 13-OCT-95 KR
  ;#                  Revision:     
  ;#
  ;#          1.3     Change Description:
  ;#
  ;#          1.4     Point of Contact:
  ;#                  Author: K.-U. Reiche IDA +49-531-391-3742
  ;#
  ;#***********************************************************************
  ;#  2.0     Description
  ;#
  ;#          2.1     Narrative Description: S/W patch 5.6.3
  ;#		  
  ;#		      DPU SOFTWARE PATCH NUMBER 5.6.3
  ;#		      MTOF MAIN RATES 5SEC GAP CORRECTION
  ;#
  ;#		      PLACE IN NON-VOLATILE MEMORY
  ;#
  ;#          2.2     Intended Use:
  ;#
  ;#		      Correction to DPU flight software (S/W Version 5.6).
  ;#	
  ;#          2.3     Duration: < 1 min.
  ;#
  ;#          2.4     References:
  ;#
  ;#***********************************************************************
  ;#  3.0     Instructions for Use:
  ;#
  ;#          3.1     Parameters Required: None
  ;#
  ;#          3.2     Critical Activities: 
  ;#
  ;#                  FBDMM commands are CRITICAL Commands.
  ;#		      Correct binary translation requires use of
  ;#		      Project Data Base Version > 9.0  (i.e., after Sept 95)
  ;#
  ;#          3.3     Special Constraints or Activities:
  ;#
  ;#		      This procedure needs to be run the FIRST time the
  ;#		      CELIAS is powered on.  As long as KEEP ALIVE power
  ;#		      is available, this command will be retained in
  ;#		      dpu memory.  
  ;#
  ;#                  This patch needed for dpu s/w version 5.6, may
  ;#		      not be required for higher versions.
  ;#
  ;#                  All sensors must be off.
  ;#
  ;# *************************************************************************
  ;#  4.0     STEPS:

  BEGIN:

  IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
  ELSE
      /CLEAR  ;Clearing the Command Buffer.
  ENDIF

  ;#  4.1   Verify sensors are OFF

  IF(P@FSDMODC <> "Power Off")THEN
      WRITE "*** CTOF IS ON ***"
      ASK "DO YOU NEED TO POWER OFF CTOF?"
      ANSWER = %UPPER(ANSWER)
      IF (ANSWER = "Y")THEN
	 /FBCMOD0I	  ; CTOF POWER OFF, IMMEDIATE
         WAIT             ; VERIFY BUFFER CONTENTS
         /SEND
         WAIT UNTIL (P@FSDMODC = "Power Off")
      ENDIF
  ENDIF

  IF(P@FSDMODM <> "Power Off")THEN
      WRITE "*** MTOF IS ON ***"
      ASK "DO YOU NEED TO POWER OFF MTOF?"
      ANSWER = %UPPER(ANSWER)
      IF (ANSWER = "Y")THEN
	 /FBMMOD0I	  ; MTOF POWER OFF, IMMEDIATE
         WAIT             ; VERIFY BUFFER CONTENTS
         /SEND
         WAIT UNTIL (P@FSDMODM = "Power Off")
      ENDIF
  ENDIF

  IF(P@FSDMODS <> "Power Off")THEN
      WRITE "*** STOF IS ON ***"
      ASK "DO YOU NEED TO POWER OFF STOF?"
      ANSWER = %UPPER(ANSWER)
      IF (ANSWER = "Y")THEN
	 /FBSMOD0I	  ; STOF POWER OFF, IMMEDIATE
         WAIT             ; VERIFY BUFFER CONTENTS
         /SEND
         WAIT UNTIL (P@FSDMODS = "Power Off")
      ENDIF
  ENDIF


  ;#  4.2    Implement s/w patch 3a, 3b

  /FBPERMI,0205           ; Make next command permanent, #5
  WAIT                    ; VERIFY BUFFER CONTENTS
  /SEND
  WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
  ; Patch 5.6.3a
  /FBDMM,ED06,3000,0010,3E83,4432,7400,0108,5087,1086,5297,;;
   C386,0000,0000,0000,0000,0000,0000,0000,0000,0000,;;
   0000,0000,0000,0000,0000,0000,0000,0000
  WAIT                    ; VERIFY BUFFER CONTENTS
  /SEND
  WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
  /FBPERMI,0206           ; Make next command permanent, #6
  WAIT                    ; VERIFY BUFFER CONTENTS
  /SEND

  WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
 ; Patch 5.6.3b
  /FBDMM,710F,3000,0003,F4E9,007B,0000,0000,0000,0000,0000,;;
   0000,0000,0000,0000,0000,0000,0000,0000,0000,0000,;;
   0000,0000,0000,0000,0000,0000,0000,0000
  WAIT                    ; VERIFY BUFFER CONTENTS
  /SEND

  ;#***********************************************************************
  ;#   5.0   Final Constraints
  ;#
  ;#         If Sensors (CTOF,MTOF,STOF) have changed from an ON to a
  ;#         Power Off mode, then non-ops heater status may require 
  ;#         a change.
  ;#
  ;#***********************************************************************
  ENDPROC