PROC m_fl_dynloil 
;Version 2	
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: m_fl_dynloil     
;#		   	MMS-F Name: m_dynloil 	 
;#		   	SUM Issue:  N/A 	
;#			Simulator Validation Status:  N/A
;#
;#		1.2	Date Created: 11-14-96  
;#			    Revision:  1:  15-NOV-96  CG
;#                                     2:  17-NOV-96  JP
;#		1.3	Change Description:	
;#
;#			1.  Added data word 0004 to all /MBIPLDIN commmands.
;#                      2.  Change timed wait after cmd for D/L LINE-DEPTH
;#                          IP REG 1683 to 120 sec.
;#
;#		1.4	Point of Contact: H. Benefield	
;#			Author:  Paul Beckwith    	ATSC/SOHO      286-4799	
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure dumps the LOI circular Velocity and Continuum
;#			buffers and downlinks a 30s line depth in parallel with 30s
;#			dopplergrams.
;#
;#		2.2	Intended Use:
;#			
;#			Perform MDI LOI buffer dump during dynamics mode continous
;#			contact with nominal continuum intensity images.
;#
;#		2.3	Duration:	 
;#			
;#			5mn (Up to 9mn wait to avoid ALT sequence)
;#
;#		2.4	References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			MDI in safe or higher mode. High rate telemetry support required 
;#			for duration of DEP/IP configuration and campaign execution.
;#			VC2 support is perferred but not required.
;#			Should be executed with 6 < MKSQINTC < 95 to avoid ALT period			
;#			
;#     		
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:


IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR  ;Clearing the Command Buffer.
ENDIF

IF ((P@KKTMMODE < 3) AND (P@KKTMFID < 1)) THEN
	WRITE "TM IS NOT IN HIGH RATE."	
	GOTO OUT
ENDIF

LOCAL CCNT,TCCNT

WAIT 10; WAIT FOR MKTCCNT TO UPDATE
CCNT=MKTCCNT;	STORE DEP COMMAND COUNTER

IF ((MKSQINTC > 94) OR(MKSQINTC < 7)) THEN
     WRITE "WATING FOR ALT TO COMPLETE, MAXIMUM OF NINE MINUTES."
ENDIF

WAIT UNTIL ((MKSQINTC >6) AND (MKSQINTC <95))

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

/MBIPLDIN,0004,0140,0693,0001 ;D/L LINE-DEPTH, IP REG 1683
/SEND
WAIT 120; WAIT FOR CONTINUUM D/L

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

/MBIPLDIN,0004,0140,070A,0001 ;D/L LOI-CB-V, IP REG 1802
/MBIPLDIN,0004,0140,070B,0001 ;D/L LOI-CB-I, IP REG 1803
/MBIPLDIN,0004,0140,0693,0000 ;D/L CONTINUUM, IP REG 1683
/SEND

TCCNT = CCNT + 4

IF TCCNT > 255 THEN
TCCNT = TCCNT -256
ENDIF

WAIT UNTIL(MKTCCNT=TCCNT);		VERIFY COMMAND RECEIPT BY DEP

OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None
;#
;#**************************************************************************
RETURN
ENDPROC