PROC m_fl_pconsca
;Version 6
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:		M_fl_PCONSCA	
;#		    MMS-F Name:		
;#		    SUM Issue:	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:	9-SEP-94
;#				Revision: 1. 11-29-94
;#					2. 4-26-95
;#					3. 5-26-95
;#					4. 8-14-95 GJ
;#					5. 11-02-95 GJ
;#					6. 11/18/95 GJ
;#
;#		1.3	Change Description:	
;#
;#			1.  Changed TM check to end proc if in LR
;#			2.  Added mdi_hrtlm and mdi_cmd instead of cmd
;#			3. Corrected syntax errors
;#			4. Added wait 5 and 10 seconds, /mcdprstr and telephone
;#			   number.
;#			5. Deleted Global and added Local and deleted if else if
;#			   statement and added PRIME or REDUNDANT.
;#			6. Changed name convention from m_ts_* to m_fl_*.
;#
;#
;#		1.4	Point of Contact:	
;#			FOT Author: RRowe	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#			
;#			This procedure powers up the MDI instrument with the primary
;#			MDI power converters on the spacecraft primary power interface (A)
;#		        and primary telecommand and telemetry interfaces.  It powers on
;#			PC1, PC2, DEP and AE.  It is initiated with MDI in OFF mode and
;#			if successful, completes with MDI in SLEEP mode.
;#			
;#
;#		2.2	Intended Use:
;#
;#			Controlled initial power on of MDI from OFF to SLEEP.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References:
;#
;#			"stol_list.tst" provided from SOI-MDI and SOHO FOT meeting.
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			Medium rate telemetry support required for duration of power on
;#			sequence.  MDI Operator on station to support verification of 
;#			procedure.  MDI Operator verification required for each step
;#			before continuing.
;#**************************************************************************
;#	4.0	STEPS:
;#		
;
BEGIN:
;
LOCAL MDI_HRTLM, MDI_CMD

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF
;
IF (P@KKTMMODE = "HK") THEN	;Check TM is not in LR
WRITE "TM IS NOT IN MEDIUM/HIGH RATE."
GOTO END
ELSE
ENDIF
;


P M_PWR_1,1,,+325+450
WAIT UNTIL((P@MIPWA>=0)AND(P@MIPWA<0.05))	;Current should be approx zero
WAIT UNTIL((P@MIPWB>=0)AND(P@MIPWB<0.05))	;Current should be approx zero
WAIT UNTIL(P@MSPWA="OFF");	Wait until MSPWA indicates OFF
WAIT UNTIL(P@MSPWB="OFF");	Wait until MSPWB indicates OFF
;
WAIT	;Verify currents and 'GO' to command MDI all off.
;
/mcallofn	;Safety command to ensure MDI is OFF, before powering on
/SEND
;
WAIT UNTIL(P@MSPWDPN="OFF");	Verify DEP is OFF.
WAIT UNTIL(P@MSPWAEN="OFF");	Verify App electronics are OFF.

WAIT;				'GO' to switch MDI power converters to B bus.
;
/mcpc1bn;		PRIMARY CONVERTER 1 TO B(N)
/mcpc2bn;		PRIMARY CONVERTER 2 TO B(N)
/mcrc1bn;		PRIMARY CONVERTER 1 TO B(N)
/mcrc2bn;		PRIMARY CONVERTER 2 TO B(N)
/SEND
;
WAIT UNTIL(P@MSPC1N="B");	Verify command execution.
WAIT UNTIL(P@MSPC2N="B");	Verify command execution.
WAIT UNTIL(P@MSRC1N="B");	Verify command execution.
WAIT UNTIL(P@MSRC2N="B");	Verify command execution.
;
WAIT;				'GO' for s/c bus A power on
;
/KNMPWANN;	S/C BUS A POWER ON
/SEND
;
WAIT UNTIL(P@MSPWA="ON");	Verify s/c bus A power on
WAIT UNTIL((P@MIPWA>=0)AND(P@MIPWA<0.05))	;Current should be approx zero

s k_exp_mon_ena

