PROC L_FL_LEBPWRON

;Version 4

GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  L_FL_LEBPWRON  
;#		   	MMS-F Name: LEBPwrON 	 
;#		   	SUM Issue:   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  	01/18/95
;#			    Revision: 1.03/15/95
;#				      2.04/12/95
;#				      3.10/24/95
;#				      4.12/04/95
;#
;#		1.3	Change Description:	
;#
;#			1. Added section V preliminary verification of LEB temps
;#			   range, and command LCPWOFN - LEB power off.
;#			   Added TM LIPWA - LASCO A current, and LIPWB - B current.
;#			   Corrected LKHKSYNC to LKHK1SYN - HK TM VALIDATION.
;#			2. Adjusted line 162 by omitted the space from LKHK1SYN = 
;#			   H 'A5A1' to LKHK1SYN = H'A5A1'.
;#			3. Changed proc's name from TS to FL, there is no TSTOL changes
;#			   and no further input from PI since GSCT#3.
;#			4. Need Procedure K_exp_mon_ena add to this procedure, and
;#		    	   change the TM display value for mnemonics LIPWA & B from 0.45
;# 			   to 0.6.
;#
;#		1.4	Point of Contact:  CCazeau
;#
;#			FOT Author:  C.Q	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure will turns power on to the LASCO LEB power
;#			supply and computer/memory.
;#
;#		2.2	Intended Use:
;#
;#			POWERS ON LASCO LEB
;#
;#		2.3	Duration:	 TBD
;#
;#		2.4  References:	LASCO/EIT EXPERIMENT GUIDE
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			The LEB should not be turned on if the temperature is outside
;#			the turn-on range of temperatures .
;#
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

;******************** PRELIMINARY VERIFICATION ********************

WRITE "Display l_hk_tmon page to verify the status of LEB temps"

IF (P@QTLI3A < 0) AND (P@QTLI3A > 30) THEN	;Verify if LEB temps outside turn
						;on range (+0C, +30C)
	GOTO STOP
ELSE

ENDIF

STOP:

WRITE "CHECK LASCO/EIT NON-OP HEATERS OFF"

SV P@QSL1
SV P@QSL2
SV P@QSL3
SV P@QSL4

;******************************************************************

/LCPWOFN					;LEB power off
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSPWAN = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBN = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWAR = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBR = "OFF")	;LASCO/EIT power status

ASK "IS INPUT PARAMETER CPU-A? (Y/N)"
    ANSWER = %UPPER(ANSWER)
 IF (ANSWER .EQ. "Y") THEN
/LCPWAONN			;LEB POWER ON A SIDE
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSPWAN = "ON")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWAR = "ON")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBN = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBR = "OFF")	;LASCO/EIT power status

/KNLPWANN			;PDU LCL: LEB NOMINAL ON
WAIT				;Verify contents of command buffer
/SEND

WAIT 60			;Wait for 60 seconds

WAIT UNTIL (P@LIPWA > 0.25) AND (P@LIPWA < 0.60); Verify LASCO A CURRENT 
						; is to be between 0.25
						; and 0.60 amps
WAIT UNTIL (P@LSPWA = "ON")			;LASCO A status
WAIT UNTIL (P@LSPWB = "OFF")			;LASCO B status

ENDIF

ASK "IS INPUT PARAMETER CPU-B? (Y/N)"
    ANSWER = %UPPER(ANSWER)
 IF (ANSWER .EQ. "Y") THEN
/LCPWBONN			;LEB POWER ON B SIDE
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSPWBN = "ON")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBR = "ON")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWAN = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWAR = "OFF")	;LASCO/EIT power status

/KNLPWBNR			;PDU LCL: LEB REDUDANT ON
WAIT				;Verify contents of command buffer
/SEND

WAIT 60			;Wait for 60 seconds

WAIT UNTIL (P@LIPWB > 0.25) AND (P@LIPWB < 0.60); Verify LASCO A CURRENT 
						; is to be between 0.25
						; and 0.60 amps
WAIT UNTIL (P@LSPWB = "ON")	;LASCO B status
WAIT UNTIL (P@LSPWA = "OFF")	;LASCO A status

ENDIF

WRITE "WAITING FOR LEB TO BOOT TCE"

WAIT UNTIL (LKHK1SYN = H'A5A1')		; HK TM valid

/LBTMANL			;TCE MANUAL BOOT (Autoboot intervention)
WAIT				;Verify contents of command buffer
/SEND

WRITE "WAITING FOR AUTOBOOT TIMER TO EXPIRE"

WAIT 120			;Wait for 120 seconds


S K_EXP_MON_ENA

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************


ENDPROC