PROC H_FL_ONNOM
;Version 7
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: H_FL_ONNOM   
;#		   	MMS-F Name: H_FL_ONNOM
;#		   	SUM Issue:  N/A    	
;#			Simulator Validation Status: Validated
;#
;#		1.2	Date Created: 7 MAR 1995     	TL 
;#			    Revision: 	1. 24 APR 1995	TL
;#                           	2.  1 MAY 1995	TL
;#                           	3.  3 MAY 1995	TL
;#                           	4. 25 MAY 1995	TL
;#                           	5. 22 AUG 1995	TL
;#                    		6. 25 Oct 1995	TL
;#						7. 17 Feb 1997	JSP
;#                          
;#		1.3	Change Description:	
;#
;#			1. Added condition "P@HSPWB = OFF" to line 72.
;#            	2. Changed WAITs to check raw, not discrete, values (5/1)
;#            	3. Added call to k_exp_mon_ena. (5/3)
;#            	4. Moved call to k_exp_mon_ena.
;#            	5. Send 2 upload commands to ESU.
;#			6. Added version number, comments.
;#			7. Passed CEPAC as parameter in OBT_DIST.
;#
;#		1.4	Point of Contact: H. Benefield	
;#			FOT Author: T. LA FAVE 	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure will switch CEPAC ON so all CEPAC units
;#             are powered and the CDPU is able to communicate with
;#             the S/C and with the sensors.  LVPC,CDPU, and LION will
;#             be in ON mode, and ESU and EPHIN in STANDBY (CEPAC safe/
;#             standby mode.)
;#
;#		2.2	Intended Use:
;#
;#			
;#
;#		2.3	Duration:	15 min.
;#
;#		2.4 References:
;#             Pages h_cepac1, h_cepac2, h_cepac3, h_cepac4
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			For safety reasons, certain housekeeping parameters
;#             will be done on-line.
;#
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

; 0-0-0-0-0-0-0  CEPAC switch-on to nominal configuraqtion  0-0-0-0-0-0-0-0


WAIT UNTIL ((HSPWA = 0) AND (HSPWB = 0)) ; wait for HSPWA,HSPWB to be OFF

/HCV12AN       ; Nominal CEPAC nominal +/-12V
/HCV6AN        ; Nominal CEPAC nominal +/-6V
WAIT                ; Verify command buffer contents
/SEND
WAIT 3

WAIT UNTIL (P@CMD_STATE = "AVAILABLE")
/KNHPWANN      ; Power on nominal CEPAC A side
WAIT                ; Verify command buffer contents
/SEND

WAIT UNTIL (HSPWA = 1)  ; wait for HSPWA to be ON
WAIT UNTIL ((P@HIPWA > .1) AND (P@HIPWA < .175))
WAIT 120
START K_EXP_MON_ENA
WAIT UNTIL (HKPID = 0)
WAIT UNTIL (HKCVTOUT = H'0000')

START K_OBT_DIST(CEPAC); Upload LOBT for CEPAC
WAIT UNTIL (P@CMD_STATE = "AVAILABLE")

/HBCCULD2,033A,FFFC      ;Upload data
/HBCCULD2,033F,FFFC
/HBCCULD2,00FF,9859
/HBCEON1                 ;Switch on ESU DPU 1
WAIT                     ; Verify command buffer contents 
/SEND
WAIT UNTIL (HKCPWREN = 1)
WAIT UNTIL ((P@HIPWA > .18) AND (P@HIPWA < .5))
WAIT UNTIL (HSEMODE = 0)   ; wait for HSEMODE to become STANDBY
WAIT UNTIL (P@CMD_STATE = "AVAILABLE")
/HBEUPLD3,4C09,C8FF,0000      ;Upload data
/HBEUPLD3,4C09,C9FF,0000
WAIT                ; Verify command buffer contents
/SEND
WAIT UNTIL (P@CMD_STATE = "AVAILABLE")
/HBCFON                   ;Switch EPHIN on
WAIT                ; Verify command buffer contents
/SEND

WAIT UNTIL (HKCPWRSF = 1)
WAIT UNTIL ((P@HIPWA > .195) AND (P@HIPWA < .515))
WAIT UNTIL (P@CMD_STATE = "AVAILABLE")
/HBFAPON                  ;Switch analog power on
WAIT                ; Verify command buffer contents
/SEND

WAIT UNTIL (HSFMODE = 0)   ; wait for HSEMODE to become STANDBY  
WAIT UNTIL ((P@HIPWA > .25) AND (P@HIPWA < .57))
WAIT UNTIL (P@CMD_STATE = "AVAILABLE")

/HBCLON                   ;Switch on LION
WAIT                ; Verify command buffer contents
/SEND

WAIT UNTIL (HKCPWRSL = 1)
WAIT UNTIL ((P@HIPWA > .295) AND (P@HIPWA < .615))


; 0-0-0-0-0-0 CEPAC switch-on to nominal configuration complete  0-0-0-0-0-0

WRITE "CEPAC is now in safe/standby mode, nominal configuration."

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None
;#
;#**************************************************************************
ENDPROC