PROC S_FL_PULSE
;VERSION 3
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:    S_FL_PULSE
;#		   	MMS-F Name:  N/A	 
;#		   	SUM Issue:   N/A	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  3 APR 95
;#			    Revision:  1) 27 APR 95 TB
;#						2) 01 JUN 95 TB
;#						3. 24 OCT 95 RS
;#
;#		1.3	Change Description:	
;#
;#			1) Added Constraint:
;#			The SUMER insturment needs to be off to run this procedure.
;#			
;#			2) Added 28 V on Commands and some comments.
;#			3. Changed name from s_ts_pulse to s_fl_pulse.
;#
;#		1.4	Point of Contact:	
;#			FOT Author: Travis Bailey  	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure tests SUMER pulse commands
;#
;#		2.2	Intended Use:
;#
;#			Test SUMER pulse commands
;#
;#		2.3	Duration:	5 min
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#
;#		3.3	Special Constraints or Activities
;#
;#			The SUMER insturment needs to be off to run this procedure.
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

local config

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

WAIT	;SA - Confirm the following WAIT UNTILS Manually

WAIT UNTIL ( (P@QTSR1 >= 16.0) AND (P@QTSR1 <= 24.0) )
WAIT UNTIL ( (P@QTSR2 >= 16.0) AND (P@QTSR2 <= 24.0) ) 
WAIT UNTIL ( (P@QTSR3 >= 16.0) AND (P@QTSR3 <= 24.0) ) 
WAIT UNTIL ( (P@QTSI1A >= 16.0) AND (P@QTSI1A <= 24.0) )
WAIT UNTIL ( (P@QTSI1B >= 16.0) AND (P@QTSI1B <= 24.0) )

/KNSPWAFN		;Current limiter +28 V A off nominal to SUMER Experiment
WAIT			;Verify command buffer contents?
/SEND

WAIT 5		;WAIT FOR VALID COMMAND STATE


/KNSPWBFR		;Current limiter +28 V B off Redundant to SUMER Experiment
WAIT			;Verify command buffer contents
/SEND

WAIT 5

ASK "Is power up for nominal or redundant configuration (NOM/RED)" config
LET config = %UPPER(config)

IF (config = "NOM") THEN
	/KNSPWANN		;Switch on bus to experiment A on nominal
	WAIT			;Verify command buffer contents
	/SEND

	WAIT UNTIL (P@SSPWA = "ON") TIMEOUT 60	

	IF (P@SSPWA .NE. "ON") THEN
		WAIT	;Contact Experimentor and ask how to proceed.
	ENDIF

	WAIT UNTIL ( (P@SIPWA >= 0.2) AND (P@SIPWA <= 0.35) )	;Current @ S/C
ELSE
	/KNSPWBNR		;Switch on bus to experiment B on Redundant
	WAIT			;Verify command buffer contents
	/SEND

	WAIT UNTIL (P@SSPWB = "ON") TIMEOUT 60	

	IF (P@SSPWB .NE. "ON") THEN
		WAIT	;Contact Experimentor and ask how to proceed.
	ENDIF

	WAIT UNTIL ( (P@SIPWB >= 0.2) AND (P@SIPWB <= 0.35) )	;Current @ S/C
ENDIF

IF (config = "NOM") THEN
	/SCMPRSTN		;RESET pulse NOMINAL
	WAIT			;Verify command buffer contents
	/SEND
ELSE
	/SCMPRSTR		;RESET pulse REDUNDANT
	WAIT			;Verify command buffer contents
	/SEND
ENDIF

WAIT ;Experimenter will report when SUMER DPU is booting after RESET pulse

IF (config = "NOM") THEN
	/SCMPBUN		;Backup pulse nominal
	WAIT			;Verify command buffer contents
	/SEND
ELSE
	/SCMPBUR		;Backup pulse redundant
	WAIT			;Verify command buffer contents
	/SEND
ENDIF

WAIT ;Experimenter will report when SUMER DPU is booting after BACKUP pulse

/KNSPWAFN		;Current limiter +28 V A off Nominal to SUMER experiment
WAIT			;Verify command buffer contents
/SEND

WAIT 5		;WAIT FOR VALID COMMAND STATE

/KNSPWBFR		;Current limiter +28 V B off Redundant to SUMER experiment
WAIT			;Verify command buffer contents
/SEND

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		TBD
;#
;#**************************************************************************
ENDPROC