PROC H_FL_ONRED
;Version 7
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: H_FL_ONRED   
;#		   	MMS-F Name: H_FL_ONRED  
;#		   	SUM Issue: N/A    	
;#			Simulator Validation Status: Validated
;#
;#		1.2	Date Created: 7 MAR 1995
;#			    Revision:	1. 24 APR 1995  TL
;#						2.  1 MAY 1995  TL
;#						3.  3 MAY 1995  TL
;#						4. 25 MAY 1995  TL
;#						5. 11 AUG 1995  TL
;#						6. 25 OCT 1995  TL
;#						7. 18 FEB 1997  JSP
;#
;#		1.3	Change Description:	
;#
;#			1. Added condition "P@HSPWA = OFF" to line 66.
;#			2. Changed WAITs to check raw, not discrete values. (5/1)
;#			3. Added call to k_exp_mon_ena. (5/3)
;#			4. Moved call to k_exp_mon_ena.
;#			5. Changed name to _FL_ (FLight ready).
;#			6. Added version number, comments.
;#			7. Passed CEPAC as a parameter in K_OBT_DIST.
;#
;#		1.4	Point of Contact: T. LA FAVE 	
;#			FOT Author: T. LA FAVE 	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure will switch on CEPAC to redundant
;#             configuration.
;#
;#		2.2	Intended Use:
;#
;#			
;#
;#		2.3	Duration:	15 min.
;#
;#		2.4 References:
;#             Pages h_cepac1, h_cepac2, h_cepac3, h_cepac4
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			None
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

; 0-0-0-0-0-0-0  CEPAC switch-on to redundant configuration  0-0-0-0-0-0-0-0

WAIT UNTIL ((HSPWA = 0) AND (HSPWB = 0))  ; wait for HSPWA,HSPWB to be OFF

/HCV12BR       ; Redundant CEPAC redundant +/-12V
/HCV6BR        ; Redundant CEPAC redundant +/-6V
WAIT           ; Verify command buffer contents
/SEND
WAIT 3

WAIT UNTIL (P@CMD_STATE = "AVAILABLE")
/KNHPWBNR      ; Power on redundant CEPAC B side
WAIT           ; Verify command buffer contents
/SEND

WAIT UNTIL (HSPWB = 1)                   ; wait for HSPWB to be ON
WAIT UNTIL ((P@HIPWB > .1) AND (P@HIPWB < .175))
WAIT 120

START K_EXP_MON_ENA

WAIT UNTIL (HKPID = 0)
WAIT UNTIL (HKCVTOUT = H'0000')

START K_OBT_DIST(CEPAC) ; Upload LOBT for CEPAC.

WAIT UNTIL (P@CMD_STATE = "AVAILABLE")
/HBCCULD2,033A,FFFC      ;Upload data
/HBCCULD2,033F,FFFC
/HBCCULD2,00FF,9859
/HBCEON2                 ;Switch on ESU DPU 2
WAIT           ; Verify command buffer contents
/SEND


WAIT UNTIL (HKCPWRER = 1)
WAIT UNTIL ((P@HIPWB > .18) AND (P@HIPWB < .5))
WAIT UNTIL (HSEMODE = 0)           ; wait for HSEMODE to become STANDBY

WAIT UNTIL (P@CMD_STATE = "AVAILABLE")
/HBCFON                 ;Switch on EPHIN
WAIT           ; Verify command buffer contents
/SEND


WAIT UNTIL (HKCPWRSF = 1)
WAIT UNTIL ((P@HIPWB > .195) AND (P@HIPWB < .515))

WAIT UNTIL (P@CMD_STATE = "AVAILABLE")
/HBFAPON                ;Switch analog power on
WAIT           ; Verify command buffer contents
/SEND

WAIT UNTIL (HSFMODE = 0)       ; wait for HSFMODE to become STANDBY
WAIT UNTIL ((P@HIPWB > .25) AND (P@HIPWB < .57))

WAIT UNTIL (P@CMD_STATE = "AVAILABLE")
/HBCLON                 ;Switch on LION
WAIT           ; Verify command buffer contents
/SEND


WAIT UNTIL (HKCPWRSL = 1)
WAIT UNTIL ((P@HIPWB > .295) AND (P@HIPWB < .615))



; 0-0-0-0-0-0 CEPAC switch-on to redundant configuration complete  0-0-0-0-0

WRITE "CEPAC is now in safe/standby mode, redundant configuration" 
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None
;#
;#**************************************************************************
ENDPROC