PROC m_fl_dynloic
;Version 2	
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: m_fl_dynloic    
;#		   	MDI Name:  m_dynloic	 
;#		   	SUM Issue:  	N/A
;#			Simulator Validation Status:  
;#
;#		1.2	Date Created:  11/14/96
;#			    Revision:   1.  11/23/96  PB
;#
;#		1.3	Change Description:	
;#
;#			1.  Added data word 0004 to all /MBIPLDIN commands.
;#			2.  Increased wait between sending commands to downlink continuum image
;#			    and sending commands to downlink LOI_V Buffer. 
;#
;#		1.4	Point of Contact:  H. Benefield	
;#			Author: C. Ginther 	ATSC/SOHO	   301-286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure dumps the LOI circular Velocity and Continuum
;#			buffers and downlinks a 30s continuum filtergram in parallel
;#			with 30s dopplergrams.
;#
;#		2.2	Intended Use:
;#			
;#			Perform MDI LOI buffer dump during dynamics mode continuous	
;#			contact with nominal line depth images.
;#
;#		2.3	Duration:	
;#
;#			5 min. (Up to 9mn wait to avoid ALT sequence)
;#
;#		2.4	References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None.
;#
;#		3.2	Critical Activities
;#
;#			None.
;#
;#		3.3	Special Constraints or Activities
;#
;# 			MDI in SAFE or higher mode.  High rate telemetry support    		
;#     		required for duration of DEP/IP configuration and campaign
;#     		execution.  VC2 support is preferred, but not required.
;#     		Should be executed with 6<MKSQINTC<95 to avoid ALT period.
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:


IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

IF ((P@KKTMMODE < 3) OR (P@KKTMFID < 1)) THEN
	WRITE "TM IS NOT IN HIGH RATE."
	GOTO OUT
ENDIF

LOCAL CCNT,TCCNT

WAIT 10 ;    WAIT FOR MLTCCNT TO UPDATE
CCNT = MKTCCNT;  Store DEP Command Counter

IF ((MKSQINTC > 94) OR (MKSQINTC < 7)) THEN
	WRITE "Waiting for ALT to complete, maximum of nine minutes."
ENDIF

WAIT UNTIL ((MKSQINTC > 6) AND (MKSQINTC < 95))

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

/MBIPLDIN,0004,0140,0693,0000		; D/L continuum, IP reg 1683
/SEND
WAIT 120;				Wait for continuum D/L

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

/MBIPLDIN,0004,0140,070A,0001		; D/L LOI-CB-V, IP reg 1802
/MBIPLDIN,0004,0140,070B,0001		; D/L LOI-CB-I, IP reg 1803
/MBIPLDIN,0004,0140,0693,0001		; D/L line depth, IP reg 1683
/SEND

TCCNT = CCNT + 4

IF (TCCNT > 255) THEN
	TCCNT = TCCNT -256
ENDIF

WAIT UNTIL (MKTCCNT = TCCNT);		Verify command receipt by DEP

OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None
;#
;#**************************************************************************
RETURN
ENDPROC