PROC L_FL_SW_ON

;Version 2

GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  L_FL_SW_ON  
;#		   	MMS-F Name: SwtchON 	 
;#		   	SUM Issue:   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:		01/17/95
;#			    Revision:     1.03/16/95
;#						   2.10/24/95
;#
;#		1.3	Change Description:	
;#
;#			1. Added section V preliminary verification
;#			   Added command KNLPWANN - PDU LCL LEB nominal on
;#			   Added TM check LIPWA, LIPWB, LSPWA, and LSPWB
;#			   Added command KNLPWBNR - PDU LCL LEB redundant on
;#			2. Changed proc's name from TS to FL, there is no TSTOL changes
;#			   and no further input from PI since GSCT#3.
;#
;#		1.4	Point of Contact:  CCazeau
;#
;#			FOT Author:  C.Q	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure will powers the LASCO/EIT experiments on.  The
;#			primary or redundant configuration can be selected depending 
;#			upon the value of an input parameter.
;#
;#		2.2	Intended Use:
;#
;#			POWERS LASCO/EIT EXPERIMENT ON
;#
;#		2.3	Duration:	 TBD
;#
;#		2.4  References:	LASCO/EIT EXPERIMENT GUIDE
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			None
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

/LCPWOFN			;LEB power off (N)
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSPWAN = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBN = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWAR = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBR = "OFF")	;LASCO/EIT power status

ASK "IS INPUT PARAMETER CPU-A? (Y/N)"
    ANSWER = %UPPER(ANSWER)
 IF (ANSWER .EQ. "Y") THEN
/LCPWAONN			;LEB POWER ON A SIDE
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSPWAN = "ON")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWAR = "ON")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBN = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBR = "OFF")	;LASCO/EIT power status

/KNLPWANN			;PDU LCL LEB NOMINAL ON
WAIT				;Verify contents of command buffer
/SEND

WAIT 60			;Wait for 60 seconds

WAIT UNTIL (P@LIPWA > 0.25) AND (P@LIPWA < 0.45)	; Verify LASCO A CURRENT 
										; is to be between 0.25
										; and 0.45 amps
WAIT UNTIL (P@LSPWA = "ON")					;LASCO A status
WAIT UNTIL (P@LSPWB = "OFF")					;LASCO B status

ENDIF

ASK "IS INPUT PARAMETER = CPU-B? (Y/N)"
    ANSWER = %UPPER(ANSWER)
 IF (ANSWER .EQ. "Y") THEN
/LCPWBONN			;LEB POWER ON B SIDE
WAIT				;Verify contents of command buffer
/SEND

WAIT 30			;Wait for 30 seconds

WAIT UNTIL (P@LSPWBN = "ON")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWBR = "ON")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWAN = "OFF")	;LASCO/EIT power status
WAIT UNTIL (P@LSPWAR = "OFF")	;LASCO/EIT power status

/KNLPWBNR			;PDU LCL LEB redundant on
WAIT				;Verify contents of command buffer
/SEND

WAIT 60			;Wait for 60 seconds

WAIT UNTIL (P@LIPWB > 0.25) AND (P@LIPWB < 0.45)	; Verify LASCO A CURRENT 
										; is to be between 0.25
										; and 0.45 amps
WAIT UNTIL (P@LSPWB = "ON")	;LASCO B status
WAIT UNTIL (P@LSPWA = "OFF")	;LASCO A status

ENDIF

WRITE "WAITING FOR LASCO/EIT TO AUTO BOOT"


;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		LASCO/EIT IS NOW AUTO-BOOTING FOR 30 MINUTES
;#
;#**************************************************************************


ENDPROC