PROC F_FL_M_SAFE
;VERSION 1
GOTO BEGIN
;#***********************************************************************
;# ****PROCEDURE HEADER****
;#
;#	1.0 Introduction
;#
;#		1.1	FOT Name: F_FL_M_SAFE
;#			MMS-F Name:
;#			SUM Issue:
;#			Simulator Validation Status:
;#
;#		1.2 	Date Created: 12-JAN-97
;#			    Revision:	1. 16-JAN-97 BDB
;#
;#		1.3	Change Description:
;#
;#			1. Add automated command counter check.  Add automated 
;#			   telemetry checks.  Alter procedure to conform to 
;#			   procedure style guidelines.
;#
;#		1.4	Point of Contact: 
;#			Author: A GALVIN UMD  301-405-6208
;#
;#***********************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Decription
;#
;#                      REDUCTION OF MTOF MAIN AND PM POWER SUPPLIES
;#                      FOR LARGE (ABOUT >50 GRAMS) THRUSTER OPERATIONS
;#   
;#                      (1)  Set Vf to minimize UV electrons penetration 
;#                           to carbon foil:  WAVE = 128 (80 hex), 
;#                                              Vf = 125 (7d hex).  
;#   (2)  Disable Wave E/Q and PM E/Q, immediate execution.
;#   (3)  Set Hyperbola Power Supply to 2 kV 
;#                           (delta 1, limit 0, level 0)
;#                      (4)  Prepare for PM recovery.  
;#                           Set PM E/Q to 77 (4d hex), 77 (4d hex), 
;#                                         77 (4d hex), 47 (2f hex),
;#                                         29 (1d hex), 18 (12 hex).  
;#
;#		2.2	Intended Use:
;# 
;#		To be used to place the CELIAS MTOF
;#		sensor into a safe configuration prior 
;#		to s/c thruster operations (such as 
;#		momentum management and orbit station
;#		keeping manuevers) in which the estimated
;#		fuel expediture is greater than about 
;#		50 grams.  
;#
;#		2.3	Duration: TBD
;#
;#		2.4	References:
;#
;#***********************************************************************
;#	3.0 Instructions for Use: 
;#
;#		3.1	Parameters Required: 
;#
;#		3.2	Critical Activities
;#
;#		None
;# 
;#		3.3 Special Constraints or Activities
;#
;#		Monitor MTOF HV HK and DPU HK during procedure:
;#
;#		Bring up the CELIAS ("F_") DPU_HKTEMP and MTOF_HK pages.
;#		Bring up "Command Buffer" page.
;#		Use the DPU_HKTEMP page to verify "command ok counter" increments
;#		appropriately for the commands sent.
;#   	Use the MTOF page to verify MTOF Housekeeping.
;#   
;#
;#*************************************************************************
;# 4.0 STEPS:

BEGIN:

LOCAL CMDOKCNT

IF(P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
   /CLEAR ;Clearing the Command Buffer.
ENDIF

;--------------------------------------------
; Record value of FSDTCOK (DPU Command OK
; Counter).
;--------------------------------------------
SV FSDTCOK
WAIT; Go after recording value.
LET CMDOKCNT =  FSDTCOK

;--------------------------------------------
; 4.1.  Set Vf to minimize UV electrons
; penetration to carbon foil
; WAVE = 128 (80 hex), Vf = 125 (7d hex).  
;--------------------------------------------
/CMD FBMWEPAR,8080,8080,8080,8080,8080,8080,7D7D,7D7D,7D7D,7D7D,7D7D,7D7D
WAIT  ;VERIFY BUFFER CONTENTS
/SEND

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
;--------------------------------------------
; 4.2.  Disable Wave E/Q and PM E/Q,
; immediate execution.
;--------------------------------------------
/CMD FBMDISI,0006
WAIT  ;VERIFY BUFFER CONTENTS
/SEND

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
;--------------------------------------------
; 4.3.  Set Hyperbola Power Supply to 2 kV
; (delta 1, limit 0, level 0)
;--------------------------------------------
/CMD FBMLIMHV,0100
/CMD FBMHV,0000
WAIT  ;VERIFY BUFFER CONTENTS
/SEND

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
;--------------------------------------------
; 4.4   Set up PM E/Q parameters for recovery
;--------------------------------------------
/CMD FBMPEPAR,4D4D,2F4D,121D
WAIT  ;VERIFY BUFFER CONTENTS
/SEND

;--------------------------------------------
; 4.5    Verify housekeeping (F_DPU_HKTEMP,
; F_MTOF_HK display pages)
;--------------------------------------------

;--------------------------------------------
; VERIFY FSDTCOK (DPU Command OK Counter) 
; HAS INCREASED BY 5. NOTE NEW VALUE.
;--------------------------------------------
WAIT UNTIL (FSDTCOK = (CMDOKCNT+5))
SV FSDTCOK
WAIT; Go after recording value.

;--------------------------------------------
; VERIFY FSMVHPSV (MTOF HPS VOLTAGE) 
;              ~ 1.95 kV +/- 0.1 kV  (2 kV)
; VERIFY FSMGPMEV (MTOF PEQ VOLTAGE)
;              ~ 0 kV +/- 0.1 kV     (OFF)
; VERIFY FSMGWVEVFSMGWVEV (MTOF WEQ VOLTAGE)
;              ~ 0 kV +/- 0.1 kV     (OFF)
; VERIFY FSMGVFV  (MTOF VF VOLTAGE)
;              ~ -0.1 kV +/- 0.1 kV  (-100v)
;--------------------------------------------
WAIT UNTIL ((P@FSMVHPSV > 1.85).AND.(P@FSMVHPSV < 2.05))
WAIT UNTIL ((P@FSMGPMEV > -0.1).AND.(P@FSMGPMEV < 0.1))
WAIT UNTIL ((P@FSMGWVEV > -0.1).AND.(P@FSMGWVEV < 0.1))
WAIT UNTIL ((P@FSMGVFV > -0.2).AND.(P@FSMGVFV < 0.0))

OUT:
;#***********************************************************************
;#   5.0   Final Constraints
;#
;#         Notify ipavich@umtof.umd.edu and galvin@umtof.umd.edu
;#         of time that procedure was executed
;#
;#***********************************************************************
RETURN
ENDPROC