PROC H_FL_OFF
;Version 7
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: H_FL_OFF  
;#		   	MMS-F Name: H_FL_OFF  	 
;#		   	SUM Issue: N/A  	
;#			Simulator Validation Status: Validated
;#
;#		1.2	Date Created: 7 MAR 1995         TL 
;#			    Revision: 1)  1 MAY 1995     TL
;#                           2)  3 MAY 1995     TL
;#                           3) 25 MAY 1995     TL
;#                           4)  2 JUNE 1995    TL
;#                           5) 11 Aug 95       TL
;#                           6) 25 Oct 95       TL 
;#					    7) 18-Feb-97	   KEH	
;# 
;#		1.3	Change Description:	
;#
;#	     	1) Changed WAITs to check raw, not discrete, values.
;#             2) Added call to proc k_exp_mon_dis. (5/3)
;#             3) Added K_EXP_MON_DIS to line 83.
;#             4) Removed one of two calls to k_exp_mon_dis (line 70).
;#             5) Changed name to _FL_ (FLight ready).
;#			6) Added version number, comments.
;#			7) Added checks for LCL status to be "off"
;#
;#		1.4	Point of Contact: T. LA FAVE	
;#			FOT Author: T. LA FAVE 	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This module switches off CEPAC by performing an EPHIN
;#             switch-off sequence and then switching off the +5V
;#             supply lines of the sensors by CDPU.  The sequence is
;#             completed by switching off CEPAC LCL by the S/C.
;#
;#		2.2	Intended Use:
;#
;#			
;#
;#		2.3	Duration:	5 min.
;#
;#		2.4 References:
;#             Page h_cepac1, h_cepac2, h_cepac3, I_EXP_CHECK
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			None
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
;--------------------------------------------
;Clearing the Command Buffer.
;--------------------------------------------
	/CLEAR		
ENDIF

;--------------------------------------------
; Wait for OFF conditions
;--------------------------------------------
WAIT UNTIL ((HSEMODE = 0) AND (HSFMODE = 0))

;--------------------------------------------
;Switch analog power off
;-------------------------------------------- 
/CMD HBFAPDOF  

;--------------------------------------------
; Verify command buffer contents
;--------------------------------------------         
WAIT                
/SEND

WAIT UNTIL (P@CMD_STATE = "AVAILABLE")
;--------------------------------------------
; Wait for OFF conditions
;--------------------------------------------
WAIT UNTIL (HSFAPW = 0) 

;--------------------------------------------
;Switch off LION
;--------------------------------------------
/CMD HBCLOFF  

;--------------------------------------------
;Switch off ESU
;--------------------------------------------         
/CMD HBCEOFF

;--------------------------------------------
;Switch off EPHIN
;--------------------------------------------            
/CMD HBCFOFF

;--------------------------------------------
; Verify command buffer contents
;--------------------------------------------            
WAIT                
/SEND

WAIT UNTIL ((HKCPWRSL = 0) AND (HKCPWRSF = 0))
WAIT UNTIL ((HKCPWREN = 0) AND (HKCPWRER = 0))
WAIT UNTIL (HKCOPMOD = 0)
WAIT UNTIL (P@CMD_STATE = "AVAILABLE")

;--------------------------------------------
; CALL PROC TO DISABLE EXPERIMENT MONITORING
; AT CHANNEL LEVEL
;--------------------------------------------
START K_EXP_MON_DIS 

;--------------------------------------------
; GO TO POWER OFF LCL
;--------------------------------------------
WAIT

;--------------------------------------------
;Power off CEPAC side A
;--------------------------------------------
IF (P@HSPWA = "ON") THEN
	/CMD KNHPWAFN 
	/CMD KNHPWAFR

;--------------------------------------------
; POWER OFF LCL A
;--------------------------------------------
	WAIT
	/SEND
	WAIT UNTIL (P@HSPWA = "OFF")
ENDIF

;--------------------------------------------
;Power off CEPAC side B
;--------------------------------------------
IF (P@HSPWB = "ON") THEN
	/CMD KNHPWBFN          
	/CMD KNHPWBFR

;--------------------------------------------
; POWER OFF LCL B
;--------------------------------------------
	WAIT
	/SEND
	WAIT UNTIL (P@HSPWB = "OFF")
ENDIF
           
OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None
;#
;#**************************************************************************
RETURN
ENDPROC