PROC L_FL_LEBPWROF

;Version 3

GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  L_FL_LEBPWROF  
;#		   	MMS-F Name: LEBPwrOf 	 
;#		   	SUM Issue:   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:		01/19/95
;#			    Revision: 	   1.03/15/95	  
;#						   2.06/01/95
;#						   3.10/24/95
;#
;#		1.3	Change Description:	
;#
;#			1. Added TM check LSI31VRC - EXP +31V COMMANDED, and LSIEXPRC
;#			   Experiment power status.
;#		 	2. Added procedure k_exp_mon_dis
;#			3. Changed proc's name from TS to FL, there is no TSTOL changes
;#			   and no further input from PI since GSCT#3.
;#
;#		1.4	Point of Contact:  CCazeau
;#
;#			FOT Author:  C.Q	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure will turns power off to the LASCO LEB.
;#
;#		2.2	Intended Use:
;#
;#			POWERS OFF LASCO LEB
;#
;#		2.3	Duration:	 TBD
;#
;#		2.4  References:	LASCO/EIT EXPERIMENT GUIDE
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

IF (P@LSI31VRC = "ON") THEN

/LBTXNF			;EXPERIMENT POWER ON, 31V OFF
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSI31VRC = "OFF")	;31V status

ENDIF

WRITE "VERIFY LASCO/EIT +31V OFF"

IF (P@LSIEXPRC = "ON") THEN

/LBTXFF			;EXPERIMENT POWER OFF, 31V OFF
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSIEXPRC = "OFF")	;EXPERIMENT POWER status

ENDIF

WRITE "VERIFY LASCO/EIT EXP PWR OFF"

S K_EXP_MON_DIS


/KNLPWAFN			;LCL RELAY OFF NOMINAL
/KNLPWBFR			;LCL RELAY OFF REDUNDANT
/LCPWOFN			;LEB POWER OFF
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSPWA = "OFF")	;LCL NOMINAL
WAIT UNTIL (P@LSPWB = "OFF")	;LCL REDUNDANT
WAIT UNTIL (P@LSPWAN = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBN = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWAR = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBR = "OFF")	;LASCO/EIT power status

WRITE "VERIFY LASCO/EIT POWERED OFF"

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************


ENDPROC