PROC K_IDTORC
;Version 9
GOTO BEGIN
;
;#***************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	Name:	K_IDTORC	
;#			MMS-F NAME:  IDLE_TO_RECORD_FORM_1_OPT
;#			SUM ISSUE:  3E
;#			Simulator Validation status:	Complete 
;#
;#		1.2	Date Created:	10-06-93
;#			    Revision:  1. 31-MAR-94  MH
;#			          	2. 08-JUN-94  MH
;#						3. 06-OCT-94  BS
;#						4. 2-FEB-95	HB
;#						5. 15-MAR-95	HB
;#						6. 24-MAR-95	HB
;#						7. 11-APR-95	MH
;#						8. 26-MAY-95	MH
;#						9. 23-OCT-95	RS
;#
;#		1.3	Change Description:
;#
;#			1. SUM 2A REV. 1 TC &TM CHANGES
;#		     2. /KNK1C000,0001 -> /KNK1CNOM
;#			   P@DSTR1POS -> DSTR1PBT, Added 2 WRITE statements
;#			   deleted page call
;#			3. Moved SB: section inside STANDBY if statement.  Moved
;#			   selecting NOMINAL TR to beginning, right after clearing
;#			   command buffer.
;#			4. Changed name to K_IDTORC.  Added flexibility to perform this
;#			   procedure regardless of TM submode number.  Moved command
;#			   state IF-THEN loop prior to first TM checks.  Deleted WAIT
;#			   statements after commands.  Deleted command state IF-THEN loop
;#			   before TR to record redundant command.  Deleted unnecessary
;#			   comments.
;#			5. Added TM check after nominal rewind command.  Added redundant
;#			   rewind command and TM check.
;#			6. Updated procedure per SUM 3B.  Added IF/THEN for TR/SSR check.
;#			7. Added blank line after first endif.  Added page reference.
;#			8. Changed order of DHSS and TR record commands.
;#			9. Added version to header, updated simulator validation status 
;#			   to complete, updated the narrative description to reflect 
;#			   procedure changes, same for intended use, references, and parameters
;#			   required.  Added local variables recorder and TRPOS.  Added choice in 
;#			   procedure to allow user to choose nominal or redundant recorders
;#			   as well as checks that the SSR is off and nominal power is
;# 			   being supplied via LCLs to the recorder. Added Constraint.
;#
;#		1.4	Point of Contact:  GMiller
;#			FOT Author:	TBailey	ATSC/SOHO	286-4799
;#
;#***************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			To change the TM mode from idle to record and to set the  
;#			(NOM/RED) in record mode.
;#			
;#		2.2	Intended Use:
;#
;#			Change TM mode to Rec in Acquisition Format (1 - 4)
;#
;#		2.3	Duration:	12 minutes 45 seconds
;#
;#		2.4 References: D_TR_STATUS, D_SSR_STAT_N
;#
;#***************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			D_SSR_RECORD
;#
;#		3.2	Critical Activities
;#
;#			TBD
;#		
;#		3.3	Special Constraints or Activities
;#
;#			Before initiating the mode transition at experiment
;#			level it is necessary to wait up to 22.5 sec. for
;#			idle mode to be correctly settled. As the procedure
;#			foresee to configure first the TR in record mode
;#			before configuring the COBS/DHSS in record mode the
;#			telemetry containing the clock information (DSTR1CLK)
;#			will indicate missing clock. Note that the procedure
;#			related to TR management has still to be checked 
;#			with ODETICS.
;#	
;#			If TR already at tape position 0 then TR rewind CMD will NOT
;#			put TR at BOT. Must Fast FWD TR then RWD.
;#***************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL TID, RECORDER, TRPOS
				
IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR				;Clearing the Command Buffer.
ENDIF					;Clear Command Buffer

ASK "What telemetry subformat is the DHSS in (1-4)?"TID

WRITE " HR idle to record mode transition can be initiated"

WAIT UNTIL  (P@KKTMFID = "MR/HR $TID")	;Verify acquisition format 1 is
					;selected
WAIT UNTIL  (P@KKTMMODE = "IDLE")	;Verify DHSS is in HR IDLE Mode

