PROC S_FL_EMERGEN
;VERSION 6
GOTO BEGIN
;#**************************************************************************
;#
;#	PROCEDURE HEADER
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:    S_FL_EMERGEN
;#		   	MMS-F Name:  N/A 
;#		   	SUM Issue:   N/A	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:	3 APR 95
;#			    Revision:	1)  25 APR 95  TB
;#						2)  27 APR 95  TB
;#						3)  18 MAY 95  TB
;#						4)  24 OCT 95  RS
;#						5)  16 Dec 95
;#						6)  13 JAN 97  RJ
;#
;#		1.3	Change Description:	
;#			1)	Changed comment on line 70
;#			From: ;Abort any running programs -- 
;#                               doesn't stop current image integration
;#			To:   ;Abort any running programs -- 
;#                             stops any activity except movement
;#			      ;within 5 seconds
;#
;#			2)	Changed command /SBCHGPAR to /SBCHGP
;#				Changed command /sbmmov to sb3mcmov
;#				Changed SWTM to SUMER
;#
;#			3) Added:
;#					START K_EXP_MON_DIS	
;#					;Disable the experiment LCL 
;#					monitoring at channel level
;#			4) Changed name from s_ts_emergen ---> s_fl_emergen.
;#	        	5) Changed door maneouvre to SBSESR 
;#			6) Added option whether to turn off LCL & limits
;#
;#		1.4	Point of Contact:	
;#			FOT Author: Travis Bailey  	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure cancels all activity, 
;#			shuts down detector and
;#			closes the experiment door. 
;#			Then it turns off the power to
;#			the SUMER experiment
;#
;#		2.2	Intended Use:
;#
;#			Turn SUMER off in an emergency
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			PLM is powered on into a ready mode
;#			Need FM6 SDB or later to run
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL SUMOFF

IF (P@CMD_STATE#TELECOMMAND .NE. "AVAILABLE") THEN
	/CLEAR		;Clearing the Command Buffer.
ENDIF

WRITE "START SUMER EMERGENCY OFF PROCEDURE"

;--------------------------------------------
; Abort any running programs -- stops any
; activity except movement within 5 seconds.
;--------------------------------------------

;--------------------------------------------
; /SBSESR: SUMER ESR warning, detector HV
;   off and close door.
; /SBLCCL: Clear all commands in SUMER
;   command list.   	
; /SBCLE: Reenable SUMER command list.	
;--------------------------------------------
/SBSESR
/SBLCCL
/SBCLE		
WAIT; Verify command buffer contents
/SEND

WAIT 5

;--------------------------------------------
; Change left limit to closed.
;--------------------------------------------
/SBCHGP,0008,4400,0000		
WAIT; Verify command buffer contents
/SEND

;--------------------------------------------
; The following checks make sure that door
; is closed before LCL switch off.
;--------------------------------------------
WAIT UNTIL (SSMC1POS > 0)
WAIT UNTIL (P@SKEXPSTA = "SUM opertnal")
WAIT UNTIL (P@SKEXPSTA = "SUM standby")

;--------------------------------------------
; Optionally turn off LCL and inhibit all
; limit checking
;--------------------------------------------
LET SUMOFF = "X"
DO WHILE ((SUMOFF <> "Y") AND (SUMOFF <> "N"))
	ASK "Do you want to Power off SUMER with" & ;;
	" EXP LCLs? (Y/N)" SUMOFF
	LET SUMOFF = %UPPER(SUMOFF)
ENDDO

IF (SUMOFF = "Y") THEN
	LIM OFF SUMER
	;---------------------------------------
	; Disable the experiment LCL monitoring
	; at channel level.
	;---------------------------------------
	START K_EXP_MON_DIS	

	;---------------------------------------
	; Turn off A-side SUMER LCL.
	;---------------------------------------
	/KNSPWAFN
	WAIT; Verify command buffer contents
	/SEND

	WAIT 5
	;---------------------------------------
	; Turn off B-side SUMER LCL.
	;---------------------------------------
	/KNSPWBFN
	WAIT; Verify command buffer contents
	/SEND
ENDIF

WRITE "End of SUMER Emergency Power OFF"

OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
RETURN
ENDPROC