PROC m_fl_fdclose
;Version 4
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  m_fdclose	
;#		    MMS-F Name:	
;#		    SUM Issue:	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:	9-23-94
;#				Revision:	1.  2-21-95  RR
;#                            2.  4-24-95  GJ
;#						3.  05-04-95 RR
;#						4.  11/18/95	GJ
;#
;#		1.3	Change Description:	
;#
;#			1.  changed comments to reflect procedure operation
;#			2.  changed comments and removed waits, added new logic
;#			3.  corrected logic for door close check
;#			4.  Changed naming convention from m_ts_* to m_fl_*.
;#			
;#		1.4	Point of Contact:	
;#
;#			FOT Author:  RRowe	ATSC/SOHO	805-3642
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure powers up the MDI front door, closes
;#			the door with both motors, verifies the open status
;#			for the door and leaves the door motor controller
;#			powered ON.  Closing the door is part of the transition
;#			from STANDBY to SAFE mode.
;#
;#		2.2	Intended Use:
;#
;#			To close the MDI front door and transition from STANDBY
;#			to SAFE mode.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			MDI in SAFE mode.  Medium rate telemetry support required for
;#			duration of power on sequence.  MDI Operator on station to support
;#			verification of procedure.  MDI operator verification required for
;#			each step before continuing.
;#			
;#**************************************************************************
;#	4.0	STEPS:
;#		
;
BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

IF (P@KKTMMODE = "HK") THEN	;Check TM is not in LR
WRITE "TM IS NOT IN MEDIUM/HIGH RATE."
GOTO END
ELSE
ENDIF

;
;
;Check if the front door is closed.  If so, skip procedure.
;
IF((P@MSFDCLN != "CLOSED") or (P@MSFDCLR != "CLOSED") or     ;;
   (P@MSFDOPN != "NOT OPEN") or (P@MSFDOPR != "NOT OPEN")or  ;;
   (P@MKFDMTR1 != "CLOSED") or (P@MKFDMTR2 != "CLOSED") or  ;;
   (P@MKFDOPN1 != "NOT OPEN") or (P@MKFDOPN2 != "NOT OPEN")) then
        goto close
endif

goto end

close:
;
WAIT;					'GO' to turn on the front door controller
;
/mbfdrs;				reset the front door controller
/SEND
;
wait 5
;
/mbpwfdon;				turn on the 15V power to the front door
/SEND
;
WAIT UNTIL(P@MKPWFD="ON");		Telemetry verification of front door power
;
WAIT;					'GO' to close front door
;
/mbfdbc;				close front door with both motors
/SEND
;
WAIT UNTIL(P@MKFDMOVE="MOVING");	VERIFY MOTION
;
;							The following will verify the door closing
;
WAIT UNTIL(P@MSFDCLN="CLOSED");		Verify the door is closed
WAIT UNTIL(P@MSFDCLR="CLOSED");		Verify the door ist closed (redundant)	
;
WAIT UNTIL(P@MSFDOPN="NOT OPEN");	Verify the door is not open
WAIT UNTIL(P@MSFDOPR="NOT OPEN");	Verify the door is not open (redundant)
;
WAIT UNTIL(P@MKFDMTR1="CLOSED");	Verify front door motor 1 indicates closed
WAIT UNTIL(P@MKFDMTR2="CLOSED");	Verify front door motor 2 indicates closed
;
WAIT UNTIL(P@MKFDOPN1="NOT OPEN");	Verify front door is not open
WAIT UNTIL(P@MKFDOPN2="NOT OPEN");	Verify front door is not open
;	
WAIT UNTIL(P@MKFDMOVE="NOT MOVING");	Verify the door is not open
;
WAIT UNTIL(P@MKFDSTAT="COMPLETED");		Verify the action is complete
;
WAIT UNTIL(P@MKFDFUNC="CLOSE BOTH");
;
SV P@MKFDTIME
WAIT;				Record the close time.  Should be about 400.
;
WAIT UNTIL(P@MKPWFD="ON");  VERIFY 15V POWER TO FRONT DOOR
WAIT;	VERIFY POWER TO FRONT DOOR
;
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
end:
ENDPROC