PROC K_DUTOMM
;Version 6
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  K_DUTOMM    
;#		   	MMS-F Name:  DUMP_TO_MDI-M_FORM_1
;#					   DUMP_TO_MDI-M_FORM_1_S 	 
;#		   	SUM Issue:  3E 	
;#			Simulator Validation Status: Complete
;#
;#		1.2	Date Created:  22 MAR 1994
;#			    Revision:  1. 2-Feb-95	HB
;#						2. 23-MAR-95	HB
;#						3. 24-MAY-95	HB
;#						4. 5-26-95 RR
;#						5.	23-OCT-95	TB
;#						6.	18-NOV-95	TB
;#
;#		1.3	Change Description:	
;#
;#			1. Added flexibility to perform this procedure regardless of TM
;#			   submode number.  Removed comments from MDI command.  Changed 
;#			   name to K_DUTOMM
;#			2. Changes for SUM 3B.  Added local variable REC.  Added option
;#			   to use procedure for either TR or SSR.
;#			3. Added HISTORY CLOSE and TNIF DISABLE statements.
;#			4. added mdi proc
;#			5.	Updated to SUM Issue 3E. Added TR
;#			6.	Changed MDI procedures from tl to fl.
;#
;#		1.4	Point of Contact:  GMiller	
;#			FOT Author:  MHill	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			To change the TM mode from dump to MDI-M
;#
;#		2.2	Intended Use:
;#
;#			Change TM mode from Dump to MDI-M, Format 1
;#
;#		2.3	Duration:	4 min 45 sec
;#
;#		2.4  References: D_SSR_STAT_N, D_TR_STATUS
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			Before initiating the mode transition at experiment level
;#			it is necessary to wait 22.5 sec for idle mode to be 
;#			correctly settled at DHSS level. No information available
;#			on the necessary operations at experiment level.
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL TID,REC

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

RETRY0:

ASK "What telemetry subformat is the DHSS in (1-4)?"TID
IF ( ($TID < 1) or ($TID > 4) ) THEN
	WAIT	;Invalid TM Subformat. Try Again
	GOTO RETRY0
ELSE
ENDIF

WAIT UNTIL (P@KKTMFID = "MR/HR $TID")	;Check current TM mode (Dump)
WAIT UNTIL (P@KKTMMODE = "PLAYBACK")	;Check current TM mode (Dump)

RETRY1:

ASK "TR or SSR?"REC
LET REC = %UPPER(REC)
IF (REC = "SSR") THEN
	IF (P@DKSSNMOD = "DUMP") THEN
		WAIT UNTIL(P@DSSSNCKA = "ACTIVE")
	ELSE
		WAIT UNTIL(P@DKSSNMOD = "STANDBY")
	ENDIF	;(Dump IF)

	/KNK1ET6$TID	;Transition to MDI-M format.  
				;Up to 22.5 sec may be necessary for the 
 			;change to be effective and reported in telemetry.
	WAIT		;Verify contents of command buffer.
	/SEND

	WAIT UNTIL (P@KKTMFID ="MR/HR $TID");Verify data format is in HR submode.
	WAIT UNTIL (P@KKTMMODE ="MDI M")	;Verify DHSS Mode is MDI-M 

	HISTORY CLOSE FRAME TREC
	TNIF DISABLE 2

	s m_fl_idtomm

	WAIT 	;Verify transitions within MDI experiment 
			;have occured (methods TBD).

	WAIT UNTIL(P@DSSSNCKA = "NOT.ACT.")

	IF (P@DKSSNMOD = "DUMP") THEN
		/DZSSNSBN	;SSR N to standby mode CMD (N)
		WAIT		;Verify contents of command buffer.
		/SEND
	ELSE
	ENDIF

	WAIT UNTIL (P@DKSSNMOD="STAND-BY")
	WAIT ;Record the logical address of the current memory page

ELSEIF (REC = "TR") THEN
	IF (P@DSTR1SBY <> "STAND-BY") THEN
		/DZTR1SBN		;Send TC to put TR in stand by mode.
		WAIT			;Verify command buffer contents.
		/SEND
		WAIT UNTIL (P@DSTR1SBY = "STAND-BY")	;Verify.
	ENDIF	;(STAND-BY IF)
	
	/KNK1ET6$TID	;Transition to MDI-M format.  
				;Up to 22.5 sec may be necessary for the 
 			;change to be effective and reported in telemetry.
	WAIT		;Verify contents of command buffer.
	/SEND

	WAIT UNTIL (P@KKTMFID ="MR/HR $TID");Verify data format is in HR submode.
	WAIT UNTIL (P@KKTMMODE ="MDI M")	;Verify DHSS Mode is MDI-M 

	HISTORY CLOSE FRAME TREC
	TNIF DISABLE 2

	s m_fl_idtomm

	WAIT 	;Verify transitions within MDI experiment 
			;have occured (methods TBD).
ELSE
	WAIT	;Invalid Recorder. Try Again
	GOTO RETRY1
ENDIF	;(Recorder IF)

WRITE "MDI-M MODE TRANSITION COMPLETE"
;
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None
;#
;#**************************************************************************
ENDPROC