PROC m_fl_deprecov
; VERSION 9

GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:   m_fl_deprecov 
;#		   	MMS-F Name:  	 
;#		   	SUM Issue:   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  11-3-94
;#			    Revision:  1.  19-DEC-94  BS
;#                            2.  24-APR-95  GJ
;#				          3.  05-03-95 RR
;#				          4.  5-26-95 RR
;#						5.  8-14-95 GJ
;#						6. 10-30-95 RR
;#						7. 11-2-95 GJ
;#						8. 11-18-95 GJ
;#						9. 11-20-95 GJ	
;#                  
;#
;#		1.3	Change Description:	
;#
;#			1.  m_depreset ->m_deprecov.  Added configs for front door,
;#			    alignment mechanism, and addition limb tracker configs. 
;#			    Changed description and Intended use fields.
;#			2.  Changed comments and goto label
;#			3.  Changed jump point to HCM:, changed comments, added prompt
;#				for oven monitoring
;#			4.  Added proc m_ts_hopspt, m_ts_ccdspt, and m_ts_ovenspt
;#			5.  Added 10 seconds waits and ask if "RESET DEP (Y/N) then
;#			    /mcdprstr /send.
;#			6.  added procedure call for m_ts_dp_patch
;#			7.  changed mspwae to mkpwae
;#			8.  Changed naming convention from m_ts_* to m_fl_*.
;#
;#		1.4	Point of Contact:	CCazeau
;#			FOT Author:  RRowe	ATSC/SOHO	805-3642
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure resets the MDI DEP and recovers to SAFE mode or 
;#			higher.  Turns on all devices normally on. Get DEP to a state
;#			consistant with instrument in SAFE or STANDBY mode depending
;#			on door status.
;#
;#		2.2	Intended Use:
;#
;#			Recover the DEP from a hang up condition.  Use this procedure if 
;#			DEP has been reset/reloaded with the instrument fully in SAFE
;#			or higher mode on S/C bus A.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			MDI in SAFE mode or higher prior to reset.  Contact MDI 
;#			operator as soon as possible.
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

LOCAL GAIN1,GAIN2,XOFF,YOFF,PZTA,PZTB,PZTC,P1,depcount

WAIT;	MDI OPERATOR SHOULD PRINT IWS PAGES

ASK "RESET DEP? (Y/N)"
answer=%UPPER(answer)
IF(answer="Y")THEN

	/MCDPRSTN				;PERFORM DEP RESET
	/SEND

	WAIT 10

	/MCDPRSTR
	/SEND

	WAIT 10
ENDIF

WAIT UNTIL (P@MSPWA = "ON")
WAIT UNTIL (P@MIPWA < 2.0 )
WAIT UNTIL (P@MSPWB = "OFF")

s m_fl_dp_patch

ask "What is current DEP reset count" depcount
depcount=(depcount+1)*256
depcount=%hex(depcount,4)

/mbdpml,1000,8C8C,$depcount
/send

