PROC S_FL_SAFE

;Version 6   ********************************** Changes are indicated by ******

GOTO BEGIN

;#      PROCEDURE HEADER

;#

;#      1.0     Introduction

;#

;#              1.1     FOT Name:    S_FL_SAFE

;#		   	MMS-F Name:  N/A	 

;#		   	SUM Issue:   N/A	

;#			Simulator Validation Status:

;#

;#		1.2	Date Created:     01-APR-95

;#			    Revision:  1) 03 APR 95	TB

;#                                     2) 08 JUN 95	TL

;#				       3) 24 OCT 95	TB

;#				       4) 24 OCT 95	RS

;#				       5) 28 NOV 95	TB

;# *************************           6) 16 DEC 95    ****************

;#

;#		1.3	Change Description:	

;#

;#			1) Changed procedure name from S_TS_SUM_SAFE -> 

;#                         S_TS_SAFE

;#                      2) Changed proc call from s_ts_sum_off to s_ts_off.

;#			3) Changed content of procedure to commands for soft 

;#                         safe procedure (IRENE BUETTNER inputs).

;#			4) Changed name of proc from s_ts_safe ---> s_fl_safe.

;#			5) Corrected typos.

;# ***************      6) Changed door maneouvre and temperature trimming

;#

;#		1.4	Point of Contact:	

;#			FOT Author: Travis Bailey  	ATSC/SOHO	286-4799

;#

;#**************************************************************************

;#	2.0	Description

;#

;#		2.1	Narrative Description

;#

;# ****************     This procedure takes SUMER to SAFE mode.

;# *****************    It will switch off all high voltages and

;# *****************    close the entrance door to a safe position

;# *****************    for attitude maneouvres.

;# *****************    The instrument will remain on with its internal

;# *****************    thermal control active.

;#			

;#		2.2	Intended Use:

;#

;#			To put SUMER into SAFE Mode without need to reboot 

;#                      afterwards.

;#

;#		2.3	Duration:	10 min

;#

;#		2.4 References:

;#

;#**************************************************************************

;#	3.0	Instructions for Use:

;#

;#		3.1	Parameters Required

;#

;#			None

;#

;#		3.2	Critical Activities

;#

;#			None

;#

;#		3.3	Special Constraints or Activities

;#

;#			Does not disable motor drives and will

;#                      not interrupt long exposures

;#**************************************************************************

;#	4.0	STEPS:



BEGIN:



IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN

ELSE

	/CLEAR		;Clearing the Command Buffer.

ENDIF



WRITE "START OF SUMER SAFE"



;Commands to switch off HV to detector and close door



;First abort any programme that may be running. Could take a long time for

;long exposure times.

/SBCANCEL

WAIT		;Verify Command Buffer

/SEND



WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")



;The command list is now disabled; dump list and clear any remaining commands

/SBLDCL

WAIT		;Verify Command Buffer

/SEND



WAIT 20	;Until 73 records of type 248 have been dumped.



WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")



/SBLCCL

WAIT		;Verify Command Buffer

/SEND



WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")



;Reenable command list for subsequent activities

/SBCLE

WAIT		;Verify Command Buffer

/SEND



;Switch off detector HV first

/SB3SHUTD

WAIT		;Verify Command Buffer

/SEND



;Close door

WRITE"If door is open, close door"





WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")



/SBPEXON,0027 ; Switch on MC 1

WAIT		;Verify Command Buffer

/SEND



WAIT UNTIL (SSMC1POS > 0)	;May take a minute



WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")



IF (SSMC1POS .LE. 1900) THEN    


  IF (SSMC1POS .LE. 700) THEN

	/SBCHGP,0001,0000,0000	 ;Initialize door position to open

	/SBCHGP,000F,4400,0000	 ;Change right limit to closed w/o pressure

	/SBMQUAL	         ;Qualify door movement

	/SB3MCMOV,0000,4400,0001 ;Close door

  ELSE

	/SBCHGP,0001,387C,0000	 ;Initialize door position to partially open

	/SBCHGP,000F,4400,0000	 ;Change position limit to closed w/o pressure

	/SBMQUAL	         ;Qualify door movement

	/SB3MCMOV,0000,4400,0001 ;Close door

  ENDIF

 

 ; wait until door is closed

  WAIT  120 

 ; check if door is really closed

  IF (SSMC1POS .LE. 1900) THEN

	WAIT ;Contact experimenter

  ELSE

  ENDIF







  /SBCHGP,0008,4400,0000	 ;Set door left limit to closed ****************



ELSE

ENDIF



WAIT		          ;Verify Command Buffer

/SEND



WAIT 120	;For door to close

WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

	;Switch off deflector (SUMER 4 switch #11)

/SBPEXOFF 000B

;Switch off all motor controllers for safety reasons.



/SBPEXOFF,0027  

/SBPEXOFF,0028  

/SBPEXOFF,0029  

/SBPEXOFF,002A  

/SBPEXOFF,002B  

/SBPEXOFF,002C  

/SBPEXOFF,002E  

WAIT		          ;Verify Command Buffer

/SEND



WAIT 30	;

;Switch off +/- 18 V



/SBPEXOFF,0030  

/SBPEXOFF,0031  

/SBPEXOFF,0032  

/SBPEXOFF,0033  


WAIT		          ;Verify Command Buffer

/SEND



WAIT 30	;

;Switch on +/- 18 V



/SBPEXON,0030  

/SBPEXON,0031  

/SBPEXON,0032  

/SBPEXON,0033  

WAIT		          ;Verify Command Buffer

/SEND



WAIT 30	;

;Switch on all motor controllers and go to heater mode 3 for thermal reasons.



/SBPEXON,0027 

/SBPEXON,0028  

/SBPEXON,0029  

/SBPEXON,002A  

/SBPEXON,002B 

/SBPEXON,002C  

/SBPEXON,002E  

WAIT		          ;Verify Command Buffer

/SEND



WAIT 30	;

/SBAUTO,0000

/SBAUTO,0001 

/SBAUTO,0002

/SBAMODE,0003,0000



WAIT		;Verify Command Buffer

/SEND


WAIT 30	;


WRITE "END OF SUMER SAFE without reboot"



;#************************************************************************** 

;#	5.0	Final Constraints

;#

;#		None

;#

;#**************************************************************************

ENDPROC