PROC L_FL_CONFRELS

;Version 3

GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  L_FL_CONFRELS  
;#		   	MMS-F Name: ConfRel 	 
;#		   	SUM Issue:   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:		01/18/95
;#			    Revision:	1.	03/14/95
;#						2.	04/18/95
;#						3.   10/24/95
;#		1.3	Change Description:	
;#
;#			1. Reformat of the steps in the section VI.
;#			   Added Command LBCHBON - COB bias heaters on, and TM check
;#			   LSCHBR - COB bias heaters on.
;#			   Corrected TM check LKORATE to LKOSCRAT.
;#			2. Removed TM check ESECMR is not applied, and moved TM check
;#			   LKOSCRAT to procedure l_ts_contboot.
;#			3. Changed proc's name from TS to FL, there is no TSTOL changes
;#			   and no further input from PI since GSCT#3.
;#
;#		1.4	Point of Contact:  CCazeau
;#
;#			FOT Author:  C.Q	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure will configures the LEB controlled relays.
;#
;#		2.2	Intended Use:
;#
;#			LEB controlled relays configuration
;#
;#		2.3	Duration:	 TBD
;#
;#		2.4  References:	LASCO/EIT EXPERIMENT GUIDE
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			The LEB power must have been commanded on experiment power
;#			and +31v should be off.
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

;**************** PRELIMINARY VERIFICATIONS ****************

SV P@LSI31VRC		;Verify (EXP +31V COMMANDED) parameter is in "OFF" position
SV P@LSIEXPRC		;Verify (Experiment Power) is in "OFF" position

ASK "IS INSTRUMENT CONTROL BOARD A TO BE BOOTED? (Y/N)"
    ANSWER = %UPPER(ANSWER)
 IF (ANSWER .EQ. "Y") THEN

/LBIAON			;Select instrument controller board A
/LB1MAON			;M1 CONTROL ELECTRONICS A ON
/LB2PAON			;PES SIDE A ON

WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSIAR = "ON")	;IC-A SELECTED
WAIT UNTIL (P@LS2PAR = "ON")	;PES-A ON
WAIT UNTIL (P@LS1MAR = "ON")	;M1-A ON

ENDIF

ASK "IS INPUT PARAMETER IS IC-B? (Y/N)"
    ANSWER = %UPPER(ANSWER)
 IF (ANSWER .EQ. "Y") THEN

/LBIBON			;Select instrument controller board B
/LB1MBON			;M1 CONTROL ELECTRONICS B ON
/LB2PBON			;PES SIDE B ON

WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSIBR = "ON")	;IC-B SELECTED
WAIT UNTIL (P@LS1MBR = "ON")	;M1-B ON
WAIT UNTIL (P@LS2PBR = "ON")	;PES-B ON

ENDIF

/LBHMOF			;MAKE UP HEATERS ALL OFF
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LS1CMR = "OFF")		;C1 CAMERA MU HEATER OFF
WAIT UNTIL (P@LS2CMR = "OFF")		;C2 CAMERA MU HEATER OFF
WAIT UNTIL (P@LS3CMR = "OFF")		;C3 CAMERA MU HEATER OFF
WAIT UNTIL (P@LS1MFR = "OFF")		;FP MU HEATER OFF

/LB1FON			;FABRY-PEROT POWER RELAY ON
/LB1CON			;C1 CAMERA ON
/LB2CON			;C2 CAMERA ON
/LB3CON			;C3 CAMERA ON
/EBECON			;EIT CAMERA ON
/LB1RDON			;CAL LAMP DETECTOR RELAY ON
/LBCBSON			;BORESIGHTER RELAY ON

WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LS1CMR = "OFF")		;C1 CAMERA MU HEATER OFF
WAIT UNTIL (P@LS2CMR = "OFF")		;C2 CAMERA MU HEATER OFF
WAIT UNTIL (P@LS3CMR = "OFF")		;C3 CAMERA MU HEATER OFF
WAIT UNTIL (P@LS1MFR = "OFF")		;FP MU HEATER OFF
WAIT UNTIL (P@LS1FR = "ON")		;FP RELAY ON
WAIT UNTIL (P@LS1CR = "ON")		;C1 CAMERA ON
WAIT UNTIL (P@LS2CR = "ON")		;C2 CAMERA ON
WAIT UNTIL (P@LS3CR = "ON")		;C3 CAMERA ON
WAIT UNTIL (P@ESECR = "ON")		;EIT CAMERA ON
WAIT UNTIL (P@LS1RR = "ON")		;CAL LAMP DETECTOR ON
WAIT UNTIL (P@LSCBR = "ON")		;BORESIGHTER ON

ASK "DO YOU WANT TO TURN ON THE COB BIAS HEATERS? (Y/N)"
    ANSWER = %UPPER(ANSWER)
 IF (ANSWER .EQ. "Y") THEN

/LBCHBON			;COB BIAS HEATERS ON
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSCHBR = "ON")	;COB BIAS HEATERS ON

ELSE				;(COB BIAS HEATERS ARE NOT TO BE TURNED ON)

/LBCHBOF			;COB BIAS HEATERS OFF
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSCHBR = "OFF")		;COB BIAS HEATERS OFF

ENDIF


;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************


ENDPROC