PROC G_FL_PWROFF_R
;Version 9
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:		G_FL_PWROFF_R
;#		    MMS-F Name:	GLF_OFF 
;#		    SUM Issue:		N/A
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:	11-SEP-94
;#				Revision:	1. 14-NOV-94	MH
;#						2. 30-NOV-94	BS
;#						3. 12-JAN-95	MH
;#						4. 24-JAN-95	HB
;#						5. 08-MAR-95	CG
;#						6. 24-APR-95	MH
;#						7. 19-OCT-95	TB
;#						8. 03-NOV-95	TB
;#						9. 06-DEC-95	MH
;#
;#		1.3	Change Description:	
;#
;#			1. Split G_TS_PWROFF into Nominal and redundant procs
;#			2. 2. Delete "WAIT 15" after /GBQWFIX.  Send /GBSC1THR,/GBSC1THR,
;#			   /GBSP1THR,/GBSP2THR in 1 blk.  Delete WAIT for GSDAYLD.
;#			   Add WAITs for GKTCxEXE, GKTCxPAR(x=1,2,3,4) after/GBSP2THR.
;#			   (x=2,3,4) after /GBFIOF, and (x=3,4) after /GBHV2OF.
;#			   WAIT UNTIL (P@GSDOMOT = "RED") vice NOM
;#			   WAIT UNTIL (P@GSPWCHN = "RED") vice NOM
;#			   WAIT UNTIL (P@GSSENSID = "FS2") vice FS1
;#			   /KNQGWNN -> /KNQGWNR.
;#			3. Added Call to proc K_EXP_MON_DIS.
;#			4. Added WAIT 15 and TM chcek after command GBCSOF.  Deleted sub htr commands
;#			   at end of procedure.
;#			5. Corrected 'G-15' in WAIT statement. 
;#			6. Comment change: Switch off GOLF REDUNDANT Power
;#			7.	Changed name from TS -> FL. No TSTOL changes.
;#			8. Removed threshold restoration. Added Switch on
;#			   of GOLF no-op heaters.
;#			9. Deleted Switch on of GOLF no-op heaters - OCD-40.
;#
;#		1.4	Point of Contact:	CCazeau	286-6374
;#			FOT Author:	MHill	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			Will put GOLF into OFF mode from any other mode.
;#
;#		2.2	Intended Use:
;#
;#			FS REDUNDANT CHANNEL SWITCH-OFF SEQUENCE
;#
;#		2.3	Duration:	35 min
;#
;#		2.4	References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			This procedure can also be performed after Recovery to Stand-by
;#			mode sequence (G_FL_RECOVERY).
;#			HK format program will not send more than 4 GOLF TCs per 14.9 sec.
;#			If an unaccepted TC is detected, after clarification of cause of
;#			failure, the sequence will be repeated, starting from unaccepted TC.
;#
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

;Starting from here: 4 last non-accepted TC will be checked (GKTCINOK, 
;GKTC2NOK, GKTC3NOK, GKTC4NOK) for each 14.9 sec. HK format program will 
;not send more than 4 GOLF commands per 14.9 sec
;if an unaccepted TC is detected, after clarification of cause of failure, 
;the sequence will be repeated, starting from unaccepted TC

;STOP POLARISER AND QUARTER-WAVE ROTATION
/GBPOFIX,0000
WAIT		;Verify command buffer contents
/SEND
WAIT 80
WAIT UNTIL (P@GSMECMOD = "PO TECH")

/GBQWFIX,0000
WAIT		;Verify command buffer contents
/SEND
WAIT UNTIL (P@GSMECMOD = "QW TECH")

;CLOSE DOOR
/GBDOCL
WAIT		;Verify command buffer contents
/SEND
WAIT 15
WAIT UNTIL (P@GSDO = "CLOSE")

/GBCSOF		;TURN CELL STEM HEATING OFF
WAIT		;Verify command buffer contents
/SEND
WAIT 15
WAIT	UNTIL (GKTC4EXE = 53)
WAIT UNTIL (GKTC4PAR = 0)

WAIT 1800	;Wait 30 mins.

;TURN MAGNETIC MODULATION OFF
/GBMMOF

/GBCBOF		;TURN CELL BULB HEATING OFF
/GBFIOF		;TURN FILTER HEATING OFF
WAIT		;Verify command buffer contents
/SEND

WAIT UNTIL (GKTC2EXE = 43)
WAIT UNTIL (GKTC2PAR = 0)
WAIT	UNTIL (GKTC3EXE = 51)
WAIT UNTIL (GKTC3PAR = 0)
WAIT	UNTIL (GKTC4EXE = 48)
WAIT UNTIL (GKTC4PAR = 0)

/GBHV1OF	;SWITCH PMT1 OFF
/GBHV2OF	;SWITCH PMT2 OFF
WAIT		;Verify command buffer contents
/SEND

WAIT UNTIL (GKTC3EXE = 55)
WAIT UNTIL (GKTC3PAR = 0)
WAIT	UNTIL (GKTC4EXE = 56)
WAIT UNTIL (GKTC4PAR = 0)

WAIT UNTIL (P@GSFIMOD = "HEAT OFF")
WAIT UNTIL (P@GSCBCST = "HEAT OFF")
WAIT UNTIL (P@GSCSMOD = "HEAT OFF")

WAIT UNTIL (P@GSSP1 = "CST")
WAIT UNTIL (P@GSSP2 = "CST")
WAIT UNTIL (P@GSHV1 = "OFF")
WAIT UNTIL (P@GSHV2 = "OFF")

WAIT UNTIL (P@GSDO = "CLOSE")
WAIT UNTIL (P@GSDOMOT = "RED")

WAIT UNTIL (P@GSMMOO = "OFF")

WAIT UNTIL (P@GSPOCHN = "ON")
WAIT UNTIL (P@GSQWCHN = "ON")

WAIT UNTIL (P@GSPWCHN = "RED")
WAIT UNTIL (P@GSMECMOD = "QW TECH")

WAIT UNTIL ((P@'G+5' > 4.6) AND (P@'G+5' < 5.3))
WAIT UNTIL ((P@'G-5' > -5.7) AND (P@'G-5' < -5.0))
WAIT UNTIL ((P@'G+15' > 14.6) AND (P@'G+15' < 15.3))
WAIT UNTIL ((P@'G-15' > -15.3) AND (P@'G-15' < -14.6))
WAIT UNTIL ((P@'G+28' > 27) AND (P@'G+28' < 28.5))

WAIT UNTIL (P@GSSENSID = "FS2")
WAIT UNTIL (P@GSDPUID = "FS")

WAIT UNTIL (P@GSONSEQ = "ENDED")
WAIT UNTIL (P@GSWDSTA = "NO")

WAIT UNTIL (P@GSWDRST = "NRST")

WAIT UNTIL (P@GSTIMLD = "WELC")
WAIT UNTIL (P@GSPROMPW = "OFF")

WAIT UNTIL (P@GSCSCTR = "ON")

WAIT UNTIL (P@GSPM1CTR = "OFF")
WAIT UNTIL (P@GSPM2CTR = "OFF")

S K_EXP_MON_DIS	;Disable experiment monitoring and corrective action

;SWITCH OFF GOLF REDUNDNAT POWER WITH REDUNDANT COMMAND
/KNGPWBFR
WAIT 		;Verify command buffer contents
/SEND
WAIT UNTIL (P@GSPWB = "OFF")
WAIT	;Verify Input current GIPWB approx 0

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None
;#
;#**************************************************************************
ENDPROC