PROC K_RCTOIDLE
;Version 5
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:   K_RCTOIDLE
;#		    	MMS-F Name:	RECORD_TO_IDLE_FORM_1_OPT
;#		    	SUM Issue:	3E
;#			Simulator Validation Status:	Complete
;#
;#		1.2	Date Created:   10-06-93
;#			   Revisions:	1. 31-MAR-94   MH
;#			          	2. 08-JUN-94   MH
;#					  	3. 7-FEB-95	HB
;#						4. 24-MAR-95	HB
;#						5. 23-OCT-95   RS
;#
;#		1.3	Change Description:	
;#
;#			1. SUM 2A REV. 1 TC & TM CHANGES
;#		    	2. Deleted page call
;#			3. Changed name to K_RCTOIDLE.  Added TM subformat flexibility.
;#			   Deleted WAIT statements after commands.
;#			4. Updated procedure to SUM 3B.  No TSTOL changes.
;#			5. Added version number to header, updated SUM issue to 3E, 
;#			   added references of pages, updated critical activities and 
;#			   constraints to "none," added module to allow the option of putting
;#			   the SSR in stand-by mode.  
;#
;#		1.4	Point of Contact:  GMiller
;#			FOT Author:  TBAILEY	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			To change the TM mode from record to idle.
;#			This procedure is now optional. Transition through
;#			idle is not mandatory for DHSS mode changes.
;#
;#		2.2	Intended Use:
;#
;#			Change TM mode Rec to Idle,  Acquisition Format 1
;#
;#		2.3	Duration:	4 minutes 45 seconds
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			None
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL TID, RECORDER

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

ASK "What telemetry subformat is the DHSS in (1-4)?"TID

WRITE "Initiating Record to HR Idle"
WAIT UNTIL (P@KKTMFID = "MR/HR $TID")	;VERIFY TM ACQISITION
WAIT UNTIL (P@KKTMMODE = "RECORD")	;VERIFY DHSS IS IN RECORD MODE

RETRY:
ASK "What recorder is being used? (Nom TR/ Red SSR) (NOM/RED)"RECORDER
WRITE " Send TC to put TR in stand by mode"
LET RECORDER = %UPPER(RECORDER)
IF (RECORDER = "NOM") THEN
	/DZTR1SBN		;Tape-Rec 1 To Stand-By (NOM)
	/SEND			;Sending Command Buffer
	WAIT UNTIL (P@DSTR1SBY = "STAND-BY")
ELSEIF (RECORDER = "RED") THEN
	WRITE "Send TC to put SSR in Stand-By mode"
	/DZSSNSBN	;Send SSR ML standby cmd.
	WAIT	;Verify cmd buffer contents.
	/SEND ;
	WAIT UNTIL (P@DSSSNCKA = "NOT.ACT.")	;Verify SSR with record clock/data signals.
	WAIT UNTIL (P@DKSSNMOD = "STAND-BY")	;Verify SSR is in stand-by.
	WAIT	;Record Time KKTCMEXO (Page K_CMD_STATUS)
ELSE
	WRITE "Invalid Recorder. Try Again."
	WAIT	;Type "GO" to try again.
	GOTO RETRY
ENDIF

/KNK1ET3$TID		;Select TM Rate/Mode = HR/IDLE.
/SEND			;Sending Command Buffer
						
WRITE " Up to 22.5 seconds may be necessary for the"
WRITE " change to be effective and reported in telemetry."

WAIT UNTIL (P@KKTMFID = "MR/HR $TID")	;Verify acuisition
WAIT UNTIL (P@KKTMMODE = "IDLE")	;DHSS is in HR idle mode.

WRITE " DHSS is now in HR Idle Mode."

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None
;#
;#**************************************************************************
ENDPROC