PROC m_fl_rconscb
;Version 6
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:		M_TS_RCONSCB	
;#		    MMS-F Name:		
;#		    SUM Issue:	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:	9-SEP-94
;#				Revision: 1. 11-29-94	
;#					2. 21-DEC-94
;#					3. 1/25/95 RR
;#					4. 5-26-95 RR
;#					5. 11-2-95 GJ
;#					6. 11/18/95 GJ
;#
;#		1.3	Change Description:	
;#
;#			1.  CHanged TM check to end proc if in LR
;# 			2.  Added promps for which 160k relay to be used, and which
;#			    block cmd i/f to be used.  Added cmd to tell DEP which 
;#			    160k relay to use.
;#			3.  Added s k_exp_mon_ena.prc
;#			4.  Corrected syntax errors
;#			5.  Deleted Global and added Local and deleted if else if
;#			    statement and added PRIME or REDUNDANT.
;#			6.  Changed name convention from m_ts_* to m_fl_*.
;#
;#
;#
;#		1.4	Point of Contact:	
;#			FOT Author: RRowe	ATSC/SOHO	805-3642
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#			
;#			This procedure powers up the MDI instrument with the redundant
;#			MDI power converters on the spacecraft primary power interface (B)
;#		     It prompts for and sets TC and TM i/fs to prime or red.It powers on
;#			PC1, PC2, DEP and AE.  It is initiated with MDI in OFF mode and
;#			if successful, completes with MDI in SLEEP mode.
;#			
;#
;#		2.2	Intended Use:
;#
;#			Controlled initial power on of MDI from OFF to SLEEP.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References:
;#
;#			"stol_list.tst" provided from SOI-MDI and SOHO FOT meeting.
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			Medium rate telemetry support required for duration of power on
;#			sequence.  MDI Operator on station to support verification of 
;#			procedure.  MDI Operator verification required for each step
;#			before continuing.
;#**************************************************************************
;#	4.0	STEPS:
;#		
;
BEGIN:
;
LOCAL MDI_HRTLM, MDI_CMD
IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

IF (P@KKTMMODE = "HK") THEN	;Check TM is not in LR
WRITE "TM IS NOT IN MEDIUM/HIGH RATE."
GOTO END
ENDIF


P M_PWR_1,1,,+325+450
WAIT UNTIL((P@MIPWA>=0)AND(P@MIPWA<0.05))	;Current should be approx zero
WAIT UNTIL((P@MIPWB>=0)AND(P@MIPWB<0.05))	;Current should be approx zero
WAIT UNTIL(P@MSPWA="OFF");	Wait until MSPWA indicates OFF
WAIT UNTIL(P@MSPWB="OFF");	Wait until MSPWB indicates OFF
;
WAIT	;Verify currents and 'GO' to command MDI all off.
;
/mcallofn	;Safety command to ensure MDI is OFF, before powering on
/SEND
;
WAIT UNTIL(P@MSPWDPN="OFF");	Verify DEP is OFF.
WAIT UNTIL(P@MSPWAEN="OFF");	Verify App electronics are OFF.

WAIT;				'GO' to switch MDI power converters to B bus.
;
/mcpc1bn;		PRIMARY CONVERTER 1 TO B(N)
/mcpc2bn;		PRIMARY CONVERTER 2 TO B(N)
/mcrc1bn;		REDUNDANT CONVERTER 1 TO B(N)
/mcrc2bn;		REDUNDANT CONVERTER 2 TO B(N)
/SEND
;
WAIT UNTIL(P@MSPC1N="A");	Verify command execution.
WAIT UNTIL(P@MSPC2N="A");	Verify command execution.
WAIT UNTIL(P@MSRC1N="A");	Verify command execution.
WAIT UNTIL(P@MSRC2N="A");	Verify command execution.
;
WAIT;				'GO' for s/c bus A power on
;
/KNMPWBNN;	LCL MDI B POWER ON (R)
/SEND
;
WAIT UNTIL(P@MSPWB="ON");	Verify s/c bus A power on
WAIT UNTIL((P@MIPWB>=0)AND(P@MIPWA<0.05))	;Current should be approx zero

s k_exp_mon_ena