RETRY:
ASK "NOM (TR) OR RED (SSR) RECORDER? (NOM/RED)"RECORDER 
LET RECORDER = %UPPER(RECORDER)
IF (RECORDER = "NOM") THEN 
	WAIT UNTIL (P@DSTR1ON = "ON")	;TR ON
	WAIT UNTIL (P@DSSSN = "OFF")	;SSR OFF
	WAIT UNTIL (P@DSSSNON = "OFF")	;LCL LINE 1 OFF (SSR)
	WAIT UNTIL (P@DSTRA = "ON")		;LCL LINE 1 ON (TR)

	WRITE "Send TCM to select nominal TR with data word 1 = 00."

	IF (P@KKTRSSEL <> "NOM TR") THEN
		/KNK1CNOM	;SELECT NOM/RED TAPE-REC
		/SEND	;Sending Command Buffer
	ELSE
	ENDIF

	WAIT UNTIL (P@KKTRSSEL = "NOM TR")	;Tape-Rec Selected continue

	IF (P@DSTR1SBY <> "STAND-BY") THEN 

		WRITE " Send TC to put TR in stand-by"
		/DZTR1SBN				;Tape-Rec 1 to stand-by (NOM)
		/SEND					;Sending Command Buffer

		WAIT UNTIL (P@DSTR1SBY = "STAND-BY") TIMEOUT 60	

		IF  (P@DSTR1SBY <> "STAND-BY") THEN	;Tape-Rec 1 Stand-By Check.
			WRITE " NOM Failed for Tape-Rec 1 stand-by, sending RED." 	

			/DZTR1SBR			;Tape-Rec 1 to Stand-By (RED)
			/SEND				;Sending Command Buffer
   							;check to see if RED worked TBD.
			WAIT UNTIL (P@DSTR1SBY = "STAND-BY")	
				;If Tape-Rec 1 in stand-by type GO to continue. 
		ELSE
		ENDIF

	ELSE
	ENDIF

	IF (P@DSTR1PBT = "PRIM.BOT") THEN 
		GOTO REC
	ELSE
	ENDIF

	WRITE " Send TC to put TR in rewind mode." 

	WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

	/DZTR1RWN				;Tape-Rec 1 to REWIND (NOM)
	/SEND					;Sending Command Buffer

	WAIT UNTIL (P@DSTR1FRV = "FAST.REV") TIMEOUT 60

	WAIT UNTIL (P@CMD_STATE#TELECOMMAND = "AVAILABLE")

	IF (P@DSTR1FRV <> "FAST.REV") THEN

		/DZTR1RWR		;Tape-Rec 1 to REWIND (RED)
		/SEND		;Sending command buffer

		WAIT UNTIL (P@DSTR1FRV = "FAST.REV")
	ELSE
	ENDIF

	WAIT UNTIL (P@DSTR1PBT = "PRIM.BOT")	;Read TM to verify tape position,
						;when it reaches BOT, ready to start recording
REC:
	WRITE "CHECK VALUE OF TR POSITION COUNTER - TM:DSTRIPOS, RECORD VALUE"
	WAIT	;Record value on pass plan.
	WAIT UNTIL (P@DSTR1SBY = "STAND-BY")		;Verify

	WRITE " Send TC to put TR in record mode."

	/KNK1ET4$TID	;Select TM Rate/Mode/Format, Selecting DHSS Mode to record
	/SEND		;Sending Command Buffer
		
	WRITE " Up to 22.5 seconds may be necessary for the change to be  effective and "
	WRITE "	reported in telemetry."

	WAIT UNTIL (P@KKTMFID = "MR/HR $TID")	;Verify TM Format 1 is selected
	WAIT UNTIL (P@KKTMMODE = "RECORD")	;Verify DHSS is in record mode

	/DZTR1CAN				;Tape-Rec 1 to Record/A (NOM)
	/SEND						;Sending Command Buffer
	WAIT UNTIL (P@DSTR1REC = "RECORD") TIMEOUT 60

	IF (P@DSTR1REC <> "RECORD") THEN	;Tape-Rec 1 Record/A Check.

		WRITE "NOM Failed for Tape-Rec 1 Record/A sending RED."

		/DZTR1CAR			;Tape-Rec 1 to Record/A (RED)
		/SEND				;Sending Command Buffer to check to see if RED worked TBD.
  		WAIT UNTIL (P@DSTR1REC = "RECORD") 	;If Tape-Rec 1 in record type GO to continue. 
	ELSE
	ENDIF

	LET TRPOS = DSTR1POS
	WAIT UNTIL (DSTR1POS .GT. TRPOS)	;Verify TR position is incrementing.
	WRITE "Tape Recorder is now Recording VC0 and VC1 data"
	WRITE "Verify Tape Recorder position counter is incrementing - TM:DSTR1POS"

ELSEIF (RECORDER = "RED" ) THEN
	S D_SSR_RECORD
ELSE 
	WRITE "Invalid Entry, TRY AGAIN."
	WAIT ;TYPE GO TO CONTINUE
	GOTO RETRY
ENDIF
;#***************************************************************************
;# 
;#	5.0	Final Constraints
;#
;#		None.
;#
;#***************************************************************************
ENDPROC