PROC F_FL_M_WMT120
;VERSION 1   
IF(P@NRT_STATE#TELECOMMAND = "ENABLED")THEN
/NRT TPUT PAUS
ELSE
ENDIF

GOTO BEGIN
;
;#***********************************************************************
;#	****PROCEDURE HEADER****
;#
;#	1.0	Introduction
;#
;#		1.1	FOT Name: F_FL_M_WMT120
;#			MMS-F Name:
;#			SUM Issue:
;#			Simulator Validation Status:
;#
;#		1.2	Date Created: 01-OCT-95 
;#			Revision: 
;#
;#		1.3	Change Description:
;#
;#			None.
;#
;#		1.4	Point of Contact: CCAZEAU   ATSC/SOHO   286-6374
;#			FOT Author: BSAPPER  ATSC/SOHO  286-4799
;#			CELIAS Author: AGALVIN UMD  301-405-6208
;#
;#***********************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Decription
;#
;#			PUT MTOF IN STANDBY MODE, STOF AND CTOF IN POWER OFF.
;#			RUN MTOF WAX MOTOR FOR 120 SECONDS.
;#
;#		2.2	Intended Use:
;# 
;#			Open MTOF cover using wax actuator motor for 120 sec. 
;#
;#		2.3	Duration:	TBD
;#
;#		2.4	References:
;#
;#***********************************************************************
;#	3.0	Instructions for Use: 
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#                  IF THE DPU, CTOF, MTOF, STOF POWER STATE IS 
;#			CHANGED DURING THIS PROCEDURE, THE FOT SHOULD
;#			CHECK THE APPROPRIATE NON-OPS HEATER(S) 
:#			CONFIGURATION(S).
;#		
;#			CELIAS MUST BE IN THE POWER ON STATE.  STOF AND CTOF 
;#			MUST BE IN, OR PLACED IN, A POWER OFF CONFIGURATION.  
;#
;#			WAX ACTUATOR COMMAND IS "CRITICAL".
;#	
;#		3.3	Special Constraints or Activities
;#
;#			Written or ONSITE verbal authorization by CELIAS 
;#			representative required for use of FBMOPT1 command.  
;#			CELIAS MTOF representative must be available.
;#
;#			Status of MTOF,STOF,CTOF non-ops heater(s) should be 
;#                  discussed with CELIAS representative.
;#
;#			Thermal parameters need to be monitored for 
;#			several minutes before, during, and several minutes 
;#			after procedure.  Printouts requested.
;#			CELIAS current needs to be monitored before, during,
;#			and after procedure.  Printouts requested.
;#
;# *************************************************************************
;#	4.0	STEPS:

BEGIN:

IF(P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
   /CLEAR		;Clearing the Command Buffer.
ENDIF

;# 	4.1	CONFIRM OR PLACE ALL SENSORS IN DESIRED MODE

IF(P@FSDMODC = "Power Off")THEN
    WRITE "**** CTOF SENSOR IS OFF *****"
ELSE
    WRITE "**** CTOF SENSOR APPEARS TO BE ON *****"
    ASK "DO YOU NEED TO TURN OFF CTOF?"
    ANSWER = %UPPER(ANSWER)
    IF (ANSWER = "Y")THEN
        /FBCMOD0I	;CTOF power off, immediate execution
        WAIT	;VERIFY BUFFER CONTENTS
        /SEND
        WAIT UNTIL (P@FSDMODC = "Power Off")
    ENDIF
ENDIF

IF(P@FSDMODS = "Power Off")THEN
    WRITE "**** STOF SENSOR IS OFF *****"
ELSE
    WRITE "**** STOF SENSOR APPEARS TO BE ON *****"
    ASK "DO YOU NEED TO TURN OFF STOF?"
    ANSWER = %UPPER(ANSWER)
    IF (ANSWER = "Y")THEN
        /FBSMOD0I   ;STOF power off, immediate execution
        WAIT        ;VERIFY BUFFER CONTENTS
        /SEND
        WAIT UNTIL (P@FSDMODS = "Power Off")
    ENDIF
ENDIF

IF(P@FSDMODM = "Standby")THEN
    WRITE "**** MTOF SENSOR IS ON, IN STANDBY MODE *****"
ELSE
    WRITE "**** MTOF SENSOR IS NOT IN STANDBY MODE *****"
    ASK "DO YOU NEED TO PUT MTOF INTO STANDBY MODE?"
    ANSWER = %UPPER(ANSWER)
    IF (ANSWER = "Y")THEN
        /FBMMOD1I   ;MTOF standby mode, immediate execution
        WAIT        ;VERIFY BUFFER CONTENTS
        /SEND
        WAIT UNTIL (P@FSDMODM = "Standby")
    ENDIF
ENDIF

WAIT UNTIL (P@FSDSPM1 = "On")
WAIT UNTIL (P@FSDSPC1 = "Off")
WAIT UNTIL (P@FSDSPS1 = "Off")

;#	4.2	MTOF WAX MOTOR ACTIVATION

		;NOTE VALUE OF CELIAS CURRENT (about 290 mA?).  PRINT OUT.
		;NOTE VALUE OF MTOF TEMPERATURES.  PRINT OUT.
WAIT	;CONFIRM WITH EXPERIMENT REPRESENTATIVE TO PROCEED.

/FBMOPT1,0302	;MTOF wax motor for 770 units = 120 seconds
WAIT		;VERIFY BUFFER CONTENTS
/SEND

			;VERIFY CELIAS CURRENT GOES UP TO ABOUT 630 mA, AND
WAIT		;PRINT OUT DISPLAY.

ASK "IS EMERGENCY WAX MOTOR OFF COMMAND REQUIRED?"
ANSWER = %UPPER(ANSWER)
IF (ANSWER = "Y")THEN
/FBMOPT1,0003	;half second cmd to supercede 120 second cmd
    WAIT		;VERIFY BUFFER CONTENTS
    /SEND
ENDIF

WAIT UNTIL (P@FSDSPM2 = "Off")

			;VERIFY CELIAS CURRENT DROPS TO ABOUT 290 mA, AND
WAIT		;PRINT OUT DISPLAY.

WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE")
;#***********************************************************************
;#   5.0   Final Constraints
;#
;#         CONFIRM MTOF NON-OPS HEATERS STATUS.
;#
;#	       CONTINUE MONITORING MTOF TEMPERATURES FOR AT LEAST 30 MINUTES.
;#
;#	       VERIFICATION OF MTOF COVER OPENING MUST BE ESTABLISHED BY
;#	       MTOF REPRESENTATIVE.
;#
;#***********************************************************************

IF(P@NRT_STATE#TELECOMMAND = "PAUSE-ENAB")THEN
/NRT TPUT RSUM
/CMSMSG,CELIAS,'Procedure F_FL_M_WMT120 has completed'
ELSE
ENDIF
ENDPROC