wait until(P@CMD_STATE#TELECOMMAND = "AVAILABLE")

/MBPWAEON			;Instruct DEP AE power is on
/SEND

WAIT UNTIL (P@MSPWAEN = "ON")
;WAIT UNTIL (P@MKPWAE = "ON")

WAIT					;RESET ALL MOTOR CONTROLLERS

/MBSHRS			;RESET SHUTTER
/MBM1RS			;RESET MTM1
/MBM2RS			;RESET MTM2
/MBPARS			;RESET PAW
/MBC1RS			;RESET CAL1
/MBC2RS			;RESET CAL2
/MBFDRS			;RESET FD
/MBAM1RS			;RESET AM1
/MBAM2RS			;RESET AM2
/SEND

WAIT UNTIL (MKM1POS = 255)
WAIT UNTIL (MKM2POS = 255)
WAIT UNTIL (MKPAPOS = 255)
WAIT UNTIL (MKC1POS = 255)
WAIT UNTIL (MKC2POS = 255)

wait until(P@CMD_STATE#TELECOMMAND = "AVAILABLE")

/MBPWTM1O			;tell DEP prime 160k tm i/f is selected
/SEND

WAIT UNTIL (MKTMSEL = 1)
WAIT UNTIL (MSTMSELN = 1)
WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
/KNK12000,0020			;set DEP local on-board time
/SEND

WAIT;	'GO' TO INSTRUCT DEP THAT IP IS ON

/MBPWIPON				;instruct DEP that IP and camera  on
/SEND

WAIT UNTIL (P@MSPWIPN = "ON")
WAIT UNTIL (P@MSPWIPR = "ON")
WAIT UNTIL (P@MKPWIP = "ON")

/MBPWCMON				;INSTRUCT DEP CAMERA IS ON
/SEND

WAIT UNTIL (P@MKPWCM = "ON")
WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
/MBCMAADC,0003			;instruct DEP amp is A, CCD offset is 3(aadc = 3)
/SEND

WAIT;	'GO' TO INSTRUCT DEP THAT INTERNAL MECHANSIMS ARE ON

/MBPWSHON			;switch on shutter for DEP
/MBPWM1ON			;switch on MTM1 for DEP
/MBPWM2ON			;switch on MTM2 for DEP
/MBPWPAON			;switch on PAW for DEP
/MBPWC1ON			;switch on CAL1 for DEP
/MBPWC2ON			;switch on CAL2 for DEP
/SEND

WAIT UNTIL (P@MKPWSH = "ON")
WAIT UNTIL (P@MKPWM1 = "ON")
WAIT UNTIL (P@MKPWM2 = "ON")
WAIT UNTIL (P@MKPWPA = "ON")
WAIT UNTIL (P@MKPWC1 = "ON")
WAIT UNTIL (P@MKPWC2 = "ON")



/MBPWLTON			;INSTRUCT DEP LIMB TRACKER IS ON
/SEND

WAIT UNTIL (P@MKPWLT = "ON")

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")
/MBLTOPNL			;LIMB TRACKER TO OPEN LOOP
/SEND

WAIT UNTIL (P@MKLTLOOP = "OPEN" )

WAIT		;VERIFY MDI OPERATOR READY WITH LIMB TRACKER CONFIG

/MBLTPDIO			;SELECT PRIME DIODES
/MBLTPOUT
/MBLTLOGN			;SELECT LOW GAIN
/MBLTFINE			;SELECT FINE OFFSETS
/SEND

ASK "WHAT IS THE X GAIN FOR LIMB TRACKER(4 DIGIT HEX)"GAIN1
ASK "WHAT IS THE Y GAIN FOR LIMB TRACKER(4 DIGIT HEX)"GAIN2

/MBLTXGN,$GAIN1
/MBLTYGN,$GAIN2
WAIT			;VERIFY BUFFER CONTENTS
/SEND

WAIT UNTIL (MKLTXGN = H'$GAIN1')
WAIT UNTIL (MKLTYGN = H'$GAIN2')

ASK "WHAT IS THE X OFFSET(4 digit hex)"XOFF
ASK "WHAT IS THE Y OFFSET(4 digit hex)"YOFF

/MBLTXOFS,$XOFF
/MBLTYOFS,$YOFF
WAIT 		;VERIFY BUFFER CONTENTS
/SEND

WAIT UNTIL (MKLTXOFS = H'$XOFF')
WAIT UNTIL (MKLTYOFS = H'$YOFF')



ASK "WHAT IS THE PZT A OFFSET(4 digit hex)"PZTA
ASK "WHAT IS THE PZT B OFFSET(4 digit hex)"PZTB
ASK "WHAT IS THE PZT C OFFSET(4 digit hex)"PZTC

/MBLTAOFS,$PZTA
/MBLTBOFS,$PZTB
/MBLTCOFS,$PZTC
WAIT;		VERIFY BUFFER CONTENTS
/SEND

WAIT UNTIL (MKLTAOS = H'$PZTA')
WAIT UNTIL (MKLTBOS = H'$PZTB')
WAIT UNTIL (MKLTCOS = H'$PZTC')

;Check if the front door is closed.  
;
IF((P@MSFDCLN="CLOSED") and (P@MSFDCLR="CLOSED")) then;	Verify the front door is not closed (redundant).
  IF((P@MSFDOPN=" NOT OPEN") and (P@MSFDOPR="NOT OPEN")) then;		Verify the front door is open (redundant).
    IF((P@MKFDMTR1="CLOSED") and (P@MKFDMTR2="CLOSED")) then;	Verify the motor2 indicates not closed.
      IF((P@MKFDOPN1="NOT OPEN") and (P@MKFDOPN2="NOT OPEN")) then;
        /MBPWFDON;	Front door power on
	   /send
      endif
    endif
  endif
endif

ASK"WAS AM POWERED ON? (Y/N)"
ANSWER=%UPPER(ANSWER)
IF (ANSWER="Y") THEN
	/MBPWAMON;	AM POWERED ON   ;Alignment Mechanism
	/SEND

	WAIT UNTIL(P@MKPWAM="ON");	VERIFY AM ON

ELSE

	/MBPWAMOF;	AM POWERED OFF
	/SEND
	
	WAIT UNTIL(P@MKPWAM="OFF");	VERIFY AM OFF

ENDIF

ASK"WAS THE HOP ON? (Y/N)"
ANSWER=%UPPER(ANSWER)
IF(ANSWER="Y") THEN
	/MBPWHOPN;	HOP ON	
	/SEND
	WAIT UNTIL(P@MKPWHOP="ON");	VERIFY HOP ON
	s m_fl_hopspt	;	set HOP set point

ELSE

	/MBPWHOPF;	HOP OFF
	/SEND
	WAIT UNTIL(P@MKPWHOP="OFF");	VERIFY HOP OFF

ENDIF

HCM:

s m_fl_ccdspt;	set the CCD op heater set point

WAIT;	'GO' TO SWITCH ON PRIME OVEN CONTROLLER

/MBPWHPON;	PRIME OVEN CONTROLLER ON
/SEND

WAIT UNTIL(P@MKPWHPO="ON")

s m_fl_ovenspt;	set the prime oven set point

ask"Does the MDI operator want to enable Oven Monitoring (Y/N)?"
answer=%upper(answer)
if(answer="Y") then
  S M_FL_OVENMON
endif

SV P@MIPWA
SV P@MIPWB
WAIT;	RECORD THE MDI CURRENTS.  PRIME SHOULD BE LESS THAN 2.0


;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
end:
ENDPROC