PROC F_FL_M_PREAMP
;VERSION 1   
IF(P@NRT_STATE#TELECOMMAND = "ENABLED")THEN
  /NRT TPUT PAUS
ELSE
ENDIF

GOTO BEGIN
;
;#***********************************************************************
;# ****PROCEDURE HEADER****
;#
;# 1.0 Introduction
;#
;#  1.1 FOT Name: F_FL_M_PREAMP
;#      MMS-F Name:
;#      SUM Issue:
;#      Simulator Validation Status:
;#
;#  1.2 Date Created: 01-OCT-95 
;#      Revision:  1. 01-DEC-95  BS
;#
;#  1.3 Change Description:
;#
;#      1. Clarify question regarding off or on status desired.
;#
;#  1.4 Point of Contact: CCAZEAU   ATSC/SOHO   286-6374
;#      FOT Author: BSAPPER  ATSC/SOHO  286-4799
;#      CELIAS Author: J PAQUETTE UMD  301-405-6223
;#      Revision:  A GALVIN
;#      CELIAS Contact: A GALVIN UMD   301-405-6208
;#
;#***********************************************************************
;# 2.0 Description
;#
;#  2.1 Narrative Decription
;#
;#      TURN OFF OR ON NEUTRAL OR ION MCP PRE-AMPLIFIERS.
;#
;#  2.2 Intended Use:
;# 
;#      Turn off or on a CELIAS MTOF MCP pre-amp.
;#
;#  2.3 Duration: TBD
;#
;#  2.4 References:
;#
;#***********************************************************************
;# 3.0 Instructions for Use: 
;#
;#  3.1 Parameters Required
;#
;#      POFFON
;#      NEUTION
;#
;#  3.2 Critical Activities
;#
;#      NONE
;# 
;#  3.3 Special Constraints or Activities
;#
;#      NONE
;#
;# *************************************************************************
;# 4.0 STEPS:

BEGIN:

LOCAL POFFON   ;preamp OFF or ON status selected
LOCAL NEUTION   ;NEUTRAL MCP or ION MCP Preamp selected


IF(P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
   /CLEAR ;Clearing the Command Buffer.
ENDIF

WAIT  ;Note value of Command Ok counter (FSDTCOK)


ASK "Which preamp, ion or neutral (I=ion, N=neutral)?"NEUTION
NEUTION=%UPPER(NEUTION)

IF(NEUTION="I")THEN
ELSE
  IF(NEUTION="N")THEN
  ELSE
    ;If we get here, then the user entered wrong value.
    ;In this case, exit without changing preamp status.

    WRITE "Input Error! You must enter N or I. Preamp state unchanged."
    WAIT  ; either backtrack or get out here
    GOTO GETOUT
  ENDIF
ENDIF


ASK "Turn preamp off or on (0=off, 1=on) Enter NUMBER ?"POFFON

IF(NEUTION="I")THEN          ;Turn the ion preamp on or off
  IF(POFFON=0)THEN
    /FBMPREI,0000 ;Ion pre-amp off
    WAIT ;VERIFY BUFFER CONTENTS
    /SEND
    WAIT  ;Verify FSDTCOK increments by 1.
    GOTO GETOUT 
  ENDIF

  IF(POFFON=1)THEN     
    /FBMPREI,00FF ;Ion pre-amp on
    WAIT  ;VERIFY BUFFER CONTENTS
    /SEND
    WAIT  ;Verify FSDTCOK increments by 1. 
    GOTO GETOUT
  ELSE    
    ;If we get here, then the user entered wrong off/on code
    ;In this case, exit without changing preamp status.

    WRITE "Input Error! You must enter either 0 or 1. Exiting."
    WAIT  ; backtrack or get out
    GOTO GETOUT
  ENDIF
ENDIF

IF(NEUTION="N")THEN      ;Turn the neutral preamp on or off
  IF(POFFON=0)THEN
    /FBMPREN,0000 ;Neutral pre-amp off
    WAIT            ;VERIFY BUFFER CONTENTS
    /SEND
    WAIT  ;Verify FSDTCOK increments by 1. 
    GOTO GETOUT
  ENDIF

  IF(POFFON=1)THEN
    /FBMPREN,00FF ;Neutral pre-amp on
    WAIT ;VERIFY BUFFER CONTENTS
    /SEND
    WAIT  ;Verify FSDTCOK increments by 1. 
    GOTO GETOUT

  ELSE    
    ;If we get here, then the user entered wrong on/off code
    ;In this case, exit without changing preamp status.

    WRITE "Input Error! You must enter either 0 or 1."
    WAIT  ; backtrack or getout
    GOTO GETOUT
  ENDIF
ENDIF
GOTO GETOUT

GETOUT:
WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE")
;#***********************************************************************
;#   5.0   Final Constraints
;#
;#         NONE
;#
;#***********************************************************************

IF(P@NRT_STATE#TELECOMMAND = "PAUSE-ENAB")THEN
/NRT TPUT RSUM
/CMSMSG,CELIAS,'Procedure F_FL_M_PREAMP has completed'
ELSE
ENDIF

ENDPROC