PROC K_IDTODUMP
;VERSION 5
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:	K_IDTODUMP
;#		    	MMS-F Name: IDLE_TO_DUMP_FORM_1_OPT	
;#		    	SUM Issue:  3E
;#			Simulator Validation Status: Complete
;#
;#		1.2	Date Created:	22 MAR 1994
;#				Revision:	1. 10-JUN-94   MH
;#						2. 2-FEB-95	HB
;#						3. 24-MAR-95	HB
;#						4. 24-MAY-95	HB
;#						5. 23-OCT-95	RS
;#
;#		1.3	Change Description:	
;#
;#			1. Deleted page call.
;#			2. Changed name to K_IDTODUMP.  Added flexibility to perform
;#			   this procedure regardless of TM subformat.  Deleted WAIT
;#			   statements after commands.  Moved TM verification for TR to 
;#			   standby to after the TC.  Deleted unnecessary comments.
;#			3. Updated procedures per SUM 3B.  No TSTOL changes.
;#			4. Added WAIT statement to configure local TPOCC switch for 
;#			   playback.  Added TNIF LOAD and HISTORY statements.
;#			5. Updated narrative description, the duration, references, parameters
;#		 	   required, critical activities, and added local new local
;#			   variables for incorporation of possibility for nominal
;#			   and redundant recorders.
;#
;#		1.4	Point of Contact:  GMiller
;#			FOT Author: MHill		ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			To change the TM mode from idle to dump and to set
;# 			the TR in dump mode. This transition is optional. The 
;#			transition can be performed directly from record mode 
;#			to dump mode.
;#
;#		2.2	Intended Use:
;#
;#			Change TM mode from Idle to dump, Acquisition Format 1
;#			(Option)
;#			
;#		2.3	Duration:	TBD
;#
;#			4 minutes 45 seconds
;#
;#		2.4 References:
;#			6.1.1	SOHO Style Guide
;#			6.1.2	SOHO SUM ISSUE 01B
;#			6.1.3	SOHO POCC Users Guide Chapter 4 and
;#				 Appendix A.
;#			Pages: D_SSR_STAT_N, D_TR_STATUS
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			D_SSR_DUMP
;#
;#		3.2	Critical Activities
;#
;#			None.
;#
;#		3.3	Special Constraints or Activities
;#
;#			Before initiating the mode transition at TR level it is 
;#			necessary to wait up to 22.5 sec for idle mode to be correctly 
;#			settled.
;#**************************************************************************
;#	4.0	STEPS:
;#		
;#		Note Time Tags may be used.
;
BEGIN:

LOCAL TID, RECORDER, TRPOS

RETRY:
ASK "What recorder is being used? NOM TR/RED SSR (NOM/RED)?"RECORDER
LET RECORDER = %UPPER(RECORDER)

IF (RECORDER = "NOM") THEN
	ASK "What telemetry subformat is the DHSS in (1-4)?"TID
	WRITE " Initiating Idle to Dump Mode"
IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR					;Clearing the Command Buffer.
ENDIF						;Clear command buffer

WAIT UNTIL  (P@KKTMFID = "MR/HR $TID") 	;Check the current TM mode
WAIT UNTIL  (P@KKTMMODE = "IDLE") 		;Check the current TM mode

WAIT;Configure local TPOCC switch for playback:  FE ch 3 (in) to FE ch 2 (out)
TNIF LOAD 2 SOHO2.DSD
HISTORY OPEN FRAME TREC

IF (P@DSTR1SBY = "STAND-BY") THEN
ELSE 
	/DZTR1SBN		;Put TR 1 in standby if not already.
	/SEND

	WAIT UNTIL (P@DSTR1SBY="STAND-BY")
ENDIF

/KNK1ET5$TID 					;Select DHSS Dump mode
/SEND

WRITE "Up to 22.5 seconds may be necessary for the change to be effective and reported in the telemetry."

WAIT UNTIL  (P@KKTMFID = "MR/HR $TID") 	;Verify Data Format 1 selected
WAIT UNTIL  (P@KKTMMODE = "PLAYBACK") 	;Verify DHSS is in Dump Mode

WRITE " (available at latest 3 formats after commanding)"

WRITE " Send TC to put TR in dump mode" 	
				
/DZTR1PAN					;Tape-Rec 1 to REPRO/A (NOM)
/SEND

WAIT UNTIL (P@DSTR1REP = "REPRO.") 		;TR in dump mode

WRITE "TR is now in dump mode"

LET TRPOS = DSTR1POS
WAIT UNTIL (DSTR1POS.LT.TRPOS)
ELSE 
IF (RECORDER = "RED") THEN
	S D_SSR_DUMP
ELSE	
	WRITE "Invalid recorder.  TRY AGAIN."
	WAIT	;Type 'GO' to try again.
	GOTO RETRY
ENDIF
ENDIF
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None
;#
;#**************************************************************************
ENDPROC