PROC m_fl_ltchk
;Version 4
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  M_TS_LTCHK  
;#		   	MMS-F Name:  	 
;#		   	SUM Issue:   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  20-DEC-94   BS 
;#			    Revision:  1. 1/25/95 RR
;#                            		2. 4/24/95   GJ
;#					3. 5-26-95 RR
;#					4. 11/18/95 GJ
;#
;#		1.3	Change Description:	
;#
;#			1. 1/25/95	ADDED FOLLOWING LOGIC TO PROC:
;#				
;#				XOFF1 = MKLTXOFS
;#				YOFF1 = MKLTYOFS
;#
;#				XOFF = XOFF1+H'0C'
;#				YOFF = YOFF1+H'0C'
;#
;#				XOFF = %HEX(XOFF,4)
;#				YOFF = %HEX(YOFF,4)
;#
;#				/MBLTXOFS,$XOFF
;#				/MBLTYOFS,$YOFF
;#			2. changed comments and removed waits
;#			3. corrected syntax errors
;#			4. Changed name convention from m_ts_* to m_fl_*.
;#
;#		1.4	Point of Contact:	
;#			FOT Author:  BSAPPER	ATSC/SOHO	805-3749
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure performs a short checkout of limb tracker
;#			commanding and telemetry monitors.
;#
;#		2.2	Intended Use:
;#
;#			Initial checkout of MDI LT subsystem.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			MDI in SAFE mode.  MR TLM required.  MDI operator on station
;#			to support verification of procedure.
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL XOFF,YOFF,XOFF1,YOFF1

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

IF (P@KKTMMODE = "HK") THEN	;Check TM is not in LR
WRITE "TM IS NOT IN MEDIUM/HIGH RATE."
GOTO END
ELSE
ENDIF

;	RECORD LT STATUS
S M_FL_LTPRN

WAIT;	'GO' FOR OFFSETS TO 0C

XOFF1 = MKLTXOFS
YOFF1 = MKLTYOFS

XOFF = XOFF1+H'0C'
YOFF = YOFF1+H'0C'

XOFF = %HEX(XOFF,4)
YOFF = %HEX(YOFF,4)

/MBLTXOFS,$XOFF
/MBLTYOFS,$YOFF
wait;	go to send
/send

WAIT UNTIL (MKLTXOFS = H'$XOFF')
WAIT UNTIL (MKLTYOFS = H'$YOFF')

;	RECORD LT STATUS
S M_FL_LTPRN

WAIT;	'GO' FOR OFFSETS TO F3

SV XOFF
SV YOFF
WAIT

XOFF = H'$XOFF1' + H'F3'
YOFF = H'$YOFF1' + H'F3'

XOFF = %HEX(XOFF,4)
YOFF = %HEX(YOFF,4)

/MBLTXOFS,$XOFF
/MBLTYOFS,$YOFF

WAIT;	GO TO SEND
/SEND


WAIT UNTIL (MKLTXOFS = H'$XOFF')
WAIT UNTIL (MKLTYOFS = H'$YOFF')

;	RECORD LT STATUS
S M_FL_LTPRN

WAIT;	'GO' FOR OFFSETS TO 0

XOFF1=%HEX(XOFF1,4)
YOFF1=%HEX(YOFF1,4)

/MBLTXOFS,$XOFF1		;SET X OFFSET
/MBLTYOFS,$YOFF1		;SET Y OFFSET
WAIT
/SEND

WAIT UNTIL (MKLTXOFS = H'$XOFF1')
WAIT UNTIL (MKLTYOFS = H'$YOFF1')

WAIT;	'GO' FOR PZT A OFFSETS TO HEX 20

/MBLTAOFS,0020			;SET PZT A OFFSETS
/SEND

WAIT UNTIL (MKLTAOS = H'0020')

;	RECORD LT STATUS
S M_FL_LTPRN

WAIT;	'GO' FOR PZT A OFFSETS TO 0060

/MBLTAOFS,0060			;SET PZT A OFFSET
/SEND

WAIT UNTIL (MKLTAOS = H'0060')

;	RECORD LT STATUS
S M_FL_LTPRN

WAIT;	GO TO SET PZT A TO 0040 AND PZT B TO 0020

/MBLTAOFS,0040			;SET PZT A OFFSET
/MBLTBOFS,0020			;SET PZT B OFFSET
/SEND

WAIT UNTIL (MKLTAOS = H'0040')
WAIT UNTIL (MKLTBOS = H'0020')

;	RECORD LT STATUS
S M_FL_LTPRN

WAIT;	SET PZT B OFFSET TO 0060

/MBLTBOFS,0060			;SET PZT B OFFSET
/SEND

WAIT UNTIL (MKLTBOS = H'0060')

;	RECORD LT STATUS
S M_FL_LTPRN

WAIT;	SET PZT B TO 0040 AND PZT C TO 0020

/MBLTBOFS,0040			;SET PZT B OFFSET
/MBLTCOFS,0020			;SET PZT C OFFSET
/SEND

WAIT UNTIL (MKLTBOS = H'0040')
WAIT UNTIL (MKLTCOS = H'0020')

;	RECORD LT STATUS
S M_FL_LTPRN

WAIT;	SET PZT C TO 0060

/MBLTCOFS,0060			;SET PZT C OFFSET
/SEND

WAIT UNTIL (MKLTCOS = H'0060')

;	RECORD LT STATUS
S M_FL_LTPRN

WAIT;	SET PZT C TO 0040

/MBLTCOFS,0040			;SET PZT C OFFSET
/SEND

WAIT UNTIL (MKLTCOS = H'0040')

;	RECORD LT STATUS
S M_FL_LTPRN

SV P@MIPWA
SV P@MIPWB
WAIT			;RECORD MDI CURRENT (MIPWA,MIPWB) < 1.5

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
end:
ENDPROC