PROC m_fl_loidump
;Version 2	
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: m_fl_loidump	   
;#		   	Experiment Name:  m_loidump	 
;#		   	SUM Issue:   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  5-21-96
;#			    Revision:  1.	5-30-96	JSP
;#			    			2.	11-14-96	CBG
;#
;#		1.3	Change Description:	
;#				1.	Added check to avoid interruption by magnetograms
;#				2. Tailored procedure to support continuous contact in 
;#				   campaign mode.		
;#		
;#			None.
;#
;#		1.4	Point of Contact:  RRowe	
;#			FOT Author:  RRowe	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure performs a campaign to dump the LOI 
;#			circular Vel and Cont buffers and downlink a 30s continuum
;#			filtergram, and dump three half IP memory pages in
;#			parallel with 30s dopplergrams	
;#
;#		2.2	Intended Use:
;#		
;#			Perform MDI LOI buffer dump campaign during continuous contact
;#			in campaign mode.
;#		
;#		2.3	Duration:	5mn    (Up to 9 minute wait to avoid ALT sequence)
;#
;#		2.4	References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#		MDI in SAFE or higher mode.  High rate telemetry support
;#		required for duration of DEP/IP configuration and campaign
;#		execution.  VC2 support is preferred, but not required.
;#  		MDI in campaign mode to support continuous contact period.   		
;#     		
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:


IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

IF((P@KKTMMODE<3) AND (P@KKTMFID<1)) THEN
WRITE "TM IS NOT IN HIGH RATE."
GOTO OUT
ENDIF

LOCAL CCNT,TCCNT

IF (MKSQRG4 <> 1) THEN
	WRITE "MDI IS NOT IN CAMPAIGN MODE."
	GOTO OUT
ENDIF

WAIT 10;	WAIT FOR MLTCCNT TO UPDATE
CCNT=MKTCCNT;	STORE DEP COMMAND COUNTER

;SET NEW CAMPAIGN FLAG ADDRESS TO CONT1_CONT1(200 decimal) CAMPAIGN

/MBSQREG,0045,00C8
/SEND

WAIT UNTIL (MKSQRG17 = H'00C8')

IF ((MKSQINTC > 94) OR (MKSQINTC < 1)) THEN
	WRITE "Waiting for ALT to complete, maximum of three minutes."
ENDIF

WAIT UNTIL ((MKSQINTC > 0) AND (MKSQINTC < 95)) ; Wait for ALT

WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE")

;SET NEW CAMPAIGN AND CHAIN FLAGS ON

/MBSQREG,0044,0001
/MBSQREG,0048,0001
/SEND

TCCNT = (CCNT + 3) MOD 256

WAIT UNTIL (MKTCCNT = TCCNT);    Verify command receipt by DEP

WAIT UNTIL (MKSQRG16 = H'00C8');   Verify that campaign starts

OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None
;#
;#**************************************************************************
RETURN
ENDPROC