PROC K_DUTOIDLE
;Version 8
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  K_DUTOIDLE
;#		     MMS-F Name:  DUMP_TO_IDLE_FORMAT_1
;#		     SUM Issue:  3E
;#			Simulator Validation Status:	Complete
;#
;#		1.2	Date Created:   10-06-93
;#				Revision: 1. 1-APR-94
;#			           	2. 10-JUN-94   MH
;#						3. 02-FEB-95	HB
;#						4. 01-MAR-95	MH
;#						5. 24-MAR-95	HB
;#						6. 11-APR-95	MH
;#						7. 24-MAY-95	HB
;#						8. 23-OCT-95   RS
;#
;#		1.3	Change Description:	
;#
;#			1.Changed TM values to agree with the Database values.
;#			Changed TM point:
;#				XSSP6N -> DSTR1SBY
;#			Changed TC:
;#				KNK1E000 -> KNK1ET31
;#			This procedure is now optional.
;#			2. Deleted page call.
;#			3. Deleted WAIT after commands.  Added ability to transition from
;#			   dump to idle from any science submode.  Changed name to 
;#			   K_DUTOIDLE.
;#			4. Added IF/THEN to check TR Standby status
;#			5. Updated procedure per SUM 3B.  No TSTOL changes.
;#			6. Removed IF/THEN to command TR to standby.  Nominally this
;#			   will not be necessary.  With proc coded in this way, DHSS will
;#			   be commanded to IDLE mode immediately after DSTR1SBY = 
;#			   "STAND-BY".
;#			7. Added HISTORY CLOSE and TNIF DISABLE statements.
;#			8. Updated SUM Issue, critical activities documentation,
;#			   and special constraints or activities.  Allows user to
;#			   choose between nominal and redunadant recorders.
;#
;#		1.4	Point of Contact:	GMiller
;#			FOT Author:  TBailey	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			To change the TM mode from Dump to Idle.
;#
;#		2.2	Intended Use:
;#
;#			Change TM mode Dump to Idle.
;#
;#		2.3	Duration:	4 minutes 45 seconds
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None.
;#
;#		3.3	Special Constraints or Activities
;#
;#			None.
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL TID, RECORDER

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

RERTY0:
ASK "What telemetry subformat is the DHSS in (1-4)?"TID

IF ( ($TID < 1) OR ($TID > 5) ) THEN
	WAIT	;Invalid TM Subformat. Try again
	GOTO RETRY0
ELSE
ENDIF

WAIT UNTIL (P@KKTMFID = "MR/HR $TID")	;Check The current TM mode
WAIT UNTIL (P@KKTMMODE = "PLAYBACK")	;Check the current TM mode


RETRY:
ASK "What recorder is being used.  Nominal (TR) or Redundant (SSR) (NOM/RED)?"RECORDER
LET RECORDER = %UPPER(RECORDER)

WRITE " Initiating DUMP to Idle"

IF (RECORDER = "NOM") THEN
	
	/DZTR1SBN	;Tape-rec 1 to stand-by
	WAIT		;Verify Command Buffer
	/SEND

	WAIT UNTIL (P@DSTR1SBY = "STAND-BY")
	
ELSEIF (RECORDER = "RED") THEN 

	IF (P@DKSSNMOD = "DUMP") THEN
		/DZSSNSBN		;Send SSR ML standby command
		WAIT			;Verify command buffer contents
		/SEND
	ENDIF

	WAIT UNTIL (P@DKSSNMOD = "STAND-BY")
	WAIT UNTIL (P@DSSSNCKA = "NOT.ACT.")
ELSE
	WAIT	;Invalid Recorder. Try again.
	GOTO RETRY
ENDIF			



/KNK1ET3$TID	;TM Rate/Mode = HR/IDLE "
/SEND		;Sending Command Buffer

WRITE " Up to 22.5 seconds may be necessary for the change to be effective and" 
WRITE " reported in the telemetry."
WRITE " Available at latest 3 formats after change is commanded."

WAIT UNTIL  (P@KKTMFID = "MR/HR $TID") 	;Check the TM mode 
WAIT UNTIL  (P@KKTMMODE = "IDLE")	;Check the TM mode 


WAIT	;Type 'GO' to close TREC History and disable TNIF 2.
HISTORY CLOSE FRAME TREC
TNIF DISABLE 2

WRITE "Transition to HR IDLE is complete"

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None.
;#
;#**************************************************************************
ENDPROC