WAIT;				'GO' to send ALL OFF command.
;
/mcallofn;	SEND MDI ALL OFF CMD
/SEND
;
WAIT UNTIL(P@MSPWDPN="OFF");	Verify DEP is OFF.
WAIT UNTIL(P@MSPWAEN="OFF");	Verify App electronics are OFF.
;

ASK_HRTLM:
ASK "USE PRIME OR REDUNDANT 160K IF (PRI/RED)?" MDI_HRTLM
MDI_HRTLM = %UPPER(MDI_HRTLM)
IF ((MDI_HRTLM <> "RED") and (MDI_HRTLM <> "PRI")) THEN 
GOTO ASK_HRTLM
ENDIF;

IF (MDI_HRTLM = "RED")THEN
	/MCTMSELN				;SET 160K INTERFACE RELAY
	/SEND
ENDIF

WAIT;				'GO' to switch pc2 to A bus.
;
/mcpc2an;		PC2 TO A BUS
/SEND
;
WAIT UNTIL(P@MSPC2N="A")   ;Verify primary converter 2 (PC2) is on the A bus.
;
SV P@MIPWA
;				Record the MDI current.  This should be 
WAIT;				approximately 0.3.
;
WAIT;				'GO' to switch on DEP.
;
/mcdponn;	DEP POWER ON
/SEND
;
WAIT UNTIL(P@MSPWDPN="ON");	Verify DEP is powered ON.
;

ASK "WILL THE PRIME OR RED BLOCK CMD I/F BE USED (PRI/RED)?"MDI_CMD
MDI_CMD = %UPPER(MDI_CMD)
IF (MDI_CMD = "RED") THEN

	/MCTCMLN				
	/SEND

ENDIF

SV P@MIPWA
;				Record the MDI current.  This should be 
WAIT;				approximately 0.4.
;
WAIT;				'GO' to switch on apps electronics.
;
/MBPWAEON;		POWER ON APPS ELECTRONICS
/SEND

WAIT 5
;
WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE"); reset DEP to recover fom AE power up.
;
/MCDPRSTN;	RESET DEP
/MCDPRSTR
/SEND

WAIT 10

;				 resend AE power on to get correct
WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE"); DEP power indication.
;
/MBPWAEON;		POWR ON AE
/SEND
;
WAIT UNTIL(P@MSPWAEN="ON")	;Verify App electronics are powered ON.
;
						;'GO' to send command to tell DEP which 
WAIT						;160k TLM interface is selected.
WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE"); DEP power indication.

IF (MDI_HRTLM = "PRI") THEN
	/MBPWTM1o
	/SEND

ELSE
	/MBPWTM2o
	/SEND

ENDIF;

;
WAIT;				'GO' to set DEP local on-board time.
;
/knk12000,0020;	DISTRIBUTE OBT TO MDI
/SEND
;
WAIT;				'GO' to reset all motor controllers.
;
/mbshrs;	SHUTTER RESET
/mbm1rs;	MTM1 RESET
/mbm2rs;	MTM2 RESET
/mbpars;	PA RESET
/mbc1rs;	C1 RESET
/mbc2rs;	C1 RESET
/mbfdrs;	FRONT DOOR STATUS
/mbam1rs;	AM1 RESET
/mbam2rs;	AM2 RESET
/SEND
;
WAIT;				'GO' to switch pc1 to A bus.
;
/mcpc1an;		PC1 TO A BUS
/SEND
;
WAIT UNTIL(P@MSPC1N="A");	Verify PC1 is connected to A bus.
;
SV P@MIPWA
;				Record the MDI current.  This should be 
WAIT;				approximately 0.7.
;
WAIT UNTIL(P@MKPWAE="ON")	;Verify application is on I/F power.

IF(MDI_HRTLM="PRI") THEN
	WAIT UNTIL(P@MKTMSEL="1")	;Verify TM selection enabled.
	WAIT UNTIL(P@MSTMSELN="1")	;Verify TM selection enabled.
ELSE
	WAIT UNTIL(P@MKTMSEL="2")	;Verify TM selection enabled.
	WAIT UNTIL(P@MSTMSELN="2")	;Verify TM selection enabled.
endif
;
SNAP M_PWR_1,,PCSONSCA.RPT,OVERWRITE
;
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
END:
ENDPROC