WAIT;				'GO' to send ALL OFF command.
;
/mcallofn;	ALL MDI SYSTEMS OFF (N)
/SEND
;
WAIT UNTIL(P@MSPWDPN="OFF");	Verify DEP is OFF.
WAIT UNTIL(P@MSPWAEN="OFF");	Verify App electronics are OFF.
;
ASK_HRTLM:
ASK "USE PRIME OR REDUNDANT 160K IF (PRI/RED)?" MDI_HRTLM
MDI_HRTLM = %UPPER(MDI_HRTLM)
IF ((MDI_HRTLM <> "RED") and (MDI_HRTLM <> "PRI")) THEN 
GOTO ASK_HRTLM
ENDIF;

IF (MDI_HRTLM = "RED")THEN
	/MCTMSELN				;SET 160K INTERFACE RELAY
	/SEND
ENDIF

WAIT;				'GO' to switch rc2 to A bus.
;
/mcrc2bn;	REDUNDANT CONVERTER 2 TO B(N)
/SEND
;
WAIT UNTIL(P@MSRC2N="B")   ;Verify primary converter 2 (PC2) is on the A bus.
;
SV MIPWB
;				Record the MDI current.  This should be 
WAIT;				approximately 0.3.
;
WAIT;				'GO' to switch on DEP.
;
/mcdponn;	DEP POWER ON(N)
/SEND
;
WAIT UNTIL(P@MSPWDPN="ON");	Verify DEP is powered ON.

ASK "WILL THE PRIME OR RED BLOCK CMD I/F BE USED (PRI/RED)?"MDI_CMD
MDI_CMD = %UPPER(MDI_CMD)
IF (MDI_CMD = "RED") THEN

	/MCTCMLN				
	/SEND

ENDIF

SV MIPWB
;				Record the MDI current.  This should be 
WAIT;				approximately 0.4.
;
WAIT;				'GO' to switch on apps electronics.
;
/MBPWAEON;	COMMAND APPS ELECTRONICS ON
/SEND
;
WAIT 5

WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE")	     
;
/MCDPRSTN;	RESET DEP TO RECOVER FROM AE POWER UP
/MCDPRSTR

/SEND

WAIT 10

;
;				'GO' to resend AE power on to get correct
WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE")			     
;
/MBPWAEON;	AE POWER ON
/SEND
;
WAIT UNTIL(P@MSPWAEN="ON")	;Verify App electronics are powered ON.
WAIT UNTIL(P@CMD_STATE#TELECOMMAND = "AVAILABLE")			     

IF (MDI_HRTLM = "PRIME") THEN

	/MBPWTM1o
	/SEND

ELSE
	/MBPWTM2o
	/SEND

ENDIF

WAIT;				'GO' to set DEP local on-board time.
;
/knk12000,0020
/SEND
;
WAIT;				'GO' to reset all motor controllers.
;
/mbshrs;	SHUTTER RESET
/mbm1rs;	MTM1 RESET
/mbm2rs;	MTM2 RESET
/mbpars;	PA RESET
/mbc1rs;	C1 RESET
/mbc2rs;	C2 RESET
/mbfdrs;	FRONT DOOR RESET
/mbam1rs;	AM1 RESET
/mbam2rs;	AM2 RESET
/SEND
;
WAIT;				'GO' to switch pc1 to B bus.
;
/mcrc1bn;		PC1 TO B BUS
/SEND
;
WAIT UNTIL(P@MSRC1N="B");	Verify PC1 is connected to A bus.
;
SV MIPWB
;				Record the MDI current.  This should be 
WAIT;				approximately 0.7.
;
WAIT UNTIL(P@MKPWAE="ON")	;Verify application is on I/F power.
if(MDI_HRTLM="PRI") then
	WAIT UNTIL(P@MKTMSEL="1")	;Verify TM selection enabled.
	WAIT UNTIL(P@MSTMSELN="1")	;Verify TM selection enabled.
else
	WAIT UNTIL(P@MKTMSEL="2")	;Verify TM selection enabled.
	WAIT UNTIL(P@MSTMSELN="2")	;Verify TM selection enabled.
endif
;
SNAP M_PWR_1,,RCSONSCB.RPT,OVERWRITE
;
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
END:
ENDPROC