PROC F_FL_M_MODIFC
;VERSION 0   
IF(P@NRT_STATE#TELECOMMAND = "ENABLED")THEN
    /NRT TPUT PAUS
ELSE
ENDIF

GOTO BEGIN
;
;#***********************************************************************
;#	****PROCEDURE HEADER****
;#
;#	1.0	Introduction
;#
;#		1.1	FOT Name: F_FL_M_MODIFC
;#			MMS-F Name:
;#			SUM Issue: MTOF Flight Procs Version 09-OCT-95 (part 1)
;#			Simulator Validation Status: None.
;#
;#		1.2	Date Created: 03-OCT-95 
;#			Revision: 
;#
;#		1.3	Change Description:
;#
;#			None.
;#
;#		1.4	Point of Contact: CCAZEAU   ATSC/SOHO   286-6374
;#			FOT Author: BSAPPER  ATSC/SOHO  286-4799
;#			CELIAS Author: AGALVIN UMD  301-405-6208
;#
;#***********************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Decription
;#
;#			PUT MTOF IN INFLIGHT CALIBRATION MODE, SET MTOF HIGH
;#			VOLTAGES (EXCEPT MCPS,HPS) TO OFF, DISABLED, LIMIT/DELTA=0/0
;#
;#		2.2	Intended Use:
;# 
;#			Put CELIAS MTOF sensor into IFC, high voltages
;#			that are affected placed in safe, known (default) 
;#			configuration.  IFC is the InFlight Calibrator.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4	References:
;#
;#***********************************************************************
;#	3.0	Instructions for Use: 
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			IF MTOF HAS BEEN IN "POWER OFF" MODE WITH MTOF NON-OPS
;#			HEATER(S) ON, THEN HEATER CONFIGURATION SHOULD BE
;#			CHECKED BY FOT.  IF NOT BAKE OUT, HEATERS SHOULD
;#			BE OFF WHEN MTOF IS POWERED ON.
;#	
;#		3.3	Special Constraints or Activities
;#
;#			High voltages may be affected.  Contact experimenter.
;#
;# *************************************************************************
;#	4.0	STEPS:

BEGIN:

IF(P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
   /CLEAR		;Clearing the Command Buffer.
ENDIF

;#	4.1 Set affected MTOF high volages to level 0 (not MCPs or HPS!)

WAIT		;NOTE VALUE OF FSDTCOK (command OK counter)
 
/FBMPE,0000		;PM E/Q power supply to level 0
/FBMWE,0000		;MAIN WAVE power supply to level 0
/FBMVF,0080		;MAIN Vf power supply to level 128


WAIT		;VERIFY BUFFER CONTENTS
/SEND

WAIT		;VERIFY FSDTCOK HAS INCREASED BY 3.  NOTE NEW VALUE.

;#	4.2 Set affected MTOF high voltage limits and deltas to 0

/FBMLIMPE,0000	;PM E/Q power supply delta/limit = 0,0
/FBMLIMWE,0000		;MAIN WAVE power supply delta/limit = 0,0
/FBMLIMVF,0000	;MAIN Vf power supply delta/limit = 0,0


WAIT		;VERIFY BUFFER CONTENTS
/SEND

WAIT		;VERIFY FSDTCOK HAS INCREASED BY 3.  NOTE NEW VALUE.

;#	4.3 Disable affected MTOF high voltages

/FBMDISI,000E		;disable MTOF PEQ,WEQ,VF high voltages
WAIT		;VERIFY BUFFER CONTENTS
/SEND

WAIT		;VERIFY FSDTCOK HAS INCREASED BY 1.

;# 	4.4 Place MTOF in IFC mode

/FBMMOD4         	;MTOF IFC mode
WAIT              	;VERIFY BUFFER CONTENTS
/SEND

WAIT UNTIL(P@FSDMODM = "IFC")

WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE")
;#***********************************************************************
;#   5.0   Final Constraints
;#
;#         CONFIRM MTOF NON-OPS HEATERS STATUS.  CONFIRM HV STATUS.
;#
;#***********************************************************************

IF(P@NRT_STATE#TELECOMMAND = "PAUSE-ENAB")THEN
    /NRT TPUT RSUM
    /CMSMSG,CELIAS,'Procedure F_FL_M_MODIFC has completed'
ELSE
ENDIF
ENDPROC