PROC F_FL_SSD_BIAS
  GOTO BEGIN
  ;
  ;#*******************************************************************
  ;#  ****PROCEDURE HEADER****
  ;#
  ;#  1.0     Introduction
  ;#
  ;#          1.1     FOT Name: F_FL_SSD_BIAS
  ;#                  MMS-F Name:
  ;#                  SUM Issue:
  ;#                  Simulator Validation Status
  ;#
  ;#          1.2     Date Created: 15-NOV-95 PEL
  ;#                   Revision: 1. 25-DEC-95 RS
  ;#
  ;#          1.3     Change Description:
  ;#					1.  Changed command /FBSSDV --> /FBSSBV.  Also fixed
  ;#					    all incorrect write statements to proper TSTOL 
  ;#					    syntax.  Also added wait until command state
  ;#					    available where appropriate and changed answers 
  ;#					    to upper case.
  ;#
  ;#          1.4     Point of Contact: CCAZEAU   ATSC/SOHO   286-6374
  ;#                  FOT Author: BSAPPER  ATSC/SOHO  286-4799
  ;#                  CELIAS Author: W.Bornemann MPE 49-89-3299-3842
  ;#********************************************************************
  ;#  2.0     Description
  ;#
  ;#          2.1     Narrative Decription
  ;#                  Procedure contains all commands for STOF SSD-Bias
  ;#                  
  ;#                  Only one menue item can be commanded by 
  ;#                  one run of this procedure
  ;#          2.2     Intended Use:
  ;#
  ;#          2.3     Duration:       TBD
  ;#
  ;#          2.4     References:
  ;#
  ;#*******************************************************************
  ;#  3.0     Instructions for Use:
  ;#
  ;#          3.1     Parameters Required
  ;#
  ;#          None
  ;#  3.2     Critical Activities
  ;#
  ;#
  ;#          TBD
  ;#
  ;#  3.3     Special Constraints or Activities
  ;#          STOF SSD-Bias Limit and Set Value = 202                         
  ;#          unless authorized by experimenter                              
  ;#
  ;# *********************************************************************
  ;#  4.0     STEPS:

  BEGIN:
  LOCAL PRCCMD,LIMIT,DELTA,SETDAC

  IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
  ELSE
      /CLEAR  ;Clearing the Command Buffer.
  ENDIF

  WRITE "STOF SSD BIAS LIMIT SET   = LIMIT"
  WRITE "STOF SSD BIAS ON          = BIASON"
  WRITE "STOF SSD BIAS OFF         = BIASOFF"
  WRITE "STOF SSD BIAS SET         = SETDAC"

  ASK "SELECT SSD BIAS COMMAND (DISPLAYED ON SCREEN)?"PRCCMD

  LET PRCCMD = %UPPER(PRCCMD)

 IF (PRCCMD = "LIMIT") THEN 

    ASK "ENTER SSD BIAS LIMIT (0 to 202 dec)?"LIMIT
    ASK "ENTER SSD BIAS DELTA (0 to 20 dec)?"DELTA

    IF (LIMIT > 202) THEN 

       WRITE "LIMIT EXCEEDS NORMAL SETTING (= 202)! $LIMIT"
   
       ASK "ABORT PROCEDURE ? (Y OR N)"
       ANSWER = %UPPER(ANSWER)

       IF (ANSWER = "Y") THEN

   WRITE "PROCEDURE ABORTED"
   GOTO ABPRC               ; ABORT PROCEDURE
       ENDIF
    ENDIF

    WRITE "SSD BIAS LIMIT SETTING $LIMIT"
    WRITE "SSD BIAS DELTA SETTING $DELTA"
    ASK "CONFIRM SSD BIAS LIMIT AND DELTA SETTING (Y OR N)"
    ANSWER = %UPPER(ANSWER)

    IF (ANSWER = "Y") THEN
 
       LIMIT = %HEX(LIMIT,2)
       DELTA = %HEX(DELTA,2)
       /FBSLIMBI,$DELTA$LIMIT  ; SSD BIAS LIMIT SET TO LIMIT, DELTA
       WAIT                    ; VERIFY BUFFER CONTENTS
       /SEND

       WRITE "SSD BIAS LIMIT SET TO D$LIMIT"
       WRITE "SSD BIAS DELTA SET TO D$DELTA"
    ELSE 
       GOTO ABPRC       
    ENDIF
 ENDIF



 IF (PRCCMD = "BIASON") THEN 

    ASK "CONFIRM SWITCH ON OF SSD BIAS ?(Y OR N)"
    ANSWER = %UPPER(ANSWER)

    IF (ANSWER = "Y") THEN
       /FBSSBON                ; SSD BIAS on
       WAIT                    ; VERIFY BUFFER CONTENTS
       /SEND
       WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
	  /FBSENASB               ; Enable SSD BIAS
       WAIT                    ; VERIFY BUFFER CONTENTS
       /SEND
       WAIT UNTIL (P@FSSSBON = "On")    ;STOF SSD Bias on
       WAIT UNTIL (P@FSSESB = "On")     ;STOF SSD Bias enabled

       WRITE "SSD BIAS SWITCHED ON"
    ELSE 
       GOTO ABPRC       
    ENDIF
 ENDIF



 IF (PRCCMD = "BIASOFF") THEN 

    ASK "CONFIRM TURN-OFF OF SSD BIAS ?(Y OR N)"
    ANSWER = %UPPER(ANSWER)

    IF (ANSWER = "Y") THEN
       /FBSSBOF                ; SSD BIAS OFF
       WAIT                    ; VERIFY BUFFER CONTENTS
       /SEND
       WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
	  /FBSDISSB               ; Disable SSD BIAS
       WAIT                    ; VERIFY BUFFER CONTENTS
       /SEND
       WAIT UNTIL (P@FSSSBON = "Off")    ;STOF SSD Bias OFF
       WAIT UNTIL (P@FSSESB = "Off")     ;STOF SSD Bias disabled

       WRITE "SSD BIAS TURNED OFF"
    ELSE 
       GOTO ABPRC       
    ENDIF
 ENDIF



 IF (PRCCMD = "SETDAC") THEN 

    ASK "ENTER SSD BIAS SETTING (0 to 202 dec)?"SETDAC

    IF (SETDAC > 202) THEN 

       WRITE "SETDAC EXCEEDS NORMAL SETTING (= 202)! $SETDAC"
   
       ASK "ABORT PROCEDURE ? (Y OR N)"
       ANSWER = %UPPER(ANSWER)

       IF (ANSWER = "Y") THEN

   WRITE "PROCEDURE ABORTED"
   GOTO ABPRC               ; ABORT PROCEDURE
       ENDIF
    ENDIF

    WRITE "SSD BIAS SETTING $SETDAC"
    ASK "CONFIRM SSD BIAS SETTING (Y OR N)"
    ANSWER = %UPPER(ANSWER)

    IF (ANSWER = "Y") THEN
       SETDAC = %HEX(SETDAC,2)

       /FBSSBV,00$SETDAC        ; SSD BIAS SET TO SETDAC
       WAIT                    ; VERIFY BUFFER CONTENTS
       /SEND

       WRITE "STOF SSD BIAS SET TO D$SETDAC"
    ELSE 
       GOTO ABPRC       
    ENDIF
 ENDIF



 ABPRC:
 ;#*******************************************************************
 ;#   5.0   Final Constraints
 ;#
 ;#         TBD
 ;#
 ;#*******************************************************************

 ENDPROC