PROC F_FL_M_MODE
;VERSION 1   
IF(P@NRT_STATE#TELECOMMAND = "ENABLED")THEN
  /NRT TPUT PAUS
ELSE
ENDIF

GOTO BEGIN
;
;#***********************************************************************
;# ****PROCEDURE HEADER****
;#
;# 1.0 Introduction
;#
;#  1.1 FOT Name: F_FL_M_MODE
;#      MMS-F Name:
;#      SUM Issue:
;#      Simulator Validation Status:
;#
;#  1.2 Date Created: 03-NOV-95 
;#      Revision:  1. 01-DEC-95  BS
;#
;#  1.3 Change Description:
;#
;#      1. GO TO -> GOTO.
;#
;#  1.4 Point of Contact: CCAZEAU   ATSC/SOHO   286-6374
;#      FOT Author: BSAPPER  ATSC/SOHO  286-4799
;#      CELIAS Author: J PAQUETTE UMD  301-405-6223
;#      Revised: A GALVIN
;#      CELIAS contact: A GALVIN UMD 301-405-6208
;#
;#***********************************************************************
;# 2.0 Description
;#
;#  2.1 Narrative Decription
;#
;#      CHANGE MTOF MODE TO THAT GIVEN BY THE PROC'S PARAMETER
;#      0 = OFF
;#      1 = STANDBY
;#      2 = MANUAL 
;#      3 = VERIFY 
;#      4 = AUTOCAL
;#      5 = NOMINAL
;#      NONE OF THESE WILL BE IMPLEMENTED UNTIL THE NEXT 
;#      CELIAS SCIENCE RECORD BEGINS (EVERY 5 MINUTES)
;#
;#  2.2 Intended Use:
;# 
;#      Allow the mode of the CELIAS MTOF sensor to be 
;#      placed in whatever mode is desired
;#
;#  2.3 Duration: TBD
;#
;#  2.4 References:
;#
;#***********************************************************************
;# 3.0 Instructions for Use 
;#
;#  3.1 Parameters Required
;#
;#      MODE
;#
;#  3.2 Critical Activities
;#
;#      IF MTOF HAS BEEN IN "POWER OFF" MODE WITH MTOF NON-OPS
;#      HEATER(S) ON, THEN HEATER CONFIGURATION SHOULD BE
;#      CHECKED BY FOT.  IF NOT BAKE OUT, HEATERS FOR MTOF
;#      SHOULD BE OFF WHEN MTOF IS POWERED ON.  MTOF HEATER
;#      IS CELIAS HEATER 2 AND (REDUNDANT) 4.
;# 
;#  3.3 Special Constraints or Activities
;#
;#      High voltages may be affected.  Contact experimenter.
;#
;# *************************************************************************
;# 4.0 STEPS

BEGIN:

LOCAL MODE

IF(P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
   /CLEAR  ;Clearing the Command Buffer.
ENDIF

WAIT  ;Note value of Command Ok counter (FSDTCOK)

;# 4.1 Prompt user for the desired mode

ASK "Enter desired mode. 0=OFF, 1=Stby, 2=Man, 3=Ver, 4=IFC, 5=Nom"MODE

;# 4.2 Place MTOF in the mode indicated by the input parameter

IF(MODE=0)THEN
        /FBMMOD0 ;MTOF Off
        WAIT  ;VERIFY BUFFER CONTENTS
        /SEND
        WAIT UNTIL(P@FSDMODM = "Power Off") ;may take up to 5 minutes to 
        ;implement and confirm
       GOTO GOODINPUT
ENDIF

IF(MODE=1)THEN
        /FBMMOD1 ;MTOF Standby mode
        WAIT  ;VERIFY BUFFER CONTENTS
        /SEND
        WAIT UNTIL(P@FSDMODM = "Standby") ;may take up to 5 minutes to
                                          ;implement and confirm  
        GOTO GOODINPUT
ENDIF

IF(MODE=2)THEN
        /FBMMOD2 ;MTOF Manual mode
        WAIT ;VERIFY BUFFER CONTENTS
        /SEND
        WAIT UNTIL(P@FSDMODM = "Manual") ;may take up to 5 minutes to
                                         ;implement and confirm  
        GOTO GOODINPUT
ENDIF

IF(MODE=3)THEN
        /FBMMOD3 ;MTOF Verify mode
        WAIT ;VERIFY BUFFER CONTENTS
        /SEND
        WAIT UNTIL(P@FSDMODM = "Verify") ;may take up to 5 minutes to
                                         ;implement and confirm  
        GOTO GOODINPUT
ENDIF

IF(MODE=4)THEN
        /FBMMOD4 ;MTOF IFC mode
        WAIT ;VERIFY BUFFER CONTENTS
        /SEND
        WAIT UNTIL(P@FSDMODM = "IFC") ;may take up to 5 minutes to
                                      ;implement and confirm  
        GOTO GOODINPUT
ENDIF

IF(MODE=5)THEN
        /FBMMOD5 ;MTOF Nominal mode
        WAIT ;VERIFY BUFFER CONTENTS
        /SEND
        WAIT UNTIL(P@FSDMODM = "Nominal") ;may take up to 5 minutes to
                                          ;implement and confirm  
        GOTO GOODINPUT
ENDIF

WRITE "Incorrect input. Mode not changed."
GOTO GOODINPUT

GOODINPUT:
WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE")
;#***********************************************************************
;#   5.0   Final Constraints
;#
;#         CONFIRM MTOF NON-OPS HEATERS STATUS.  CONFIRM HV STATUS.
;#
;#***********************************************************************

IF(P@NRT_STATE#TELECOMMAND = "PAUSE-ENAB")THEN
/NRT TPUT RSUM
/CMSMSG,CELIAS,'Procedure F_FL_M_MODE has completed'
ELSE
ENDIF

ENDPROC